I_CAINVCGDOCHEADER
Fakturierungsbelegkopf
I_CAINVCGDOCHEADER is a CDS View in S/4HANA. Fakturierungsbelegkopf. It contains 69 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_BSQPMContrAcctgInvcgDocument | view_entity | from | CONSUMPTION | BSQPM CA Invoice Attribute |
| C_CAInvcgDocHeader | view | from | CONSUMPTION | Fakturierungsbeleg Kopf |
| C_CAInvcgDocVH | view | from | CONSUMPTION | Wertehilfe Fakturierungsbeleg |
| C_CAInvcgOvwInvcgDocHeader | view | from | CONSUMPTION | Fakturierungsbeleg Kopf |
| C_CAInvoiceCFO | view | from | CONSUMPTION | Rechnung |
| C_CANotDisputedInvcgDoc | view_entity | from | CONSUMPTION | Not disputed invoicing document |
| CRMS4_IU_I_CDH | view_entity | from | Convergent Invoice Document Header | |
| I_CABillPrntBillData | view | from | COMPOSITE | Rechnungsausgabe |
| I_CABillPrntInvcgDocHeader | view | from | COMPOSITE | Fakt.beleg für Rechnungsausgabe |
| I_CADisputedInvcgDoc | view_entity | inner | COMPOSITE | Disputed invoicing document |
| I_CAInvcgDocMassCreate | view | from | COMPOSITE | Abrechnungsauftrag (Mass) |
| R_CAInvcgDocumentTP | view_entity | from | TRANSACTIONAL | Invoicing Document - TP |
Fields (69)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BusinessPartner | BusinessPartner | 8 |
| KEY | CAInvoicingDocument | CAInvoicingDocument | 6 |
| _BusinessPartner | _BusinessPartner | 1 | |
| _CAApplicationArea | _CAApplicationArea | 1 | |
| _CAInvcgDocHeader | _CAInvcgDocHeader | 1 | |
| _ContractAccountHeader | _ContractAccountHeader | 1 | |
| AltvContractAcctForCollvBills | AltvContractAcctForCollvBills | 5 | |
| ApplicationForm | ApplicationForm | 5 | |
| BusinessPlace | BusinessPlace | 5 | |
| CAAmountInTransactionCurrency | CAAmountInTransactionCurrency | 5 | |
| CAApplicationArea | CAApplicationArea | 6 | |
| CACashDiscountDueDate | CACashDiscountDueDate | 5 | |
| CACashDiscountRate | CACashDiscountRate | 5 | |
| CAContract | CAContract | 6 | |
| CADunningCounter | CADunningCounter | 5 | |
| CAInvcgAdjustedDocument | CAInvcgAdjustedDocument | 3 | |
| CAInvcgAdjustmentDocument | CAInvcgAdjustmentDocument | 3 | |
| CAInvcgBaseDate | CAInvcgBaseDate | 6 | |
| CAInvcgBolloTaxPostStatus | CAInvcgBolloTaxPostStatus | 5 | |
| CAInvcgCategory | CAInvcgCategory | 5 | |
| CAInvcgCorrectionCategory | CAInvcgCorrectionCategory | 5 | |
| CAInvcgCreationDate | CAInvcgCreationDate | 5 | |
| CAInvcgCreationTime | CAInvcgCreationTime | 5 | |
| CAInvcgDocCreationMode | CAInvcgDocCreationMode | 5 | |
| CAInvcgDocExternal | CAInvcgDocExternal | 5 | |
| CAInvcgDocFormID | CAInvcgDocFormID | 2 | |
| CAInvcgDocHasChargeOrDiscItems | CAInvcgDocHasChargeOrDiscItems | 5 | |
| CAInvcgDocHasControlDoc | CAInvcgDocHasControlDoc | 6 | |
| CAInvcgDocHasObjectRelation | CAInvcgDocHasObjectRelation | 5 | |
| CAInvcgDocHasSEPAPreNotif | CAInvcgDocHasSEPAPreNotif | 5 | |
| CAInvcgDocInternalNumber | CAInvcgDocInternalNumber | 5 | |
| CAInvcgDocIsLockedForPrinting | CAInvcgDocIsLockedForPrinting | 6 | |
| CAInvcgDocIsPartOfList | CAInvcgDocIsPartOfList | 5 | |
| CAInvcgDocPeriodCategory | CAInvcgDocPeriodCategory | 5 | |
| CAInvcgDocPeriodDate | CAInvcgDocPeriodDate | 5 | |
| CAInvcgDocPeriodStartDate | CAInvcgDocPeriodStartDate | 5 | |
| CAInvcgDocumentPrintDate | CAInvcgDocumentPrintDate | 6 | |
| CAInvcgDocumentReversalReason | CAInvcgDocumentReversalReason | 5 | |
| CAInvcgDocumentType | CAInvcgDocumentType | 5 | |
| CAInvcgIsDocumentPosted | CAInvcgIsDocumentPosted | 5 | |
| CAInvcgIsDocumentPreliminary | CAInvcgIsDocumentPreliminary | 5 | |
| CAInvcgIsDocumentSimulated | CAInvcgIsDocumentSimulated | 5 | |
| CAInvcgMasterDataType | CAInvcgMasterDataType | 5 | |
| CAInvcgNmbrOfInvoicingDocItems | CAInvcgNmbrOfInvoicingDocItems | 5 | |
| CAInvcgPreliminaryCategory | CAInvcgPreliminaryCategory | 5 | |
| CAInvcgProcess | CAInvcgProcess | 5 | |
| CAInvcgReversalDocument | CAInvcgReversalDocument | 5 | |
| CAInvcgReversedDocument | CAInvcgReversedDocument | 5 | |
| CAInvcgTargetProcess | CAInvcgTargetProcess | 5 | |
| CAInvcgTechnicalDocumentType | CAInvcgTechnicalDocumentType | 5 | |
| CAInvcgType | CAInvcgType | 5 | |
| CAKeyIdentification | CAKeyIdentification | 5 | |
| CANetDueDate | CANetDueDate | 6 | |
| CAOfficialDocumentNumber | CAOfficialDocumentNumber | 5 | |
| CAPartnerSettlementRule | CAPartnerSettlementRule | 5 | |
| CAPaymentFormNumber | CAPaymentFormNumber | 5 | |
| CAPaymentMethod | CAPaymentMethod | 5 | |
| CAPostingDate | CAPostingDate | 5 | |
| CAPreliminaryInvcgDocStatus | CAPreliminaryInvcgDocStatus | 4 | |
| CAPrelimInvcgDocValue | CAPrelimInvcgDocValue | 4 | |
| CAReconciliationKey | CAReconciliationKey | 5 | |
| CASubApplication | CASubApplication | 5 | |
| CASubstituteDocumentNumber | CASubstituteDocumentNumber | 5 | |
| CompanyCode | CompanyCode | 6 | |
| ContractAccount | ContractAccount | 7 | |
| CreatedByUser | CreatedByUser | 5 | |
| DocumentDate | DocumentDate | 5 | |
| FormIDForAttachedPaymentMedium | FormIDForAttachedPaymentMedium | 5 | |
| TransactionCurrency | TransactionCurrency | 6 |
@AbapCatalog.sqlViewName: 'ICAINVDOC_H'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
usageType: {
serviceQuality: #B,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
},
representativeKey: 'CAInvoicingDocument',
supportedCapabilities: [
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET
]
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fakturierungsbelegkopf'
define view I_CAInvcgDocHeader
as select from dfkkinvdoc_h
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_ContractAccountHeader as _ContractAccountHeader on $projection.ContractAccount = _ContractAccountHeader.ContractAccount
association [0..1] to I_ContractAccountPartner as _ContractAccountPartner on $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
and $projection.ContractAccount = _ContractAccountPartner.ContractAccount
association [0..1] to I_ContractAccountHeader as _AltvContractAcctForCollvBills on $projection.AltvContractAcctForCollvBills = _AltvContractAcctForCollvBills.ContractAccount
association [1..1] to I_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
association [0..1] to I_CAInvcgDocHeader as _CAInvcgReversalDocument on $projection.CAInvcgReversalDocument = _CAInvcgReversalDocument.CAInvoicingDocument
association [0..1] to I_CAInvcgDocHeader as _CAInvcgReversedDocument on $projection.CAInvcgReversedDocument = _CAInvcgReversedDocument.CAInvoicingDocument
association [0..1] to I_Currency as _TransactionCurrency on $projection.TransactionCurrency = _TransactionCurrency.Currency
association [0..1] to I_CAInvcgPreliminaryCategory as _CAInvcgPreliminaryCategory on $projection.CAInvcgPreliminaryCategory = _CAInvcgPreliminaryCategory.CAInvcgPreliminaryCategory
association [0..1] to I_CAPreliminaryInvcgDocStatus as _CAPreliminaryInvcgDocStatus on $projection.CAPreliminaryInvcgDocStatus = _CAPreliminaryInvcgDocStatus.CAPreliminaryInvcgDocStatus
association [0..1] to I_CAInvcgDocReversalReason as _CAInvcgDocReversalReason on $projection.CAInvcgDocumentReversalReason = _CAInvcgDocReversalReason.CAInvcgDocumentReversalReason
association [0..1] to I_CAInvcgDocLockedforPrint as _CAInvcgDocLockedforPrint on $projection.CAInvcgDocIsLockedForPrinting = _CAInvcgDocLockedforPrint.CAInvcgDocIsLockedForPrinting
association [0..1] to I_CAInvcgProcess as _CAInvcgProcess on $projection.CAInvcgProcess = _CAInvcgProcess.CAInvcgProcess
and $projection.CAApplicationArea = _CAInvcgProcess.CAApplicationArea
association [0..1] to I_CAInvcgCategory as _CAInvcgCategory on $projection.CAInvcgCategory = _CAInvcgCategory.CAInvcgCategory
association [0..1] to I_CAInvcgType as _CAInvcgType on $projection.CAInvcgType = _CAInvcgType.CAInvcgType
and $projection.CAApplicationArea = _CAInvcgType.CAApplicationArea
association [0..1] to I_CAInvcgDocumentType as _CAInvcgDocumentType on $projection.CAInvcgDocumentType = _CAInvcgDocumentType.CAInvcgDocumentType
and $projection.CAApplicationArea = _CAInvcgDocumentType.CAApplicationArea
and _CAInvcgDocumentType.NameNumberRangeObject = 'FKKINVDOC'
association [0..1] to I_CASubApplication as _CASubApplication on $projection.CASubApplication = _CASubApplication.CASubApplication
association [0..1] to I_CAInvcgPeriodCat as _CAInvcgPeriodCat on $projection.CAInvcgDocPeriodCategory = _CAInvcgPeriodCat.CAInvcgPeriodCategory
association [0..1] to I_CAInvcgTargetProc as _CAInvcgTargetProc on $projection.CAInvcgTargetProcess = _CAInvcgTargetProc.CAInvcgTargetProcess
association [0..1] to I_CAApplicationArea as _CAApplicationArea on $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
association [0..1] to I_CAInvcgCorrectionCat as _CAInvcgCorrectionCat on $projection.CAInvcgCorrectionCategory = _CAInvcgCorrectionCat.CAInvcgCorrectionCategory
association [0..1] to I_CAInvcgDocChrgDiscItems as _CAInvcgDocChrgDiscItems on $projection.CAInvcgDocHasChargeOrDiscItems = _CAInvcgDocChrgDiscItems.CAInvcgDocHasChargeOrDiscItems
association [0..1] to I_CAInvcgDocCreationMode as _CAInvcgDocCreationMode on $projection.CAInvcgDocCreationMode = _CAInvcgDocCreationMode.CAInvcgDocCreationMode
association [0..1] to I_CAInvcgMasterDataType as _CAInvcgMasterDataType on $projection.CAInvcgMasterDataType = _CAInvcgMasterDataType.CAInvcgMasterDataType
association [0..1] to I_CAInvcgDocTechDocType as _CAInvcgDocTechDocType on $projection.CAInvcgTechnicalDocumentType = _CAInvcgDocTechDocType.CAInvcgTechnicalDocumentType
association [0..1] to I_CAInvcgDocPartOfList as _CAInvcgDocPartOfList on $projection.CAInvcgDocIsPartOfList = _CAInvcgDocPartOfList.CAInvcgDocIsPartOfList
association [0..1] to I_CAInvcgBolloTaxPostStatus as _CAInvcgBolloTaxPostStatus on $projection.CAInvcgBolloTaxPostStatus = _CAInvcgBolloTaxPostStatus.CAInvcgBolloTaxPostStatus
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_CAReconciliationKey as _CAReconciliationKey on $projection.CAReconciliationKey = _CAReconciliationKey.CAReconciliationKey
association [0..1] to I_CAProviderContractHeader as _ProviderContract on $projection.CASubApplication = 'P'
and $projection.CAContract = _ProviderContract.CAProviderContract
// extension
//association [0..1] to E_CAInvcgDocHeader as _Extension on $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument
{
key invdocno as CAInvoicingDocument,
@ObjectModel.foreignKey.association: '_CAApplicationArea'
applk as CAApplicationArea,
@ObjectModel.foreignKey.association: '_CAInvcgProcess'
inv_process as CAInvcgProcess,
@ObjectModel.foreignKey.association: '_CAInvcgType'
inv_type as CAInvcgType,
@ObjectModel.foreignKey.association: '_CAInvcgCategory'
inv_category as CAInvcgCategory,
@ObjectModel.foreignKey.association: '_CAInvcgDocTechDocType'
cast(techdoctype as techdoctype_gfn_kk preserving type) as CAInvcgTechnicalDocumentType,
@ObjectModel.foreignKey.association: '_CAInvcgTargetProc'
targprocess as CAInvcgTargetProcess,
@ObjectModel.foreignKey.association: '_BusinessPartner'
cast(gpart as bu_partner preserving type) as BusinessPartner,
@ObjectModel.foreignKey.association: '_ContractAccountHeader'
vkont as ContractAccount,
@ObjectModel.foreignKey.association: '_CAInvcgMasterDataType'
mdcat as CAInvcgMasterDataType,
@ObjectModel.foreignKey.association: '_AltvContractAcctForCollvBills'
abwvk as AltvContractAcctForCollvBills,
abwbl as CASubstituteDocumentNumber,
@Semantics.user.createdBy: true
crname as CreatedByUser,
@Semantics.systemDate.createdAt: true
crdate as CAInvcgCreationDate,
@Semantics.systemTime.createdAt: true
crtime as CAInvcgCreationTime,
@ObjectModel.foreignKey.association: '_CAInvcgDocCreationMode'
crmode as CAInvcgDocCreationMode,
recnum as CAInvcgNmbrOfInvoicingDocItems,
invrunno as CAInvcgDocInternalNumber,
@ObjectModel.foreignKey.association: '_CAReconciliationKey'
fikey as CAReconciliationKey,
budat as CAPostingDate,
bldat as DocumentDate,
faedn as CANetDueDate,
faeds as CACashDiscountDueDate,
sktpz as CACashDiscountRate,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
@Semantics.currencyCode: true
total_curr as TransactionCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
total_amt as CAAmountInTransactionCurrency,
invoiced as CAInvcgIsDocumentPosted,
simulated as CAInvcgIsDocumentSimulated,
cast(preliminary as inv_preliminary_gfn_kk preserving type) as CAInvcgIsDocumentPreliminary,
@ObjectModel.foreignKey.association: '_CAInvcgPreliminaryCategory'
cast(prlinv_cat as prlinv_cat_gfn_kk preserving type) as CAInvcgPreliminaryCategory,
prlinv_cnt as CAPrelimInvcgDocValue,
@ObjectModel.foreignKey.association: '_CAPreliminaryInvcgDocStatus'
cast(prlinv_status as prlinv_status_gfn_kk preserving type) as CAPreliminaryInvcgDocStatus,
@ObjectModel.foreignKey.association: '_CAInvcgDocReversalReason'
revreason as CAInvcgDocumentReversalReason,
@ObjectModel.foreignKey.association: '_CAInvcgReversalDocument'
reversaldoc as CAInvcgReversalDocument,
@ObjectModel.foreignKey.association: '_CAInvcgReversedDocument'
cast(reverseddoc as inv_reverseddoc_gfn_kk preserving type) as CAInvcgReversedDocument,
@ObjectModel.foreignKey.association: '_CAInvcgCorrectionCat'
cast(corrcat as corrcat_gfn_kk preserving type) as CAInvcgCorrectionCategory,
printdate as CAInvcgDocumentPrintDate,
@ObjectModel.foreignKey.association: '_CAInvcgDocLockedforPrint'
printlock as CAInvcgDocIsLockedForPrinting,
-- fkey in upper view (due to complexity)
pymet as CAPaymentMethod,
nrzas as CAPaymentFormNumber,
form_id as CAInvcgDocFormID,
formkey as ApplicationForm,
zlsch as FormIDForAttachedPaymentMedium,
@ObjectModel.foreignKey.association: '_CAInvcgDocumentType'
doctype as CAInvcgDocumentType,
exkid as CAKeyIdentification,
cast(exbel as exbel_no_conv_kk) as CAOfficialDocumentNumber,
ptsrl as CAPartnerSettlementRule,
@ObjectModel.foreignKey.association: '_CompanyCode'
bukrs as CompanyCode,
bupla as BusinessPlace,
vtref as CAContract,
@ObjectModel.foreignKey.association: '_CASubApplication'
subap as CASubApplication,
invoice_basedate as CAInvcgBaseDate,
@ObjectModel.foreignKey.association: '_CAInvcgPeriodCat'
invpercat as CAInvcgDocPeriodCategory,
invperiod as CAInvcgDocPeriodDate,
invperiod_from as CAInvcgDocPeriodStartDate,
mazae as CADunningCounter,
cast(chgdoc_ex as chgdoc_ex_gfn_kk preserving type) as CAInvcgDocHasChargeOrDiscItems,
cast(cfcsimulated as inv_cfcsimulated_gfn_kk preserving type) as CAInvcgDocHasControlDoc,
@ObjectModel.foreignKey.association: '_CAInvcgBolloTaxPostStatus'
bollotax as CAInvcgBolloTaxPostStatus,
@EndUserText.label: 'Subfakturierngsbeleg'
xsubinv as CAInvcgDocIsPartOfList,
@EndUserText.label: 'Objektrelationen vorhanden'
xinvdoc_x as CAInvcgDocHasObjectRelation,
sepa_prenot as CAInvcgDocHasSEPAPreNotif,
cast(ext_invdocno as ext_invdocno_gfn_kk preserving type) as CAInvcgDocExternal,
adjustmentdoc as CAInvcgAdjustmentDocument,
adjusteddoc as CAInvcgAdjustedDocument,
cast('FKKINV' as nrobj) as NameNumberRangeObject,
// Make association public
_BusinessPartner,
_ContractAccountHeader,
_ContractAccountPartner,
_AltvContractAcctForCollvBills,
_CAReconciliationKey,
_TransactionCurrency,
_CAInvcgPreliminaryCategory,
_CAPreliminaryInvcgDocStatus,
_CAInvcgProcess,
_CAInvcgType,
_CAInvcgCategory,
_CAInvcgDocTechDocType,
_CAInvcgTargetProc,
_CAInvcgMasterDataType,
_CAInvcgDocCreationMode,
_CAInvcgDocReversalReason,
_CAInvcgReversalDocument,
_CAInvcgReversedDocument,
_CAInvcgCorrectionCat,
_CAInvcgDocumentType,
_CAInvcgDocLockedforPrint,
_CAInvcgPeriodCat,
_CAInvcgDocChrgDiscItems,
_CAInvcgBolloTaxPostStatus,
_CAInvcgDocPartOfList,
_CompanyCode,
_CASubApplication,
_ProviderContract,
_CAInvcgDocHeader,
_CAApplicationArea
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKKINVDOC_H"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CAINVCGBOLLOTAXPOSTSTATUS",
"I_CAINVCGCATEGORY",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGDOCCHRGDISCITEMS",
"I_CAINVCGDOCCREATIONMODE",
"I_CAINVCGDOCLOCKEDFORPRINT",
"I_CAINVCGDOCPARTOFLIST",
"I_CAINVCGDOCREVERSALREASON",
"I_CAINVCGDOCTECHDOCTYPE",
"I_CAINVCGDOCUMENTTYPE",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGPERIODCAT",
"I_CAINVCGPRELIMINARYCATEGORY",
"I_CAINVCGPROCESS",
"I_CAINVCGTARGETPROC",
"I_CAINVCGTYPE",
"I_CAPRELIMINARYINVCGDOCSTATUS",
"I_CAPROVIDERCONTRACTHEADER",
"I_CARECONCILIATIONKEY",
"I_CASUBAPPLICATION",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/