A_WorkCenters

@AbapCatalog.sqlViewName: 'AWORKCENTER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Header'
@VDM.viewType: #COMPOSITE
@AccessControl.privilegedAssociations: ['_WorkCenterResponsible']
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
define view A_WorkCenters
  as select from I_WorkCenter as WorkCenter
  association [1..1] to A_WorkCenterCapacity          as _Capacity              on  $projection.CapacityInternalID = _Capacity.CapacityInternalID

  association [0..*] to A_WorkCenterDayOperation      as _WorkCenterTodayOp     on  $projection.WorkCenterInternalID              = _WorkCenterTodayOp.WorkCenterInternalID
                                                                                and _WorkCenterTodayOp.ManufacturingOrderCategory = '10'
  association [0..*] to A_WorkCenterPipeLineOperation as _WorkCenterQueuingOp   on  $projection.WorkCenterInternalID                = _WorkCenterQueuingOp.WorkCenterInternalID
                                                                                and _WorkCenterQueuingOp.ManufacturingOrderCategory = '10'
  association [0..1] to A_WorkCenterResponsible       as _WorkCenterResponsible on  $projection.Plant                 = _WorkCenterResponsible.Plant
                                                                                and $projection.WorkCenterResponsible = _WorkCenterResponsible.WorkCenterResponsible
  association [1..*] to A_WorkCenterAllCapacity       as _WorkCenterCapacity    on  $projection.WorkCenterInternalID = _WorkCenterCapacity.WorkCenterInternalID
                                                                                and $projection.WorkCenterTypeCode   = _WorkCenterCapacity.WorkCenterTypeCode
  association [0..*] to A_WorkCenterAllCapacity_2     as _WorkCenterAllCapacity on  $projection.WorkCenterInternalID = _WorkCenterAllCapacity.WorkCenterInternalID
                                                                                and $projection.WorkCenterTypeCode   = _WorkCenterAllCapacity.WorkCenterTypeCode
  association [1..*] to A_WorkCenterDescription       as _WorkCenterDescription on  $projection.WorkCenterInternalID = _WorkCenterDescription.WorkCenterInternalID
                                                                                and $projection.WorkCenterTypeCode   = _WorkCenterDescription.WorkCenterTypeCode
  association [0..*] to A_WorkCenterCostCenter        as _WorkCenterCostCenter  on  $projection.WorkCenterInternalID = _WorkCenterCostCenter.WorkCenterInternalID
                                                                                and $projection.WorkCenterTypeCode   = _WorkCenterCostCenter.WorkCenterTypeCode
{
                    //General Information

                    @EndUserText.label:'Work Center Internal Id'
  key               WorkCenter.WorkCenterInternalID,
                    @EndUserText.label:'Work Center Type Code'
  key               WorkCenterTypeCode,
                    WorkCenter,
                    _Text[1:Language=$session.system_language].WorkCenterText as WorkCenterDesc,
                    Plant,
                    WorkCenterCategoryCode,
                    WorkCenterResponsible,
                    @Semantics.text: true
                    _WorkCenterResponsible.WorkCenterResponsibleName,
                    SupplyArea,
                    WorkCenterUsage,
                    CapacityInternalID,

                    WorkCenterIsToBeDeleted,

                    ValidityStartDate,
                    ValidityEndDate,

                    WorkCenterFormulaParam1,
                    WorkCenterFormulaParam2,
                    WorkCenterFormulaParam3,
                    WorkCenterFormulaParam4,
                    WorkCenterFormulaParam5,
                    WorkCenterFormulaParam6,

                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit1'
                    WorkCenterFmlaParamValue1,
                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit2'
                    WorkCenterFmlaParamValue2,
                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit3'
                    WorkCenterFmlaParamValue3,
                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit4'
                    WorkCenterFmlaParamValue4,
                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit5'
                    WorkCenterFmlaParamValue5,
                    @Semantics.quantity.unitOfMeasure : 'WorkCenterFmlaParamUnit6'
                    WorkCenterFmlaParamValue6,

                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit1,
                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit2,
                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit3,
                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit4,
                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit5,
                    @Semantics.unitOfMeasure: true
                    WorkCenterFmlaParamUnit6,

                    StandardWorkFormulaParamGroup,
                    WrkCtrStdValMaintRule1,
                    WrkCtrStdValMaintRule2,
                    WrkCtrStdValMaintRule3,
                    WrkCtrStdValMaintRule4,
                    WrkCtrStdValMaintRule5,
                    WrkCtrStdValMaintRule6,

                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit1,
                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit2,
                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit3,
                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit4,
                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit5,
                    @Semantics.unitOfMeasure: true
                    WorkCenterStandardWorkQtyUnit6,

                    OperationControlProfile,
                    MatlCompIsMarkedForBackflush,
                    WorkCenterLocation,
                    WorkCenterLocationGroup,

                    WrkCtrSetupSchedgFmla,
                    WrkCtrProcgSchedgFmla,
                    WrkCtrTeardownSchedgFmla,
                    WrkCtrIntProcgSchedgFmla,

                    WorkCenterLastChangeDateTime,
                    //End of new fields


                    _Capacity,
                    _WorkCenterTodayOp,
                    _WorkCenterQueuingOp,
                    _WorkCenterResponsible,
                    _WorkCenterCapacity,
                    _WorkCenterAllCapacity,
                    _WorkCenterDescription,
                    _WorkCenterCostCenter

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_WORKCENTERRESPONSIBLE",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"A_WORKCENTERALLCAPACITY",
"A_WORKCENTERALLCAPACITY_2",
"A_WORKCENTERCAPACITY",
"A_WORKCENTERCOSTCENTER",
"A_WORKCENTERDAYOPERATION",
"A_WORKCENTERDESCRIPTION",
"A_WORKCENTERPIPELINEOPERATION",
"A_WORKCENTERRESPONSIBLE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/