@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Direct Activity Allocation Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
usageType: {
serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL
}
}
@OData.entityType.name:'DirectActivityAllocationItem_Type'
@VDM: {
viewType: #CONSUMPTION,
usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE],
lifecycle.contract.type: #PUBLIC_REMOTE_API
}
define view entity A_DirectActivityAllocationItem
as projection on R_DrctActivityAllocationItemTP as _ActivityAllocationItem
{
key FiscalYear,
key ReferenceDocument,
key ControllingArea,
key ReferenceDocumentItem,
key LedgerGLLineItem,
key ReferenceDocumentType,
key ReferenceDocumentContext,
key AccountingDocument,
TransactionSubitem,
SourceLedger,
ServicesRenderedDate,
CompanyCode,
_CompanyCodeText.CompanyCodeName as CompanyCodeName,
SenderCompanyCode,
@EndUserText.label: 'Sender Company Code Name'
@EndUserText.quickInfo: 'Sender Company Code Name'
_SenderCompanyCodeText.CompanyCodeName as SourceCompanyCodeName,
AccountAssignment,
AccountAssignmentType,
@EndUserText.label: 'Account Assignment Type Text'
@EndUserText.quickInfo: 'Account Assignment Type Text'
_AccountAssignmentTypeT.AccountAssignmentTypeDesc,
PartnerAccountAssignment,
PartnerAccountAssignmentType,
@EndUserText.label: 'Receiver Account Assignment Type Text'
@EndUserText.quickInfo: 'Receiver Account Assignment Type Text'
_PartnerAccountAssignmentTypeT.AccountAssignmentTypeDesc as PartAccountAssignmentTypeDesc,
GLAccount,
@EndUserText.label: 'Account for Allocation Name'
@EndUserText.quickInfo: 'Account for Allocation Name'
_GLAccountText[1:Language = $session.system_language].GLAccountName as GLAccountName,
ChartOfAccounts,
SenderCostCenter,
@EndUserText.label: 'Sender Cost Center Name'
@EndUserText.quickInfo: 'Sender Cost Center Name'
_CostCenterText.CostCenterName as SenderCostCenterName,
@EndUserText.label: 'Sender Activity Type'
@EndUserText.quickInfo: 'Sender Activity Type'
CostCtrActivityType,
@EndUserText.label: 'Sender Activity Type Name'
@EndUserText.quickInfo: 'Sender Activity Type Name'
_CostCtrActivityTypeTxt.CostCtrActivityTypeName as CostCtrActivityTypeName,
Fund,
@EndUserText.label: 'Sender Fund Name'
@EndUserText.quickInfo: 'Sender Fund Name'
_FundText[1:Language = $session.system_language].FundName as FundName,
FunctionalArea,
@EndUserText.label: 'Sender Functional Area Name'
@EndUserText.quickInfo: 'Sender Functional Area Name'
_FunctionalAreaText[1:Language = $session.system_language].FunctionalAreaName,
GrantID,
@EndUserText.label: 'Sender Grant Name'
@EndUserText.quickInfo: 'Sender Grant Name'
_GrantText[1:Language = $session.system_language].GrantName,
@EndUserText.label: 'Sender Budget Period'
@EndUserText.quickInfo: 'Sender Budget Period'
BudgetPeriod,
@EndUserText.label: 'Sender Budget Period Name'
@EndUserText.quickInfo: 'Sender Budget Period Name'
_BudgetPeriodText[1:Language = $session.system_language].BudgetPeriodName,
@EndUserText.label: 'Sender Recovery Indicator'
@EndUserText.quickInfo: 'Sender Recovery Indicator'
SenderCostRecoveryCode,
@EndUserText.label: 'Receiver Cost Center'
@EndUserText.quickInfo: 'Receiver Cost Center'
PartnerCostCenter,
@EndUserText.label: 'Receiver Cost Center Name'
@EndUserText.quickInfo: 'Receiver Cost Center Name'
_PartnerCostCenterText.CostCenterName as PartnerCostCenterName,
DocumentItemText,
@Semantics.unitOfMeasure:true
BaseUnit,
_UnitOfMeasureText[1:Language = $session.system_language].UnitOfMeasureLongName as UnitOfMeasureLongName,
@EndUserText.label: 'Quantity'
@EndUserText.quickInfo: 'Quantity'
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
Quantity,
@Semantics.currencyCode:true
TransactionCurrency,
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
AmountInTransactionCurrency,
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
PrcTotAmtInTransactionCurrency,
@Semantics.currencyCode:true
CompanyCodeCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
AmountInCompanyCodeCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
PrcTotAmtInCompanyCodeCurrency,
@Semantics.currencyCode:true
GlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
AmountInGlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
PrcTotAmtInGlobalCurrency,
@EndUserText.label: 'Receiver WBS Element'
@EndUserText.quickInfo: 'Receiver WBS Element'
PartnerWBSElementExternalID,
@EndUserText.label: 'Receiver WBS Element Name'
@EndUserText.quickInfo: 'Receiver WBS Element Name'
_PartnerWBSElementText.WBSDescription as WBSDescription,
@EndUserText.label: 'Receiver Project'
@EndUserText.quickInfo: 'Receiver Project'
PartnerProjectExternalID,
@EndUserText.label: 'Receiver Service Doc. Type'
@EndUserText.quickInfo: 'Receiver Service Document Type'
PartnerServiceDocumentType,
@EndUserText.label: 'Receiver Service Document'
@EndUserText.quickInfo: 'Receiver Service Document'
PartnerServiceDocument,
@EndUserText.label: 'Receiver Service Doc. Item'
@EndUserText.quickInfo: 'Receiver Service Document Item'
PartnerServiceDocumentItem,
@EndUserText.label: 'Receiver Project Network'
@EndUserText.quickInfo: 'Receiver Project Network'
PartnerProjectNetwork,
@EndUserText.label: 'Receiver Order'
@EndUserText.quickInfo: 'Receiver Order'
PartnerOrder,
@EndUserText.label: 'Receiver Project Network Activity'
@EndUserText.quickInfo: 'Receiver Project Network Activity'
PartnerProjectNetworkActivity,
@EndUserText.label: 'Receiver Activity Type'
@EndUserText.quickInfo: 'Receiver Activity Type'
PartnerCostCtrActivityType,
@EndUserText.label: 'Receiver Activity Type Name'
@EndUserText.quickInfo: 'Receiver Activity Type Name'
_PartnerCostCtrActivityTypeTxt.CostCtrActivityTypeName as PartnerCostCtrActivityTypeName,
@EndUserText.label: 'Receiver Cost Object'
@EndUserText.quickInfo: 'Receiver Cost Object'
PartnerCostObject,
@EndUserText.label: 'Receiver Sales Document'
@EndUserText.quickInfo: 'Receiver Sales Document'
PartnerSalesDocument,
@EndUserText.label: 'Receiver Sales Doc. Item'
@EndUserText.quickInfo: 'Receiver Sales Document Item'
PartnerSalesDocumentItem,
WorkItem,
PersonnelNumber,
Plant,
Product,
ReceiverProcurementProcess,
@EndUserText.label: 'Receiver Business Process'
@EndUserText.quickInfo: 'Receiver Business Process'
PartnerBusinessProcess,
PartnerFund,
@EndUserText.label: 'Receiver Fund Name'
@EndUserText.quickInfo: 'Receiver Fund Name'
_PartnerFundText[1:Language = $session.system_language].FundName as ReceiverPostedFundName,
PartnerFunctionalArea,
@EndUserText.label: 'Receiver Functional Area Name'
@EndUserText.quickInfo: 'Receiver Functional Area Name'
_PartnerFunctionalAreaText[1:Language = $session.system_language].FunctionalAreaName as PartnerFunctionalAreaName,
PartnerGrant,
@EndUserText.label: 'Receiver Grant Name'
@EndUserText.quickInfo: 'Receiver Grant Name'
_PartnerGrantText[1:Language = $session.system_language].GrantName as ReceiverPostedGrantName,
@EndUserText.label: 'Receiver Budget Period'
@EndUserText.quickInfo: 'Receiver Budget Period'
PartnerBudgetPeriod,
@EndUserText.label: 'Receiver Budget Period Name'
@EndUserText.quickInfo: 'Receiver Budget Period Name'
_PartnerBudgetPeriodText[1:Language = $session.system_language].BudgetPeriodName as ReceiverPostedBudgetPeriodName,
@EndUserText.label: 'Is Reposted'
@EndUserText.quickInfo: 'Is Reposted'
IsSettled,
@EndUserText.label: 'Receiver Accounting Indicator'
@EndUserText.quickInfo: 'Receiver Accounting Indicator'
BillableControl,
_BillableControlText[1:Language = $session.system_language].BillableControlName as BillableControlName,
// Joint Venture
@EndUserText.label: 'Receiver Recovery Indicator'
@EndUserText.quickInfo: 'Receiver Recovery Indicator'
PartnerCostRecoveryCode,
ControllingDocumentItem,
OperatingConcern,
PartnerProfitabilitySegment,
@Semantics.booleanIndicator
PartProfitabilitySgmtIsAssgd,
@EndUserText.label: 'Reposting Reference Document'
@EndUserText.quickInfo: 'Reposting Reference Document'
_SuccessorReferenceItem.SuccessorReferenceDocument as SuccessorReferenceDocument,
@EndUserText.label: 'Receiver Order Operation'
@EndUserText.quickInfo: 'Receiver Order Operation'
OrderOperation,
@EndUserText.label: 'Receiver Real Estate Company Code'
@EndUserText.quickInfo: 'Receiver Real Estate Company Code'
ReceiverRECompanyCode,
@EndUserText.label: 'Receiver Real Estate Business Entity'
@EndUserText.quickInfo: 'Receiver Real Estate Business Entity'
REPartnerBusinessEntity,
@EndUserText.label: 'Receiver Real Estate Building'
@EndUserText.quickInfo: 'Receiver Real Estate Building'
RealEstatePartnerBuilding,
@EndUserText.label: 'Receiver Real Estate Property'
@EndUserText.quickInfo: 'Receiver Real Estate Property'
RealEstatePartnerProperty,
@EndUserText.label: 'Receiver Real Estate Rental Object'
@EndUserText.quickInfo: 'Receiver Real Estate Rental Object'
REPartnerRentalObject,
@EndUserText.label: 'Receiver Real Estate Contract'
@EndUserText.quickInfo: 'Receiver Real Estate Contract'
RealEstatePartnerContract,
@EndUserText.label: 'Receiver Real Estate Service Charge Key'
@EndUserText.quickInfo: 'Receiver Real Estate Service Charge Key'
REPartnerServiceChargeKey,
@EndUserText.label: 'Receiver Real Estate Settlement Unit'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Unit'
REPartnerSettlementUnitID,
@EndUserText.label: 'Receiver Real Estate Settlement Reference Date'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Reference Date'
PartnerSettlementReferenceDate,
PartnerProfitCenter,
ProfitCenter,
@Semantics.currencyCode:true
FreeDefinedCurrency1,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
AmountInFreeDefinedCurrency1,
@Semantics.currencyCode:true
FreeDefinedCurrency2,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
AmountInFreeDefinedCurrency2,
@Semantics.currencyCode:true
FreeDefinedCurrency3,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
AmountInFreeDefinedCurrency3,
@Semantics.currencyCode:true
FreeDefinedCurrency4,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
AmountInFreeDefinedCurrency4,
@Semantics.currencyCode:true
FreeDefinedCurrency5,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
AmountInFreeDefinedCurrency5,
@Semantics.currencyCode:true
FreeDefinedCurrency6,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
AmountInFreeDefinedCurrency6,
@Semantics.currencyCode:true
FreeDefinedCurrency7,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
AmountInFreeDefinedCurrency7,
@Semantics.currencyCode:true
FreeDefinedCurrency8,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
AmountInFreeDefinedCurrency8,
@Semantics.currencyCode:true
FunctionalCurrency,
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
AmountInFunctionalCurrency,
ControllingBusTransacType,
_Header : redirected to parent A_DirectActivityAllocation,
_ProfitabilitySegment : redirected to composition child A_DrctActyAllocPrftbltySegment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_BILLABLECONTROLTEXT",
"I_BUDGETPERIODTEXT",
"I_COMPANYCODE",
"I_COSTCENTERACTIVITYTYPETEXT",
"I_COSTCENTERTEXT",
"I_DRCTACTYALLOCSUCCSSRREFITEM",
"I_FUNCTIONALAREATEXT",
"I_FUNDTEXT",
"I_GLACCOUNTTEXT",
"I_GRANTTEXT",
"I_UNITOFMEASURETEXT",
"I_WBSELEMENTBASICDATA",
"R_DRCTACTIVITYALLOCATIONITEMTP"
],
"ASSOCIATED":
[
"A_DIRECTACTIVITYALLOCATION",
"A_DRCTACTYALLOCPRFTBLTYSEGMENT",
"R_DIRECTACTIVITYALLOCATIONTP",
"R_DRCTACTYALLOCPRFTBLTYSGMTTP"
],
"BASE":
[
"R_DRCTACTIVITYALLOCATIONITEMTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/