@AbapCatalog.sqlViewName: 'CCAINVBILL_H'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #REQUIRED,
privilegedAssociations: [ '_CAInvcgUserContact' ]
}
@ObjectModel: {
usageType: {
serviceQuality: #D,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
}
}
@EndUserText.label: 'Abrechnungsbelegkopf anzeigen'
@Consumption.semanticObject: 'CABillgDocument'
define view C_CABillgDocHeader
as select from I_CABillgDocHeader as _CABillgDocHeader
// Value help
association [0..1] to C_CAInvcgUserContact as _CAInvcgUserContact on $projection.CreatedByUser = _CAInvcgUserContact.ContactCardID
{
//BILLDOCNO
key _CABillgDocHeader.CABillgDocument,
//INVDOCNO
_CABillgDocHeader.CAInvoicingDocument,
//GPART
_BusinessPartner.FirstName,
_BusinessPartner.LastName,
@UI.hidden: true
@Semantics: { name.givenName: true , contact.type: #PERSON }
_BusinessPartner.BusinessPartnerFullName,
cast( concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.StreetName,
_BusinessPartner._CurrentDefaultAddress._StandardAddress.HouseNumber, 1)
as adress_gfn_kk preserving type ) as StreetName,
cast( concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.PostalCode,
_BusinessPartner._CurrentDefaultAddress._StandardAddress.CityName, 1)
as city_gfn_kk preserving type ) as AddressCityName,
cast( _BusinessPartner._CurrentDefaultAddress._StandardAddress._Country._Text[1: Language=$session.system_language].CountryName
as country_gfn_kk preserving type ) as CountryName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner' }}]
@Consumption.semanticObject: 'CAContractPartner'
_CABillgDocHeader.BusinessPartner,
//VKONT
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount' }}]
@Consumption.semanticObject: 'ContractAccount'
_CABillgDocHeader.ContractAccount,
_ContractAccountHeader.ContractAccountName,
//bill_type
_CABillgDocHeader.CABillgType,
//date_from
@Consumption.filter.selectionType: #INTERVAL
_CABillgDocHeader.CABillgDocPeriodStartDate,
//date_to
_CABillgDocHeader.CABillgDocPeriodEndDate,
//crdate
@Consumption.filter.selectionType: #INTERVAL
_CABillgDocHeader.CABillgDocCreationDate,
//revreason
_CABillgDocHeader.CABillgDocumentReversalReason,
//simulated
_CABillgDocHeader.CABillgIsDocumentSimulated,
//refdocno
_CABillgDocHeader.CABillgDocumentExternal,
//log_system
_CABillgDocHeader.LogicalSystem,
//applk
_CABillgDocHeader.CAApplicationArea,
//srcprocess
_CABillgDocHeader.CABillgDocOriginProcess,
//srcdoctype
_CABillgDocHeader.CAInvcgSourceDocumentType,
//techdoctype
_CABillgDocHeader.CAInvcgTechnicalDocumentType,
//doctype
_CABillgDocHeader.CAInvcgDocumentType,
//targprocess
_CABillgDocHeader.CAInvcgTargetProcess,
//mdcat
_CABillgDocHeader.CAInvcgMasterDataType,
//gpart_inv
_CABillgDocHeader.CAInvcgAltvBusinessPartner,
//vkont_inv
_CABillgDocHeader.CAInvcgAltvContractAccount,
//bill_basedate
_CABillgDocHeader.CABillgBaseDate,
//bill_curr
_CABillgDocHeader.CABillgCurrency,
//inv_curr
_CABillgDocHeader.CAInvcgCurrency,
//tax_det_type
_CABillgDocHeader.CATaxDetnType,
//tax_date_type
_CABillgDocHeader.CATaxDateType,
//inv_category
_CABillgDocHeader.CAInvcgCategory,
//separate_inv
_CABillgDocHeader.CAInvcgControlOfInvoicingUnit,
//invoice_first
_CABillgDocHeader.CAInvcgFirstDate,
//reversaldoc
_CABillgDocHeader.CABillgReversalDocument,
//reverseddoc
_CABillgDocHeader.CABillgReversedDocument,
//adjustmentdoc
_CABillgDocHeader.CABillgAdjustmentDocument,
//adjusteddoc
_CABillgDocHeader.CABillgAdjustedDocument,
//corrcat
_CABillgDocHeader.CAInvcgCorrectionCategory,
//trigdeleted
_CABillgDocHeader.CaInvcgIsOrderDeleted,
//xinfbill
_CABillgDocHeader.CABillgHasAdditionalInvoice,
//xbillac
_CABillgDocHeader.CAInvcgIsAccrualPostingRlvt,
//invlock
_CABillgDocHeader.CABillgLockedForInvoicing,
//add_group
_CABillgDocHeader.CABillgGrpgOfAdditionalItems,
//xinvbill_x
_CABillgDocHeader.CABillgDocHasRefObjects,
//recnum
_CABillgDocHeader.CABillgDocumentNumberOfItems,
//crname
_CABillgDocHeader.CreatedByUser,
//crtime
_CABillgDocHeader.CABillgDocCreationTime,
//billrunno
_CABillgDocHeader.CABillgDocInternalNumber,
//bill_process
_CABillgDocHeader.CABillgProcess,
//prepaid_incl
_CABillgDocHeader.CABillgDocHasPrepaidItems,
//pprefill_incl
_CABillgDocHeader.CABillgDocHasRefillItems,
//revrec_incl
_CABillgDocHeader.CABillgDocHasRevnRecgnItems,
//ptsrl
_CABillgDocHeader.CAPartnerSettlementRule,
//invstatus
_CABillgDocHeader.CABillgDocumentInvcgStatus,
//invcrdate
_CABillgDocHeader.CAInvcgCreationDate,
//keypp
_CABillgDocHeader.CASubAreaForParallelization,
//altmd_orig_incl
_CABillgDocHeader.CAAltvMDOriginalIsIncluded,
_CAInvcgDocumentType._CAInvcgDocumentTypeText[1: Language=$session.system_language].CAInvcgDocumentTypeText,
_CABillgDocOriginProcess._CABillgDocOriginProcessText[1: Language=$session.system_language].CABillgDocOriginProcessText,
_CAInvcgTargetProc._CAInvcgTargetProcText[1: Language=$session.system_language].CAInvcgTargetProcText,
_CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,
_CABillgProcess._CABillgProcessText[1: Language=$session.system_language].CABillgProcessText,
_CABillgType._CABillgTypeText[1: Language=$session.system_language].CABillgTypeText,
_CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText[1: Language=$session.system_language].CAInvcgDocTechDocTypeText,
_CABillgDocReversalReason._CABillgDocReversalReasonText[1: Language=$session.system_language].CABillgDocReversalReasonText,
_CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,
_CATaxDetnType._CATaxDetnTypeText[1: Language=$session.system_language].CATaxDetnTypeText,
_CATaxDateType._CATaxDateTypeText[1: Language=$session.system_language].CATaxDateTypeText,
_CAInvcgControlOfInvcgUnit._CAInvcgControlOfInvcgUnitTxt[1: Language=$session.system_language].CAInvcgControlOfInvcgUnitTxt,
_CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,
_CABillgExistsAddInvcg._CABillgExistsAddInvcgText[1: Language=$session.system_language].CABillgAdditionalInvoiceText,
_CABillgLockedForInvcg._CABillgLockedForInvcgText[1: Language=$session.system_language].CABillgLockedForInvcgText,
_CABillgDocInvcgStatus._CABillgDocInvcgStatusText[1: Language=$session.system_language].CABillgDocumentInvcgStatusText,
_CAInvcgSourceDocType._CAInvcgSourceDocTypeText[1: Language=$session.system_language].CAInvcgSourceDocTypeText,
// Make association public
_ContractAccountPartner,
_BusinessPartner,
_ContractAccountHeader,
_CAInvcgAltvBusinessPartner,
_CAInvcgAltvContractAccount,
_CABillgReversalDocument,
_CABillgReversedDocument,
_CABillgAdjustedDocument,
_CABillgAdjustmentDocument,
_CAApplicationArea,
_CABillgCurrency,
_CAInvcgCurrency,
_CABillgDocOriginProcess,
_CAInvcgSourceDocType,
_CAInvcgTargetProc,
_CAInvcgCategory,
_CABillgProcess,
_CABillgType,
_CAInvcgDocTechDocType,
_CAInvcgMasterDataType,
_CATaxDetnType,
_CATaxDateType,
_CAInvcgDocumentType,
_CAInvcgControlOfInvcgUnit,
_CAInvcgCorrectionCat,
_CABillgExistsAddInvcg,
_CABillgLockedForInvcg,
_CABillgDocInvcgStatus,
_CABillgDocReversalReason,
_CAInvcgDocHeader,
_CAInvcgUserContact,
@UI.hidden: true
concat('00000000', _CABillgDocHeader.CABillgDocument ) as CAInvcgSourceDocumentNumber,
@UI.hidden: true
'INVBI' as CAInvcgSourceDocumentCat
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_CABILLGDOCHEADER",
"I_CABILLGDOCINVCGSTATUS",
"I_CABILLGDOCINVCGSTATUSTEXT",
"I_CABILLGDOCORIGINPROCESS",
"I_CABILLGDOCORIGINPROCESSTEXT",
"I_CABILLGDOCREVERSALREASON",
"I_CABILLGDOCREVERSALREASONTEXT",
"I_CABILLGEXISTSADDINVCG",
"I_CABILLGEXISTSADDINVCGTEXT",
"I_CABILLGLOCKEDFORINVCG",
"I_CABILLGLOCKEDFORINVCGTEXT",
"I_CABILLGPROCESS",
"I_CABILLGPROCESSTEXT",
"I_CABILLGTYPE",
"I_CABILLGTYPETEXT",
"I_CAINVCGCATEGORY",
"I_CAINVCGCATEGORYTEXT",
"I_CAINVCGCONTROLOFINVCGUNIT",
"I_CAINVCGCONTROLOFINVCGUNITTXT",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGCORRECTIONCATTEXT",
"I_CAINVCGDOCTECHDOCTYPE",
"I_CAINVCGDOCTECHDOCTYPETEXT",
"I_CAINVCGDOCUMENTTYPE",
"I_CAINVCGDOCUMENTTYPETEXT",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGMASTERDATATYPETEXT",
"I_CAINVCGSOURCEDOCTYPE",
"I_CAINVCGSOURCEDOCTYPETEXT",
"I_CAINVCGTARGETPROC",
"I_CAINVCGTARGETPROCTEXT",
"I_CATAXDATETYPE",
"I_CATAXDATETYPETEXT",
"I_CATAXDETNTYPE",
"I_CATAXDETNTYPETEXT",
"I_CONTRACTACCOUNTHEADER",
"I_COUNTRY",
"I_COUNTRYTEXT"
],
"ASSOCIATED":
[
"C_CAINVCGUSERCONTACT",
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CABILLGDOCHEADER",
"I_CABILLGDOCINVCGSTATUS",
"I_CABILLGDOCORIGINPROCESS",
"I_CABILLGDOCREVERSALREASON",
"I_CABILLGEXISTSADDINVCG",
"I_CABILLGLOCKEDFORINVCG",
"I_CABILLGPROCESS",
"I_CABILLGTYPE",
"I_CAINVCGCATEGORY",
"I_CAINVCGCONTROLOFINVCGUNIT",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGDOCHEADER",
"I_CAINVCGDOCTECHDOCTYPE",
"I_CAINVCGDOCUMENTTYPE",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGSOURCEDOCTYPE",
"I_CAINVCGTARGETPROC",
"I_CATAXDATETYPE",
"I_CATAXDETNTYPE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[
"I_CABILLGDOCHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/