A_WorkCenterAllCapacity_2

@AbapCatalog.sqlViewName: 'AWORKCTRALLCAP2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Capacity Assignment Version 2'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
define view A_WorkCenterAllCapacity_2
  as select from I_WorkCenterCapacity
  association [1..1] to A_WorkCenterCapacity    as _Capacity            on  $projection.CapacityInternalID = _Capacity.CapacityInternalID
  association [0..*] to A_WorkCenterCapDayOp    as _WorkCenterTodayOp   on  $projection.WorkCenterInternalID = _WorkCenterTodayOp.WorkCenterInternalID
  association [0..*] to A_WorkCenterCapPplineOp as _WorkCenterQueuingOp on  $projection.WorkCenterInternalID = _WorkCenterQueuingOp.WorkCenterInternalID
  association [1..1] to A_WorkCenters           as _WorkCenter          on  $projection.WorkCenterTypeCode   = _WorkCenter.WorkCenterTypeCode
                                                                        and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
{
  key WorkCenterInternalID,
  key WorkCenterTypeCode,
  key CapacityCategoryAllocation,
      Plant,
      WorkCenterCategoryCode,
      WorkCenter,
      CapacityInternalID,
      SetupCapRequirementFormula,
      ProcgCapRequirementFormula,
      TeardownCapRequirementFormula,
      OtherCapRequirementFormula,
      case when _WorkCenter.WorkCenterLastChangeDateTime is null then
       cast(dats_tims_to_tstmp(cast('20190101' as dats), cast('120000'as tims), 'UTC', $session.client, 'NULL') as cr_lastchange_datetime)
       else _WorkCenter.WorkCenterLastChangeDateTime end as WorkCenterLastChangeDateTime,
      _Capacity,
      _WorkCenterTodayOp,
      _WorkCenterQueuingOp
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_WORKCENTERS",
"I_WORKCENTERCAPACITY"
],
"ASSOCIATED":
[
"A_WORKCENTERCAPACITY",
"A_WORKCENTERCAPDAYOP",
"A_WORKCENTERCAPPPLINEOP",
"A_WORKCENTERS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/