A_BusinessPartner

@AbapCatalog.sqlViewName: 'ABUSINESSPARTNER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Business Partner'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled:true
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API

define view A_BusinessPartner as select from I_BusinessPartner

  association [0..1] to E_BP_D as _PartnerExtension on $projection.BusinessPartner = _PartnerExtension.BusinessPartner

  association [0..1] to I_CustomerToBusinessPartner as _CustomerToBusinessPartner on I_BusinessPartner.BusinessPartnerUUID = _CustomerToBusinessPartner.BusinessPartnerUUID

  association [0..1] to I_SupplierToBusinessPartner as _SupplierToBusinessPartner on I_BusinessPartner.BusinessPartnerUUID = _SupplierToBusinessPartner.BusinessPartnerUUID

  association [0..1] to A_Customer as _Customer on $projection.customer = _Customer.Customer

  association [0..1] to A_Supplier as _Supplier on $projection.supplier = _Supplier.Supplier

  association [0..*] to A_BusinessPartnerAddress as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner

  association [0..*] to A_BusinessPartnerRole as _BusinessPartnerRole on $projection.BusinessPartner = _BusinessPartnerRole.BusinessPartner

  association [0..*] to A_BusinessPartnerTaxNumber as _BusinessPartnerTax on $projection.BusinessPartner = _BusinessPartnerTax.BusinessPartner

  association [0..*] to A_BusinessPartnerBank as _BusinessPartnerBank on $projection.BusinessPartner = _BusinessPartnerBank.BusinessPartner

  association [0..*] to A_BuPaIdentification as _BuPaIdentification on $projection.BusinessPartner = _BuPaIdentification.BusinessPartner

  association [0..*] to A_BusinessPartnerContact as _BusinessPartnerContact on $projection.BusinessPartner = _BusinessPartnerContact.BusinessPartnerCompany

  association [0..*] to A_BPRelationship as _BPRelationship on $projection.BusinessPartner = _BPRelationship.BusinessPartner1

  association [0..*] to A_BuPaIndustry as _BuPaIndustry on $projection.BusinessPartner = _BuPaIndustry.BusinessPartner

  association [0..*] to A_BusPartAddrDepdntTaxNmbr as _BusPartAddrDepdntTaxNmbr on $projection.BusinessPartner = _BusPartAddrDepdntTaxNmbr.BusinessPartner

  association [0..*] to A_BusinessPartnerPaymentCard as _PaymentCard on $projection.BusinessPartner = _PaymentCard.BusinessPartner

  association [0..1] to A_BPFinancialServicesExtn as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..1] to A_BPFinancialServicesReporting as _BPFinServicesReporting on $projection.BusinessPartner = _BPFinServicesReporting.BusinessPartner

  association [0..1] to A_BPCreditWorthiness as _BPCreditWorthiness on $projection.BusinessPartner = _BPCreditWorthiness.BusinessPartner

  association [0..*] to A_BusinessPartnerRating as _BusinessPartnerRating on $projection.BusinessPartner = _BusinessPartnerRating.BusinessPartner

  association [0..*] to A_BPFiscalYearInformation as _BPFiscalYearInformation on $projection.BusinessPartner = _BPFiscalYearInformation.BusinessPartner

  association [0..*] to A_BPEmployment as _BPEmployment on $projection.BusinessPartner = _BPEmployment.BusinessPartner

  association [0..*] to A_BPTaxCompliance as _BPTaxCompliance on $projection.BusinessPartner = _BPTaxCompliance.BusinessPartner

  association [0..*] to A_BusinessPartnerAlias as _BusinessPartnerAlias on $projection.BusinessPartner = _BusinessPartnerAlias.BusinessPartner

  association [0..1] to A_BusinessPartnerIsBank as _BusinessPartnerIsBank on $projection.BusinessPartner = _BusinessPartnerIsBank.BusinessPartner

  association [0..*] to A_BPDataController as _BPDataController on $projection.BusinessPartner = _BPDataController.BusinessPartner

{
  key BusinessPartner,
      @ObjectModel.readOnly: true
      _CustomerToBusinessPartner.Customer,
      @ObjectModel.readOnly: true
      _SupplierToBusinessPartner.Supplier,
      AcademicTitle,
      AuthorizationGroup,
      BusinessPartnerCategory,
      @ObjectModel.readOnly: true
      BusinessPartnerFullName,
      BusinessPartnerGrouping,
      @ObjectModel.readOnly: true
      BusinessPartnerName,
      @ObjectModel.readOnly: true
      BusinessPartnerUUID,
      CorrespondenceLanguage,
      @ObjectModel.readOnly: true
      CreatedByUser,
      @ObjectModel.readOnly: true
      CreationDate,
      @ObjectModel.readOnly: true
      CreationTime,
      FirstName,
      FormOfAddress,
      Industry,
      InternationalLocationNumber1,
      InternationalLocationNumber2,
      IsFemale,
      IsMale,
      IsNaturalPerson,
      IsSexUnknown,
      GenderCodeName,
      Language,
      @ObjectModel.readOnly: true
      LastChangeDate,
      @ObjectModel.readOnly: true
      LastChangeTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,
      LastName,
      LegalForm,
      OrganizationBPName1,
      OrganizationBPName2,
      OrganizationBPName3,
      OrganizationBPName4,
      OrganizationFoundationDate,
      OrganizationLiquidationDate,
      SearchTerm1,
      SearchTerm2,
      AdditionalLastName,
      BirthDate,
      BusinessPartnerBirthDateStatus,
      BusinessPartnerBirthplaceName,
      BusinessPartnerDeathDate,
      BusinessPartnerIsBlocked,
      BusinessPartnerType,
      @ObjectModel.readOnly: true
      ETag,
      GroupBusinessPartnerName1,
      GroupBusinessPartnerName2,
      @ObjectModel.readOnly: true
      IndependentAddressID,
      InternationalLocationNumber3,
      MiddleName,
      NameCountry,
      NameFormat,
      PersonFullName,
      @ObjectModel.readOnly: true
      PersonNumber,
      IsMarkedForArchiving,
      @Consumption.hidden: true
      IsBusinessPurposeCompleted,
      BusinessPartnerIDByExtSystem,
      BusinessPartnerPrintFormat,
      BusinessPartnerOccupation,
      BusPartMaritalStatus,
      BusPartNationality,
      BusinessPartnerBirthName,
      BusinessPartnerSupplementName,
      NaturalPersonEmployerName,
      LastNamePrefix,
      LastNameSecondPrefix,
      Initials,
      BPDataControllerIsNotRequired,
      @Consumption.hidden:true
      DataControllerSet,
      @Consumption.hidden:true
      DataController1,
      @Consumption.hidden:true
      DataController2,
      @Consumption.hidden:true
      DataController3,
      @Consumption.hidden:true
      DataController4,
      @Consumption.hidden:true
      DataController5,
      @Consumption.hidden:true
      DataController6,
      @Consumption.hidden:true
      DataController7,
      @Consumption.hidden:true
      DataController8,
      @Consumption.hidden:true
      DataController9,
      @Consumption.hidden:true
      DataController10,
      _BusinessPartner.TradingPartner,
      _Customer,
      _Supplier,
      _BusinessPartnerAddress,
      _BusinessPartnerRole,
      _BusinessPartnerTax,
      _BusinessPartnerBank,
      _BuPaIdentification,
      _BusinessPartnerContact,
      _BPRelationship,
      _BuPaIndustry,
      _BusPartAddrDepdntTaxNmbr,
      _PaymentCard,
      _BusinessPartner,
      _BPFinServicesReporting,
      _BPCreditWorthiness,
      _BusinessPartnerRating,
      _BPFiscalYearInformation,
      _BPEmployment,
      _BPTaxCompliance,
      _BusinessPartnerAlias,
      _BusinessPartnerIsBank,
      _BPDataController
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_BPFINANCIALSERVICESEXTN",
"I_BUSINESSPARTNER",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[
"A_BPCREDITWORTHINESS",
"A_BPDATACONTROLLER",
"A_BPEMPLOYMENT",
"A_BPFINANCIALSERVICESEXTN",
"A_BPFINANCIALSERVICESREPORTING",
"A_BPFISCALYEARINFORMATION",
"A_BPRELATIONSHIP",
"A_BPTAXCOMPLIANCE",
"A_BUPAIDENTIFICATION",
"A_BUPAINDUSTRY",
"A_BUSINESSPARTNERADDRESS",
"A_BUSINESSPARTNERALIAS",
"A_BUSINESSPARTNERBANK",
"A_BUSINESSPARTNERCONTACT",
"A_BUSINESSPARTNERISBANK",
"A_BUSINESSPARTNERPAYMENTCARD",
"A_BUSINESSPARTNERRATING",
"A_BUSINESSPARTNERROLE",
"A_BUSINESSPARTNERTAXNUMBER",
"A_BUSPARTADDRDEPDNTTAXNMBR",
"A_CUSTOMER",
"A_SUPPLIER",
"E_BP_D",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/