C_CAInvcgDocVH

@AbapCatalog.sqlViewName: 'CCAINVCGDOCVH'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED
  },
  dataCategory: #VALUE_HELP
}
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Wertehilfe Fakturierungsbeleg'

@Search.searchable: true
@Consumption.ranked: true
define view C_CAInvcgDocVH
  as select from I_CAInvcgDocHeader as CAInvcgDocHeader
{
       @UI.lineItem: [{ position: 10, importance: #HIGH }]
       @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key  CAInvoicingDocument,

       @EndUserText.label: 'Geschäftspartnername'
       @UI.lineItem: [{ position: 20, importance: #LOW }]
       @ObjectModel.filter.enabled: false
       _BusinessPartner.BusinessPartnerFullName,

       @UI.lineItem: [{ position: 30, importance: #HIGH }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner' }}]
       @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
       CAInvcgDocHeader.BusinessPartner,

       @UI.lineItem: [{ position: 35, importance: #HIGH }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount' } } ]
       @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
       ContractAccount,

       @UI.lineItem: [{ position: 70, importance: #LOW }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgProcessVH', element: 'CAInvcgProcess' } } ]
       CAInvcgProcess,

       @UI.lineItem: [{ position: 80, importance: #LOW }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgTypeVH', element: 'CAInvcgType' } } ]
       CAInvcgType,

       @UI.lineItem: [{ position: 40, importance: #HIGH }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgDocumentType', element: 'CAInvcgDocumentType' } }]
       CAInvcgDocumentType,

       @UI.lineItem: [{ position: 50, importance: #LOW }]
       DocumentDate,

       @UI.lineItem: [{ position: 60, importance: #HIGH }]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAReconciliationKeyVH', element: 'CAReconciliationKey' } }]
       CAReconciliationKey,

       @UI.lineItem: [{ position: 90, importance: #LOW }]
       @ObjectModel.filter.enabled: false
       CAAmountInTransactionCurrency,

       @UI.lineItem: [{ position: 100, importance: #LOW }]
       TransactionCurrency,

       @UI.lineItem: [{ position: 110, importance: #LOW }]
       CANetDueDate,

       @UI.lineItem: [{ position: 110, importance: #HIGH }]
       CreatedByUser,

       @UI.hidden: true
       @UI.lineItem: [{ position: 120, importance: #HIGH }]
       CAInvcgCreationDate,

       @UI.hidden: true
       @UI.lineItem: [{ position: 130, importance: #LOW }]
       CAInvcgCreationTime,

       //combined field of crdate and crtime

       @UI.lineItem: [{ position: 120, importance: #HIGH }]
       @Consumption.filter.selectionType: #INTERVAL
       @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
       cast(dats_tims_to_tstmp(CAInvcgCreationDate, CAInvcgCreationTime,
       abap_system_timezone($session.client, 'NULL'),
       $session.client, 'NULL') as invdoc_crtsmp_kk) as CAInvcgCreationDateTime,

       @UI.hidden: true
       CAApplicationArea,
       @UI.hidden: true
       CAInvcgIsDocumentSimulated,
       @UI.hidden: true
       CAInvcgIsDocumentPreliminary,
       @UI.hidden: true
       CAInvcgReversalDocument,
       @UI.hidden: true
       CAInvcgReversedDocument,
       @UI.hidden: true
       CompanyCode,

       @Consumption.filter.hidden: true
       _ContractAccountPartner,
       @Consumption.filter.hidden: true
       _BusinessPartner,
       @Consumption.filter.hidden: true
       _ContractAccountHeader,
       @Consumption.filter.hidden: true
       _TransactionCurrency,
       @Consumption.filter.hidden: true
       _CAInvcgProcess,
       @Consumption.filter.hidden: true
       _CAInvcgType,
       @Consumption.filter.hidden: true
       _CAInvcgDocumentType,
       @Consumption.filter.hidden: true
       _CAApplicationArea,
       @Consumption.filter.hidden: true
       _CompanyCode,
       @Consumption.filter.hidden: true
       _CAReconciliationKey
}
//where

//      CAInvcgDocHeader.CAInvcgIsDocumentPosted      = 'X'

//  and CAInvcgDocHeader.CAInvcgIsDocumentPreliminary = ' '

//  and CAInvcgDocHeader.CAInvcgIsDocumentSimulated   = ' '

//  and ( CAInvcgReversedDocument                       = '000000000000' or CAInvcgReversedDocument is null )

//  and ( CAInvcgReversalDocument                       = '000000000000' or CAInvcgReversalDocument is null )       

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CAINVCGDOCHEADER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CAINVCGDOCUMENTTYPE",
"I_CAINVCGPROCESS",
"I_CAINVCGTYPE",
"I_CARECONCILIATIONKEY",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[
"I_CAINVCGDOCHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/