A_DebitMemoRequestSimulation

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ObjectModel: {
   createEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Debit Memo Request Simulation'

define root view entity A_DebitMemoRequestSimulation
  as select from I_DebitMemoRequest as DebitMemoRequest
  composition [0..*] of A_DebitMemoReqItemSimulation   as _Item
  composition [0..*] of A_DebitMemoReqPartnerSimln     as _Partner
  composition [0..*] of A_DebitMemoReqPrcgElmntSimln   as _PricingElement
  association [1..1] to A_DebitMemoReqCreditSimulation as _Credit    on _Credit.DebitMemoRequest = $projection.DebitMemoRequest
  //Extensibility

  association [0..1] to E_SalesDocumentBasic           as _Extension on $projection.DebitMemoRequest = _Extension.SalesDocument

{

  key DebitMemoRequest.DebitMemoRequest,

      @ObjectModel.mandatory: true
      DebitMemoRequest.DebitMemoRequestType,

      DebitMemoRequest.SalesOrganization,

      DebitMemoRequest.DistributionChannel,

      DebitMemoRequest.OrganizationDivision,

      DebitMemoRequest.SalesGroup,
      DebitMemoRequest.SalesOffice,
      DebitMemoRequest.SalesDistrict,
      DebitMemoRequest.SoldToParty,

      DebitMemoRequest.PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      DebitMemoRequest.CustomerPurchaseOrderType,
      DebitMemoRequest.CustomerPurchaseOrderDate,

      DebitMemoRequest.DebitMemoRequestDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      DebitMemoRequest.TotalNetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      DebitMemoRequest.TransactionCurrency,
      
      @ObjectModel.readOnly: true
      DebitMemoRequest.SDPricingProcedure,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      DebitMemoRequest.SDDocumentReason,
      DebitMemoRequest.PricingDate,
      DebitMemoRequest.CustomerTaxClassification1,
      DebitMemoRequest.CustomerTaxClassification2,
      DebitMemoRequest.CustomerTaxClassification3,
      DebitMemoRequest.CustomerTaxClassification4,
      DebitMemoRequest.CustomerTaxClassification5,
      DebitMemoRequest.CustomerTaxClassification6,
      DebitMemoRequest.CustomerTaxClassification7,
      DebitMemoRequest.CustomerTaxClassification8,
      DebitMemoRequest.CustomerTaxClassification9,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      DebitMemoRequest.HeaderBillingBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      DebitMemoRequest.IncotermsClassification,
      DebitMemoRequest.IncotermsTransferLocation,
      DebitMemoRequest.IncotermsLocation1,
      DebitMemoRequest.IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      DebitMemoRequest.IncotermsVersion,
      DebitMemoRequest.CustomerPaymentTerms,
      DebitMemoRequest.PaymentMethod,

      DebitMemoRequest.BillingDocumentDate,
      DebitMemoRequest.ServicesRenderedDate,

      DebitMemoRequest.ReferenceSDDocument,

      // Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Credit
}
where
  DebitMemoRequest.DebitMemoRequest = '0'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DEBITMEMOREQUEST"
],
"ASSOCIATED":
[
"A_DEBITMEMOREQCREDITSIMULATION",
"A_DEBITMEMOREQITEMSIMULATION",
"A_DEBITMEMOREQPARTNERSIMLN",
"A_DEBITMEMOREQPRCGELMNTSIMLN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/