A_SlsOrdPaymentPlanItemDetails

@ClientHandling.algorithm:#SESSION_VARIABLE

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASOPAYTPLANITEM',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #M
   }
}
@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Header Payment Plan'
define view A_SlsOrdPaymentPlanItemDetails
  as select from I_SlsDocPaymentPlanItemDetails as PaymentPlanItemDetails
    inner join   I_SalesDocumentBasic as SalesOrder on  SalesOrder.PaymentPlan      = PaymentPlanItemDetails.PaymentPlan
                                                    and SalesOrder.SDDocumentCategory = 'C'
                                                    
  association [1..1] to A_SalesOrder as _SalesOrder on _SalesOrder.SalesOrder = $projection.SalesOrder

{
      @ObjectModel.readOnly: true
  key cast(PaymentPlanItemDetails.SalesDocument as vdm_sales_order preserving type)    as SalesOrder,

  key PaymentPlanItem,
      @ObjectModel.readOnly: true
      PaymentPlanItemDetails.PaymentPlan,
      
      ElectronicPaymentType,
      ElectronicPayment,
      EPaytValidityStartDate,
      EPaytValidityEndDate,
      ElectronicPaymentHolderName,
      @Semantics.amount.currencyCode: 'AuthorizationCurrency'
      AuthorizedAmountInAuthznCrcy,
      @ObjectModel.readOnly: true
      @Semantics.currencyCode: true 
      AuthorizationCurrency,
      
      AuthorizationByDigitalPaytSrvc,
      @ObjectModel.readOnly: true
      AuthorizationByAcquirer,
      @ObjectModel.readOnly: true
      AuthorizationDate,
      @ObjectModel.readOnly: true
      AuthorizationTime,
      @ObjectModel.readOnly: true
      AuthorizationStatusName,
      
      EPaytByDigitalPaymentSrvc,
      
      @ObjectModel.readOnly: true
      ElectronicPaymentCallStatus,
      @ObjectModel.readOnly: true
      EPaytAuthorizationResult,
      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'AuthorizationCurrency'
      EPaytToBeAuthorizedAmount,
      @ObjectModel.readOnly: true
      EPaytAuthorizationIsExpired,
      @ObjectModel.readOnly: true
      EPaytAmountIsChanged,
      @ObjectModel.readOnly: true
      PreauthorizationIsRequested,
            
      PaymentServiceProvider,
      PaymentByPaymentServicePrvdr,
      TransactionByPaytSrvcPrvdr,
      MerchantByClearingHouse,
      PaymentCardAuthznRelationID,
            
      @Semantics.amount.currencyCode: 'AuthorizationCurrency'
      MaximumToBeAuthorizedAmount,
      @ObjectModel.readOnly: true
      PaytPlnForAuthorizationItem, 
      @ObjectModel.readOnly: true         
      PaytPlnItmForAuthorizationItem,
      
      // For Access control

      @Consumption.hidden: true
      SalesOrder.SalesDocumentType                                                  as SalesOrderType,
      @Consumption.hidden: true
      SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      SalesOrder.DistributionChannel,
      @Consumption.hidden: true
      SalesOrder.OrganizationDivision,
      
      //Expose associations

      _SalesOrder
} 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTBASIC",
"I_SLSDOCPAYMENTPLANITEMDETAILS"
],
"ASSOCIATED":
[
"A_SALESORDER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/