A_SalesOrderPartnerAddress

@EndUserText.label: 'Header Partner Address'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
//   createEnabled: true,

     updateEnabled: true,
//   deleteEnabled: true,

   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations:true

define view entity A_SalesOrderPartnerAddress
  as select from I_SDDocumentPartner  as HeaderPartner

    inner join   I_Address_2          as Address       on Address.AddressID = HeaderPartner.AddressID
    inner join   I_SalesDocumentBasic as SalesDocument on  SalesDocument.SalesDocument      = HeaderPartner.SDDocument
                                                       and SalesDocument.SDDocumentCategory = 'C'

  association [1..1] to A_SalesOrder              as _SalesOrder on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [1..1] to A_SalesOrderHeaderPartner as _Partner    on  $projection.SalesOrder      = _Partner.SalesOrder
                                                                 and $projection.PartnerFunction = _Partner.PartnerFunction
                                                                 
                                                                                                                      

{
  key HeaderPartner.SDDocument                                            as SalesOrder,
  key HeaderPartner.PartnerFunction,
  key Address.AddressRepresentationCode,

      Address.CorrespondenceLanguage,
      Address.AddresseeFullName,
      //        Address.PersonGivenName, for next release

      //        Address.PersonFamilyName, for next release

      Address.OrganizationName1,
      Address.OrganizationName2,
      Address.OrganizationName3,
      Address.OrganizationName4,
      Address.CityName,
      Address.DistrictName,
      Address.PostalCode,
      //Address.CompanyPostalCode, --> This is planned to be in A2A


      @EndUserText.label: 'Street Address Non-Deliverable Reason'
      Address.StreetPrefixName1,
      Address.StreetPrefixName2,
      Address.StreetName,
      Address.StreetSuffixName1,
      Address.StreetSuffixName2,
      Address.HouseNumber,
      //Address.HouseNumberSupplementText, --> This is planned to be in A2A (#1)

      Address.Country,
      Address.Region,
      Address.FormOfAddress,
      Address.TaxJurisdiction,
      Address.TransportZone,

      Address.POBox,
      Address.POBoxPostalCode,
      //        @EndUserText.label: 'PO Box Address Non-Deliverable Reason'

      //        Address.POBoxIsWithoutNumber,  --> This is planned to be in A2A

      //        Address.CareOfName, --> This is planned to be in A2A (#1)


      Address._CurrentDfltEmailAddress.EmailAddress,
      
      Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry            as MobilePhoneCountry,
      Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobileNumber,

      Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry,
      Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
      Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,

      Address._CurrentDfltFaxNumber.FaxNumberCountry,
      Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
      Address._CurrentDfltFaxNumber.FaxExtensionNumber,

      // For Access control

      @Consumption.hidden: true
      SalesDocument.SalesDocumentType                                     as SalesOrderType,
      @Consumption.hidden: true
      SalesDocument.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocument.SalesOrganization,
      @Consumption.hidden: true
      SalesDocument.DistributionChannel,

      _SalesOrder,
      _Partner


}
where
     HeaderPartner.SDDocPartnerAddressRefType = 'E'
  or HeaderPartner.SDDocPartnerAddressRefType = 'F'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESS_2",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTPARTNER"
],
"ASSOCIATED":
[
"A_SALESORDER",
"A_SALESORDERHEADERPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/