C_BudgetPeriod_ObjP

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CBUDGETPDOBJP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Additional Selection - Budget Period'
@UI.headerInfo: {
    typeName: 'Budget Period',    ---- App name (mandatory)
    typeNamePlural: 'Budget Periods',   ---- App name plural (mandatory)
    
    title: {
        value:'BudgetPeriod'      ---- Title of the App
    },
    
    description: {
        value:'BudgetPeriodName'  ---- Description of the App
    }
}

define view C_BudgetPeriod_ObjP
  as select from I_BudgetPeriod


  association [0..*] to C_FundToBudgetPeriod          as _FundToBP            on $projection.BudgetPeriod = _FundToBP.BudgetPeriod

  association [0..*] to C_FixedAssetsForFundsMgmt     as _FixedAsset          on $projection.BudgetPeriod = _FixedAsset.BudgetPeriod

  association [0..*] to C_BudDocItemForObjP           as _BudgetEntryDocument on $projection.BudgetPeriod = _BudgetEntryDocument.BudgetedBudgetPeriod

  association [0..*] to C_EarmarkedFundsItemForObjP   as _EarmarkedFundsItem  on $projection.BudgetPeriod = _EarmarkedFundsItem.BudgetPeriod

  association [0..*] to C_PurchaseOrderByFMAA         as _PurchaseOrder       on $projection.BudgetPeriod = _PurchaseOrder.PostedBudgetPeriod

  association [0..*] to C_PurchaseRequisitionByFMAA   as _PurchaseRequisition on $projection.BudgetPeriod = _PurchaseRequisition.PostedBudgetPeriod

  association [0..*] to C_JrnlEntrItmByLeadingLdgr_FM as _AccountingLine      on _AccountingLine.BudgetPeriod = $projection.BudgetPeriod

  association [0..*] to C_SetleafForBPObjp            as _Sets                on _Sets.SetClass               = '0114'
                                                                              and $projection.BudgetPeriod    = _Sets.BudgetPeriod

{
@EndUserText.label: 'Budget Period'
      @UI.lineItem: [{
             position: 10,
             importance: #HIGH }]

  key I_BudgetPeriod.BudgetPeriod,
      @EndUserText.label: 'Validity Start Date'
      @UI:{ fieldGroup: {qualifier: 'Validity', position: 10, importance: #HIGH} }
   
      @UI.lineItem: [{
             position: 30,
             importance: #HIGH }]
      @Consumption.filter.selectionType: #INTERVAL       
      I_BudgetPeriod.ValidityStartDate,
      @UI:{ fieldGroup: {qualifier: 'Validity', position: 20, importance: #HIGH} }
      @EndUserText.label: 'Validity End Date'
      @UI.lineItem: [{
             position: 40,
             importance: #HIGH }]
      @Consumption.filter.selectionType: #INTERVAL       
      I_BudgetPeriod.ValidityEndDate,
      @EndUserText.label: 'Authorization Group'
      @UI:{ fieldGroup: {qualifier: 'General Information', position: 10, importance: #HIGH} }
    
      @UI.lineItem: [{
             position: 40,
             importance: #HIGH }]
      I_BudgetPeriod.BudgetPeriodAuthznGrp,
      @EndUserText.label: 'Expiration Date'
 
      @UI:{ fieldGroup: {qualifier: 'Validity', position: 30, importance: #HIGH} }   
      @Consumption.filter.selectionType: #INTERVAL    
      I_BudgetPeriod.BudgetPeriodExpirationDate,
      @EndUserText.label: 'Reversal Date'
      @UI:{ fieldGroup: {qualifier: 'Validity', position: 40, importance: #HIGH} }
      @Consumption.filter.selectionType: #INTERVAL
      I_BudgetPeriod.BudgetPeriodReversalDate,
      @EndUserText.label: 'Created By'
      @UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 10, importance: #HIGH} }
      I_BudgetPeriod.CreatedByUser,
      @EndUserText.label: 'Creation Date'
      @UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 20, importance: #HIGH} }
      @Consumption.filter.selectionType: #INTERVAL
      I_BudgetPeriod.CreationDate,
      @EndUserText.label: 'Changed By'
      @UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 30, importance: #HIGH} }
      I_BudgetPeriod.LastChangeUser,
      @EndUserText.label: 'Changed On'
      @UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 40, importance: #HIGH} }
      @Consumption.filter.selectionType: #INTERVAL
      I_BudgetPeriod.LastChangeDate,

      //Text

      @EndUserText.label: 'Budget Period Name'
       @UI.lineItem: [{
             position: 20,
             importance: #HIGH }]
      _Text[Language = $session.system_language].BudgetPeriodName,

      //Facet Funds AoF

      _FundToBP,

      //Facet Fixed Assests

      _FixedAsset,

      //Facet Budget Entry Document

      _BudgetEntryDocument,

      //Earmarked Funds

      _EarmarkedFundsItem,

      //Facet Purchase Order

      _PurchaseOrder,
      
      //Facet Purchase Requisition

      _PurchaseRequisition,

      //Facet Accounting Document

      _AccountingLine,
      
      //Sets

      _Sets

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUDGETPERIOD",
"I_BUDGETPERIODTEXT"
],
"ASSOCIATED":
[
"C_BUDDOCITEMFOROBJP",
"C_EARMARKEDFUNDSITEMFOROBJP",
"C_FIXEDASSETSFORFUNDSMGMT",
"C_FUNDTOBUDGETPERIOD",
"C_JRNLENTRITMBYLEADINGLDGR_FM",
"C_PURCHASEORDERBYFMAA",
"C_PURCHASEREQUISITIONBYFMAA",
"C_SETLEAFFORBPOBJP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/