I_DEBITMEMOREQUESTITEM

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'DebitMemoRequestItem'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: [ #ANALYTICAL_DIMENSION ]   
@EndUserText.label: 'Debit Memo Request Item'
@Analytics: { dataCategory: #DIMENSION}
@Metadata.allowExtensions: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#CHECK
@AccessControl.privilegedAssociations: [ '_Partner' ,'_CreatedByUser' ,'_BusinessAreaText','_MaterialText','_ProductText','_OrigMaterialText'   ]
@AbapCatalog.sqlViewName: 'ISDDEBMEMOREQITM'
@Metadata.ignorePropagatedAnnotations:true 

define view I_DebitMemoRequestItem
  as select from I_SalesDocumentItem as SalesDocumentItem
  //Associations


  //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

  association [0..*] to I_BusinessAreaText          as _BusinessAreaText on  $projection.BusinessArea                = _BusinessAreaText.BusinessArea
  association [0..*] to I_MaterialText              as _MaterialText     on  $projection.Material                    = _MaterialText.Material
  association [0..*] to I_ProductText                  as _ProductText       on  $projection.Product = _ProductText.Product
  association [0..*] to I_MaterialText              as _OrigMaterialText on  $projection.OriginallyRequestedMaterial = _OrigMaterialText.Material
  // ]--GENERATED

  association [1..1] to I_DebitMemoRequest          as _DebitMemoRequest on  $projection.DebitMemoRequest            = _DebitMemoRequest.DebitMemoRequest
  
  association [0..*] to I_DebitMemoReqItemPartner   as _Partner          on  $projection.DebitMemoRequest            = _Partner.DebitMemoRequest
                                                                               and $projection.DebitMemoRequestItem        = _Partner.DebitMemoRequestItem
  association [0..*] to I_DebitMemoReqItemPrcgElmnt as _PricingElement   on  $projection.DebitMemoRequest            = _PricingElement.DebitMemoRequest
                                                                               and $projection.DebitMemoRequestItem        = _PricingElement.DebitMemoRequestItem

  //Extensibility

  association [0..1] to E_SalesDocumentItemBasic    as _Extension        on  SalesDocumentItem.SalesDocument         = _Extension.SalesDocument
                                                                         and SalesDocumentItem.SalesDocumentItem     = _Extension.SalesDocumentItem

{
      //Key

      @ObjectModel.foreignKey.association: '_DebitMemoRequest'
  key cast(SalesDocument as debit_memo_request preserving type)          as DebitMemoRequest,
      @ObjectModel.text.element: 'DebitMemoRequestItemText'
  key cast(SalesDocumentItem as debit_memo_request_item preserving type) as DebitMemoRequestItem,

      //Category

      @ObjectModel.foreignKey.association: '_ItemCategory'
      SalesDocumentItemCategory                                          as DebitMemoRequestItemCategory,
      SalesDocumentItemType                                              as DebitMemoRequestItemType,
      IsReturnsItem,

      //Admin

      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      CreationTime,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,

      //Org

      @ObjectModel.foreignKey.association: '_Division'
      Division,

      //Product

      @Consumption.valueHelpDefinition: [                        //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      @ObjectModel.text.association: '_MaterialText'             // ]--GENERATED

      @ObjectModel.foreignKey.association: '_Material'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'Product'
      Material,
      
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProductStdVH',
                     element: 'Product' }
        }]
      @ObjectModel.text.association: '_ProductText'
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_Product'
      Product,
      
      @Consumption.valueHelpDefinition: [                        //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      @ObjectModel.text.association: '_OrigMaterialText'         // ]--GENERATED

      @ObjectModel.foreignKey.association: '_OriginallyRequestedMaterial'
      OriginallyRequestedMaterial,
      MaterialByCustomer,
      Batch,
      ProductHierarchyNode,
      ProductCatalog,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProductGroup'
      MaterialGroup,
      @ObjectModel.foreignKey.association: '_ProductGroup'
      @Analytics.internalName: #LOCAL
      ProductGroup,
      @ObjectModel.foreignKey.association: '_MaterialPricingGroup'
      MaterialPricingGroup,
      ProductTaxClassification1,
      ProductTaxClassification2,
      ProductTaxClassification3,
      ProductTaxClassification4,
      ProductTaxClassification5,
      ProductTaxClassification6,
      ProductTaxClassification7,
      ProductTaxClassification8,
      ProductTaxClassification9,
   
      @ObjectModel.foreignKey.association: '_AdditionalMaterialGroup1'
      AdditionalMaterialGroup1,
      @ObjectModel.foreignKey.association: '_AdditionalMaterialGroup2'
      AdditionalMaterialGroup2,
      @ObjectModel.foreignKey.association: '_AdditionalMaterialGroup3'
      AdditionalMaterialGroup3,
      @ObjectModel.foreignKey.association: '_AdditionalMaterialGroup4'
      AdditionalMaterialGroup4,
      @ObjectModel.foreignKey.association: '_AdditionalMaterialGroup5'
      AdditionalMaterialGroup5,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,

      //Sales

      @Semantics.text: true
      SalesDocumentItemText                                              as DebitMemoRequestItemText,
      PurchaseOrderByCustomer,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      BaseUnit,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'TargetQuantityUnit'
      TargetQuantity,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_TargetQuantityUnit'
      TargetQuantityUnit,

      TargetToBaseQuantityDnmntr,
      TargetToBaseQuantityNmrtr,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      RequestedQuantity,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_RequestedQuantityUnit'
      RequestedQuantityUnit,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      RequestedQuantityInBaseUnit,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ItemWeightUnit'
      ItemWeightUnit,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      ItemVolume,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ItemVolumeUnit'
      ItemVolumeUnit,

      ServicesRenderedDate,
      @ObjectModel.foreignKey.association: '_SalesDistrict'
      SalesDistrict,
      @Consumption.valueHelpDefinition: [              //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

        { entity:  { name:    'I_SalesDealStdVH',
                     element: 'SalesDeal' }    }]      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_SalesDeal'
      SalesDeal,
      @ObjectModel.foreignKey.association: '_CustomerGroup'
      CustomerGroup,
      @ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
      SalesDocumentRjcnReason,

      //Contract

      //TargetQuantityUnitDcmls,


      //Pricing

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      NetAmount,

      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,

      PricingDate,
      ExchangeRateDate,
      PriceDetnExchangeRate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      NetPriceAmount,

      @Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
      NetPriceQuantity,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_NetPriceQuantityUnit'
      NetPriceQuantityUnit,

      @ObjectModel.foreignKey.association: '_StatisticalValueControl'
      StatisticalValueControl,
      _StatisticalValueControl,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TaxAmount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CostAmount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal1Amount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal2Amount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal3Amount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal4Amount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal5Amount,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Subtotal6Amount,

      //Shipping

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,

      //Billing

      BillingDocumentDate,
      @ObjectModel.foreignKey.association: '_ItemIsBillingRelevant'
      ItemIsBillingRelevant,
      @ObjectModel.foreignKey.association: '_ItemBillingBlockReason'
      ItemBillingBlockReason,
      ReferenceBillingPlan,
      ReferenceBillingPlanItem,

      //Payment

      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      CustomerPaymentTerms,
      PaymentMethod,

      //Accounting

      FiscalYear,
      FiscalPeriod,
      @ObjectModel.foreignKey.association: '_CustomerAccountAssgmtGroup'
      CustomerAccountAssignmentGroup,
      @Consumption.valueHelpDefinition: [                         //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

        { entity:  { name:    'I_BusinessAreaStdVH',
                     element: 'BusinessArea' }
        }]
      @ObjectModel.text.association: '_BusinessAreaText'          // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      ProfitCenter,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'WBSElementInternalID'
      WBSElement,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_WBSElementBasicData_2'
      WBSElementInternalID,
      OrderID,
      ControllingObject,      
      @API.element.releaseState: #DECOMMISSIONED
      @API.element.successor:    'ProfitabilitySegment_2'
      ProfitabilitySegment,
      ProfitabilitySegment_2,
      OriginSDDocument,
      OriginSDDocumentItem,

      //Reference

      @ObjectModel.foreignKey.association: '_ReferenceSDDocument'
      ReferenceSDDocument,
      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentItem'
      ReferenceSDDocumentItem,
      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      ReferenceSDDocumentCategory,
      HigherLevelItem,

      //Status

      @ObjectModel.foreignKey.association: '_SDProcessStatus'
      SDProcessStatus,
      @ObjectModel.foreignKey.association: '_OrderRelatedBillingStatus'
      OrderRelatedBillingStatus,
      @ObjectModel.foreignKey.association: '_BillingBlockStatus'
      BillingBlockStatus,
      @ObjectModel.foreignKey.association: '_ItemGeneralIncompletionStatus'
      ItemGeneralIncompletionStatus,
      @ObjectModel.foreignKey.association: '_ItemBillingIncompletionStatus'
      ItemBillingIncompletionStatus,
      @ObjectModel.foreignKey.association: '_PricingIncompletionStatus'
      PricingIncompletionStatus,
      @ObjectModel.foreignKey.association: '_SDDocumentRejectionStatus'
      SDDocumentRejectionStatus,
      @ObjectModel.foreignKey.association: '_TotalSDDocReferenceStatus'
      TotalSDDocReferenceStatus,

      //Association

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                    #TO_COMPOSITION_ROOT]
      _DebitMemoRequest,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Partner,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _PricingElement,
      _ItemCategory,
      _CreatedByUser,
      _Division,
      _Material,
      _Product,
      _OriginallyRequestedMaterial,
      _MaterialPlant,
      _ProductHierarchyNode,
      _MaterialGroup,
      _ProductGroup,
      _MaterialPricingGroup,
      _AdditionalMaterialGroup1,
      _AdditionalMaterialGroup2,
      _AdditionalMaterialGroup3,
      _AdditionalMaterialGroup4,
      _AdditionalMaterialGroup5,
      _Plant,
      _BaseUnit,
      _TargetQuantityUnit,
      _RequestedQuantityUnit,
      _ItemWeightUnit,
      _ItemVolumeUnit,
      _SalesDistrict,
      _SalesDeal,
      _CustomerGroup,
      _SalesDocumentRjcnReason,
      _TransactionCurrency,
      _NetPriceQuantityUnit,
      _IncotermsClassification,
      _IncotermsVersion,
      _ItemIsBillingRelevant,
      _ItemBillingBlockReason,
      _CustomerPaymentTerms,
      //_PaymentMethod,

      _CustomerAccountAssgmtGroup,
      _BusinessArea,
      _ReferenceSDDocument,
      _ReferenceSDDocumentItem,
      _ReferenceSDDocumentCategory,
      _SDProcessStatus,
      _OrderRelatedBillingStatus,
      _BillingBlockStatus,
      _ItemGeneralIncompletionStatus,
      _ItemBillingIncompletionStatus,
      _PricingIncompletionStatus,
      _SDDocumentRejectionStatus,
      _TotalSDDocReferenceStatus,
      //--[ GENERATED:012:GFBfhyK17jY4okn0BRdW}G

      @Consumption.hidden: true
      _BusinessAreaText,
      @Consumption.hidden: true
      _MaterialText,
      @Consumption.hidden: true
      _ProductText,
      @Consumption.hidden: true
      _OrigMaterialText,
      // ]--GENERATED

     _WBSElementBasicData_2

}
where
  SDDocumentCategory = 'L';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEM"
],
"ASSOCIATED":
[
"E_SALESDOCUMENTITEMBASIC",
"I_ADDITIONALMATERIALGROUP1",
"I_ADDITIONALMATERIALGROUP2",
"I_ADDITIONALMATERIALGROUP3",
"I_ADDITIONALMATERIALGROUP4",
"I_ADDITIONALMATERIALGROUP5",
"I_BILLINGBLOCKREASON",
"I_BILLINGBLOCKSTATUS",
"I_BILLINGRELEVANCECODE",
"I_BUSINESSAREA",
"I_BUSINESSAREATEXT",
"I_CURRENCY",
"I_CUSTOMERACCOUNTASSGMTGROUP",
"I_CUSTOMERGROUP",
"I_CUSTOMERPAYMENTTERMS",
"I_DEBITMEMOREQITEMPARTNER",
"I_DEBITMEMOREQITEMPRCGELMNT",
"I_DEBITMEMOREQUEST",
"I_DIVISION",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_ITEMBILLINGINCOMPLETIONSTS",
"I_ITEMGENINCOMPLETIONSTATUS",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALPLANT",
"I_MATERIALPRICINGGROUP",
"I_MATERIALTEXT",
"I_ORDERRELATEDBILLINGSTATUS",
"I_PLANT",
"I_PRICINGINCOMPLETIONSTATUS",
"I_PRODUCT",
"I_PRODUCTGROUP_2",
"I_PRODUCTHIERARCHYNODE",
"I_PRODUCTTEXT",
"I_SALESDEAL",
"I_SALESDISTRICT",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SALESDOCUMENTRJCNREASON",
"I_SDDOCUMENTCATEGORY",
"I_SDDOCUMENTREJECTIONSTATUS",
"I_SDPROCESSSTATUS",
"I_STATISTICALVALUECONTROL",
"I_TOTALSDDOCREFERENCESTATUS",
"I_UNITOFMEASURE",
"I_USER",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_SALESDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/