A_VMSVehicle

@AbapCatalog.sqlViewName: 'AVMSVEHICLE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Vehicle Details'
@ObjectModel.usageType.serviceQuality : #C
@ObjectModel.usageType.sizeCategory : #XXL
@ObjectModel.usageType.dataClass : #MIXED
@VDM.viewType: #COMPOSITE
@AccessControl.privilegedAssociations : ['_VMSVehicleHistory' ,'_VMSVehicleIncomingInvoice','_VMSVehicleInvoice','_VMSVehiclePurchaseOrder','_VMSVehicleSalesOrder']
@Metadata.ignorePropagatedAnnotations:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define root view A_VMSVehicle
  as select from I_VMSVehicle
    inner join   I_SAPClient as _SAPClient on _SAPClient.sapclient = $session.client
  association [1..1] to E_VMSVehicle                 as _Extension                     on  _Extension.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [1..*] to A_VMSVehicleInvoice          as _VMSVehicleInvoice             on  _VMSVehicleInvoice.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [1..*] to A_VMSVehicleIncomingInvoice  as _VMSVehicleIncomingInvoice     on  _VMSVehicleIncomingInvoice.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [1..*] to A_VMSVehicleToEquipment      as _VMSVehicleToEquipment         on  _VMSVehicleToEquipment.InstalledBaseComponent = $projection.ConfigurationNumber
                                                                                       and $projection.Material                          = _VMSVehicleToEquipment.ClfnObjectID
  association [1..*] to A_VMSVehicleSalesOrder       as _VMSVehicleSalesOrder          on  _VMSVehicleSalesOrder.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [1..*] to A_VMSVehiclePurchaseOrder    as _VMSVehiclePurchaseOrder       on  _VMSVehiclePurchaseOrder.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [1..*] to A_VMSVehicleHistory          as _VMSVehicleHistory             on  _VMSVehicleHistory.VMSVehicleUUID = $projection.VMSVehicleUUID
  association [0..1] to A_VMSVehicleLocation         as _VMSVehicleLocation            on  I_VMSVehicle.VMSVehicleLocation = _VMSVehicleLocation.AddressNumber
                                                                                            and _VMSVehicleLocation.AddressNumber <> ' '
  association [1..*] to A_VMSVehicleStatusText       as _VMSVehiclePrimaryStatusText   on  _VMSVehiclePrimaryStatusText.VMSVehicleStatus = $projection.VMSVehiclePrimaryStatus
  association [1..*] to A_VMSVehicleStatusText       as _VMSVehicleSecondaryStatusText on  _VMSVehicleSecondaryStatusText.VMSVehicleStatus = $projection.VMSVehicleSecondaryStatus
  association [1..*] to A_VMSVehicleAvailabilityText as _VMSVehicleAvailabilityText    on  _VMSVehicleAvailabilityText.VMSVehicleAvailabilityStatus = $projection.VMSVehicleAvailabilityStatus
  association [1..*] to A_VMSVehicleCampaignText     as _VMSVehCampaignText            on  _VMSVehCampaignText.VMSVehicleSalesCampaign = $projection.VMSVehicleSalesCampaign
  association [1..*] to A_VMSVehicleSearchAreaText   as _VMSVehicleSearchAreaText      on  _VMSVehicleSearchAreaText.VMSVehicleSearchArea = $projection.VMSVehicleSearchArea
  association [1..*] to A_VMSVehicleSharingLevelText as _VMSVehSharingLevelText        on  _VMSVehSharingLevelText.VMSVehicleSharingLevel = $projection.VMSVehicleSharingLevel
  association [1..*] to A_VMSVehicleUsageStatusText  as _VMSVehUsageStatusText         on  _VMSVehUsageStatusText.VMSVehicleUsageStatus = $projection.VMSVehicleUsageStatus
  association [1..*] to A_VMSVehicleLocationText     as _LocationText                  on  $projection.vmsvehiclelocation = _LocationText.VMSVehicleLocation
  association        to A_Plant                      as _plant                         on  _plant.Plant = $projection.Plant
  association        to A_StorageLocation            as _storagelocation               on  _storagelocation.Plant           = $projection.Plant
                                                                                       and _storagelocation.StorageLocation = $projection.StorageLocation
  association [1..1] to A_Customer                   as _Customer                      on  $projection.VMSVehicleCustomer = _Customer.Customer
  association [1..1] to A_Customer                   as _OrderingParty                 on  $projection.VMSVehicleOrderingParty = _OrderingParty.Customer
  association [1..1] to A_Supplier                   as _Supplier                      on  $projection.ReferenceVendor = _Supplier.Supplier
  association [1..1] to A_BusinessPartner            as _Partner                       on  $projection.VMSVehicleEndCustomer = _Partner.BusinessPartner
{
  key VMSVehicleUUID,
      Material,
      VMSDigitalVehicleHubModel,
      VMSVehicleInternalID,
      ReferenceVendor,
      VMSVehicleBatch,
      Equipment,
      VMSVehicleActionDocType,
      @ObjectModel.text.element: ['PlantName','StorageLocationName' ]
      Plant,
      @Semantics.text:true
      _plant.PlantName,
      StorageLocation,
      @Semantics.text:true
      _storagelocation.StorageLocationName,
      ValuationType,
      ConfigurationNumber,
      VMSVehiclePrimActionControl,
      @ObjectModel.text.association: '_VMSVehiclePrimaryStatusText'
      VMSVehiclePrimaryStatus,
      VMSVehiclePrimStatusDateTime,
      VMSVehicleSecdryActionControl,
      @ObjectModel.text.association: '_VMSVehicleSecondaryStatusText'
      VMSVehicleSecondaryStatus,
      VMSVehicleSecdryStatusDateTime,
      VMSVehicleConfdDelivDateTime,
      VMSVehicleProductionDateTime,
      VMSVehiclePlndDelivDateTime,
      VMSVehicleIsArchived,
      VehicleIdentificationNumber,
      VMSVehicleExternalID,
      @ObjectModel.text.association: '_VMSVehicleAvailabilityText'
      VMSVehicleAvailabilityStatus,
      VMSVehicleIsVisible,
      @ObjectModel.text.association : '_LocationText'
      _VMSVehicleLocation.VMSVehicleLocation ,
      VMSVehicleCustomer,
      VMSVehicleEndCustomer,
      CreatedByUserName,
      @ObjectModel.text.association: '_VMSVehUsageStatusText'
      VMSVehicleUsageStatus,
      @ObjectModel.text.association: '_VMSVehCampaignText'
      VMSVehicleSalesCampaign,
      @Semantics.quantity.unitOfMeasure: 'VMSVehicleMileageUsageUnit'
      VMSVehicleMileageQuantity,
      VMSVehicleMileageUsageUnit,
      VMSVehicleRegistrationDate,
      @ObjectModel.text.association: '_VMSVehicleSearchAreaText'
      VMSVehicleSearchArea,
      VMSVehicleOrderingParty,
      @Semantics.amount.currencyCode : 'VMSVehiclePriceCrcy'
      VMSVehGrossPrcAmtInVehPrcCrcy,
      @Semantics.currencyCode: true
      VMSVehiclePriceCrcy,
      @ObjectModel.text.association: '_VMSVehSharingLevelText'
      VMSVehicleSharingLevel,
      VMSVehicleIsUsed,
      _SAPClient.LogicalSystem,
      _VMSVehicleInvoice,
      _VMSVehicleIncomingInvoice,
      _VMSVehicleToEquipment,
      _VMSVehicleSalesOrder,
      _VMSVehiclePurchaseOrder,
      _VMSVehicleHistory,
      @Consumption.hidden: true
      _VMSVehiclePrimaryStatusText,
      @Consumption.hidden: true
      _VMSVehicleSecondaryStatusText,
      @Consumption.hidden: true
      _VMSVehicleAvailabilityText,
      @Consumption.hidden: true
      _VMSVehCampaignText,
      @Consumption.hidden: true
      _VMSVehicleSearchAreaText,
      @Consumption.hidden: true
      _VMSVehSharingLevelText,
      @Consumption.hidden: true
      _VMSVehUsageStatusText,
      @Consumption.hidden: true
      _LocationText,
      @Consumption.hidden: true
      _Customer,
      @Consumption.hidden: true
      _OrderingParty,
      @Consumption.hidden: true
      _Supplier,
      @Consumption.hidden: true
      _Partner
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_PLANT",
"A_STORAGELOCATION",
"A_VMSVEHICLELOCATION",
"I_SAPCLIENT",
"I_VMSVEHICLE"
],
"ASSOCIATED":
[
"A_BUSINESSPARTNER",
"A_CUSTOMER",
"A_PLANT",
"A_STORAGELOCATION",
"A_SUPPLIER",
"A_VMSVEHICLEAVAILABILITYTEXT",
"A_VMSVEHICLECAMPAIGNTEXT",
"A_VMSVEHICLEHISTORY",
"A_VMSVEHICLEINCOMINGINVOICE",
"A_VMSVEHICLEINVOICE",
"A_VMSVEHICLELOCATION",
"A_VMSVEHICLELOCATIONTEXT",
"A_VMSVEHICLEPURCHASEORDER",
"A_VMSVEHICLESALESORDER",
"A_VMSVEHICLESEARCHAREATEXT",
"A_VMSVEHICLESHARINGLEVELTEXT",
"A_VMSVEHICLESTATUSTEXT",
"A_VMSVEHICLETOEQUIPMENT",
"A_VMSVEHICLEUSAGESTATUSTEXT",
"E_VMSVEHICLE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/