A_DebitMemoReqItemSimulation

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Debit Memo Request Item Simulation'

define view entity A_DebitMemoReqItemSimulation

  as select from I_DebitMemoRequestItem as DebitMemoRequestItem
  association        to parent A_DebitMemoRequestSimulation as _DebitMemoRequest on  $projection.DebitMemoRequest = _DebitMemoRequest.DebitMemoRequest
  composition [0..*] of A_DebitMemoReqItemPartnerSimln      as _Partner
  composition [0..*] of A_DebitMemoReqItemPrgElmSimln       as _PricingElement
  //Extensibility

  association [0..1] to E_SalesDocumentItemBasic            as _Extension        on  $projection.DebitMemoRequest     = _Extension.SalesDocument
                                                                                 and $projection.DebitMemoRequestItem = _Extension.SalesDocumentItem
{
       @ObjectModel.readOnly: true
  key  DebitMemoRequestItem.DebitMemoRequest,
  key  DebitMemoRequestItem.DebitMemoRequestItem,

       DebitMemoRequestItem.HigherLevelItem,

       DebitMemoRequestItem.DebitMemoRequestItemCategory,

       @Semantics.text: true
       DebitMemoRequestItem.DebitMemoRequestItemText,

       DebitMemoRequestItem.PurchaseOrderByCustomer,
       DebitMemoRequestItem.Material,
       DebitMemoRequestItem.MaterialByCustomer,

       DebitMemoRequestItem.PricingDate,

       @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'RequestedQuantitySAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'RequestedQuantityISOUnit'
       DebitMemoRequestItem.RequestedQuantity,

       DebitMemoRequestItem.RequestedQuantityUnit,
       cast(_RequestedQuantityUnit.UnitOfMeasureSAPCode as sd_reqd_qty_sapunit preserving type) as RequestedQuantitySAPUnit,
       cast(_RequestedQuantityUnit.UnitOfMeasureISOCode as sd_reqd_qty_isounit preserving type) as RequestedQuantityISOUnit,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
         @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
       DebitMemoRequestItem.ItemGrossWeight,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
       DebitMemoRequestItem.ItemNetWeight,

       @ObjectModel.readOnly: true
       DebitMemoRequestItem.ItemWeightUnit,
       @ObjectModel.readOnly: true
       cast(_ItemWeightUnit.UnitOfMeasureSAPCode as sd_itm_wgt_sapunit preserving type)         as ItemWeightSAPUnit,
       @ObjectModel.readOnly: true
       cast(_ItemWeightUnit.UnitOfMeasureISOCode as sd_itm_wgt_isounit preserving type)         as ItemWeightISOUnit,

       @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemVolumeSAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'ItemVolumeISOUnit'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.ItemVolume,

       @ObjectModel.readOnly: true
       DebitMemoRequestItem.ItemVolumeUnit,
       @ObjectModel.readOnly: true
       cast(_ItemVolumeUnit.UnitOfMeasureSAPCode as sd_itm_vol_sapunit preserving type)         as ItemVolumeSAPUnit,
       @ObjectModel.readOnly: true
       cast(_ItemVolumeUnit.UnitOfMeasureISOCode as sd_itm_vol_isounit preserving type)         as ItemVolumeISOUnit,

       @ObjectModel.sapObjectNodeTypeReference: 'Currency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.TransactionCurrency,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.NetAmount,

       DebitMemoRequestItem.MaterialGroup,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'AdditionalProductGroup1'
       DebitMemoRequestItem.AdditionalMaterialGroup1,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'AdditionalProductGroup2'
       DebitMemoRequestItem.AdditionalMaterialGroup2,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'AdditionalProductGroup3'
       DebitMemoRequestItem.AdditionalMaterialGroup3,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'AdditionalProductGroup4'
       DebitMemoRequestItem.AdditionalMaterialGroup4,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'AdditionalProductGroup5'
       DebitMemoRequestItem.AdditionalMaterialGroup5,
       @ObjectModel.sapObjectNodeTypeReference: 'MaterialPricingGroup'
       DebitMemoRequestItem.MaterialPricingGroup,
       DebitMemoRequestItem.ProductTaxClassification1,
       DebitMemoRequestItem.ProductTaxClassification2,
       DebitMemoRequestItem.ProductTaxClassification3,
       DebitMemoRequestItem.ProductTaxClassification4,
       DebitMemoRequestItem.ProductTaxClassification5,
       DebitMemoRequestItem.ProductTaxClassification6,
       DebitMemoRequestItem.ProductTaxClassification7,
       DebitMemoRequestItem.ProductTaxClassification8,
       DebitMemoRequestItem.ProductTaxClassification9,

       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Batch,
       DebitMemoRequestItem.Plant,

       @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
       DebitMemoRequestItem.IncotermsClassification,
       DebitMemoRequestItem.IncotermsTransferLocation,
       DebitMemoRequestItem.IncotermsLocation1,
       DebitMemoRequestItem.IncotermsLocation2,

       DebitMemoRequestItem.CustomerPaymentTerms,

       @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
       DebitMemoRequestItem.ItemBillingBlockReason,
       @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentRjcnReason'
       DebitMemoRequestItem.SalesDocumentRjcnReason,

       //       WBSElement,

       DebitMemoRequestItem.ProfitCenter,

       DebitMemoRequestItem.ReferenceSDDocument,
       DebitMemoRequestItem.ReferenceSDDocumentItem,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal1Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal2Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal3Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal4Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal5Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.Subtotal6Amount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       DebitMemoRequestItem.TaxAmount,
       // For Access control

       @Consumption.hidden: true
       _DebitMemoRequest.DebitMemoRequestType,
       @Consumption.hidden: true
       _DebitMemoRequest.SalesOrganization,
       @Consumption.hidden: true
       _DebitMemoRequest.DistributionChannel,
       @Consumption.hidden: true
       _DebitMemoRequest.OrganizationDivision,

       // Expose own associations

       _DebitMemoRequest,
       _Partner,
       _PricingElement

}
where
  DebitMemoRequestItem.DebitMemoRequest = '0'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_DEBITMEMOREQUESTSIMULATION",
"I_DEBITMEMOREQUESTITEM",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_DEBITMEMOREQITEMPARTNERSIMLN",
"A_DEBITMEMOREQITEMPRGELMSIMLN",
"A_DEBITMEMOREQUESTSIMULATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/