R_DRCTACTIVITYALLOCATIONITEMTP

CDS View

Direct Activity Allocation Item

R_DRCTACTIVITYALLOCATIONITEMTP is a CDS View in S/4HANA. Direct Activity Allocation Item. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_DirectActivityAllocationItem view_entity projection CONSUMPTION Direct Activity Allocation Item
C_DrctActivityAllocationItemTP view_entity projection CONSUMPTION Direct Activity Allocation Item
I_DrctActyAllocationItemTP_2 view_entity projection TRANSACTIONAL Direct Activity Allocation Item - TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Direct Activity Allocation Item'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

define view entity R_DrctActivityAllocationItemTP
  as select from R_DirectActivityAllocationItem

  association        to parent R_DirectActivityAllocationTP as _Header                   on  $projection.ControllingArea          = _Header.ControllingArea
                                                                                         and $projection.FiscalYear               = _Header.FiscalYear
                                                                                         and $projection.ReferenceDocument        = _Header.ReferenceDocument
                                                                                         and $projection.ReferenceDocumentType    = _Header.ReferenceDocumentType
                                                                                         and $projection.ReferenceDocumentContext = _Header.ReferenceDocumentContext
  
  composition [1..1] of R_DrctActyAllocPrftbltySgmtTP    as _ProfitabilitySegment
  
  association [1..1] to E_JournalEntryItem      as _Extension       on $projection.SourceLedger       = _Extension.SourceLedger
                                                                    and $projection.CompanyCode        = _Extension.CompanyCode
                                                                    and $projection.FiscalYear         = _Extension.FiscalYear
                                                                    and $projection.AccountingDocument = _Extension.AccountingDocument
                                                                    and $projection.LedgerGLLineItem   = _Extension.LedgerGLLineItem  
{
  key FiscalYear,
  key ReferenceDocument,
  key ControllingArea,
  key ReferenceDocumentItem,
  key LedgerGLLineItem,
  key ReferenceDocumentType,
  key ReferenceDocumentContext, 
  key AccountingDocument,

      @ObjectModel.editableFieldFor: 'FiscalYear'
      FiscalYear               as FiscalYearForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocument'
      ReferenceDocument        as ReferenceDocumentForEdit,
      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea          as ControllingAreaForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocumentItem'
      ReferenceDocumentItem    as ReferenceDocumentItemForEdit,
      @ObjectModel.editableFieldFor: 'LedgerGLLineItem'
      LedgerGLLineItem         as LedgerGLLineItemForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocumentType'
      ReferenceDocumentType    as ReferenceDocumentTypeForEdit,
      @ObjectModel.editableFieldFor: 'AccountingDocument'
      AccountingDocument         as AccountingDocumentForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocumentContext'
      ReferenceDocumentContext    as ReferenceDocumentContextFoEd,                        
      
      SourceLedger,
      CompanyCode,
      SenderCompanyCode,
      
      AccountAssignment,      
      AccountAssignmentType,      
      PartnerAccountAssignment,      
      PartnerAccountAssignmentType,
      
      PartnerCostCtrActivityType,
      CostCtrActivityType,
      
      PartnerCostCenter,
      SenderCostCenter,
      
      DocumentItemText,      
      GLAccount,      
      
      BaseUnit,
      
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      Quantity,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }      
      PrcTotAmtInTransactionCurrency,
      
      TransactionCurrency,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,
      
      CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      PrcTotAmtInCompanyCodeCurrency,
      
      GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,
      
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }      
      PrcTotAmtInGlobalCurrency,
      
      //WBS Element

      PartnerWBSElementExternalID,
      PartnerWBSElementInternalID,
      
      PartnerProjectExternalID,      
      
      //Service Contract Item and Service Order Item

      PartnerServiceDocumentType,
      PartnerServiceDocument,
      PartnerServiceDocumentItem,
      
      //Network

      PartnerProjectNetwork,
      
      //Activity or Order

      PartnerOrder,
      PartnerProjectNetworkActivity,  
      
      //Real Estate Management - Rental Unit

      PartnerCompanyCode,
      
      //Cost object

      PartnerCostObject, 
      
      //Sales Order

      PartnerSalesDocument,
      PartnerSalesDocumentItem,
      
      WorkItem,
      PersonnelNumber,
      ReceiverProcurementProcess,
      Plant,  
      PartnerBusinessProcess, 
      Product,
      
      cast('' as costaccountingdocumentaction)    as CostAccountingDocumentAction,
      cast('' as fco_drct_acty_is_posted) as ControllingDocumentStatus,
      
      ControllingBusTransacType,
      ControllingDocumentItem,
      
      //Public Sector

      Fund,
      FunctionalArea,
      GrantID,
      BudgetPeriod,
      PartnerFund,
      PartnerFunctionalArea,
      PartnerGrant,
      PartnerBudgetPeriod,
      FinancialManagementArea,
      
      IsSettled,
      BillableControl,
      PostingDate,
      
      // Joint Venture

      PartnerCostRecoveryCode,
      SenderCostRecoveryCode,
      
      OperatingConcern,
      
      PartnerProfitabilitySegment,
      @Semantics.booleanIndicator
      PartProfitabilitySgmtIsAssgd,
      
      OrderOperation,
      ReceiverRECompanyCode,
      REPartnerBusinessEntity,
      RealEstatePartnerBuilding,
      RealEstatePartnerProperty,
      REPartnerRentalObject,
      RealEstatePartnerContract,
      REPartnerServiceChargeKey,
      REPartnerSettlementUnitID,
      PartnerSettlementReferenceDate,
      
      PartnerProfitCenter,
      ProfitCenter,
      
      ServicesRenderedDate,
      
      //Additional amounts

      FreeDefinedCurrency1,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      AmountInFreeDefinedCurrency1,
      
      FreeDefinedCurrency2,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      AmountInFreeDefinedCurrency2,
      
      FreeDefinedCurrency3,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      AmountInFreeDefinedCurrency3,
      
      FreeDefinedCurrency4,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      AmountInFreeDefinedCurrency4,
      
      FreeDefinedCurrency5,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      AmountInFreeDefinedCurrency5,
      
      FreeDefinedCurrency6,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      AmountInFreeDefinedCurrency6,
      
      FreeDefinedCurrency7,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      AmountInFreeDefinedCurrency7,
      
      FreeDefinedCurrency8,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      AmountInFreeDefinedCurrency8,
      
      FunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      AmountInFunctionalCurrency,
      
      ChartOfAccounts,
      TransactionSubitem,
      
      AccountingDocumentType,
      
      //Technical field

      cast( '0' as timestampl ) as DraftCreationDateTime,
      
      _Header,
      _ProfitabilitySegment,
            
      _PartnerWBSElementText,
      _PartnerCostCtrActivityTypeTxt,
      _PartnerCostCenterText,
      _CostCtrActivityTypeTxt,
      _CostCenterText,   
      _SuccessorReferenceItem,
      _FundText,
      _PartnerFundText,
      _GrantText,
      _PartnerGrantText,
      _BudgetPeriodText,
      _PartnerBudgetPeriodText,
      _PartnerFunctionalAreaText,
      _FunctionalAreaText,
      _BillableControlText,
      _GLAccountText,
      _UnitOfMeasureText,
      _PartnerAccountAssignmentTypeT,
      _AccountAssignmentTypeT,
      _SenderCompanyCodeText,
      _CompanyCodeText 

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_DIRECTACTIVITYALLOCATIONITEM"
],
"ASSOCIATED":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_BILLABLECONTROLTEXT",
"I_BUDGETPERIODTEXT",
"I_COMPANYCODE",
"I_COSTCENTERACTIVITYTYPETEXT",
"I_COSTCENTERTEXT",
"I_DRCTACTYALLOCSUCCSSRREFITEM",
"I_FUNCTIONALAREATEXT",
"I_FUNDTEXT",
"I_GLACCOUNTTEXT",
"I_GRANTTEXT",
"I_UNITOFMEASURETEXT",
"I_WBSELEMENTBASICDATA",
"R_DIRECTACTIVITYALLOCATIONTP",
"R_DRCTACTYALLOCPRFTBLTYSGMTTP"
],
"BASE":
[
"R_DIRECTACTIVITYALLOCATIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More