A_CreditMemoRequest

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Credit Memo Request Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACREDITMEMOREQ',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'Creditmemorequest',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_CreditMemoRequest
  as select from I_CreditMemoRequest as CreditMemoRequest

  association [0..*] to A_CreditMemoRequestItem  as _Item           on _Item.CreditMemoRequest = $projection.CreditMemoRequest

  association [0..*] to A_CreditMemoReqPartner   as _Partner        on _Partner.CreditMemoRequest = $projection.CreditMemoRequest

  association [0..*] to A_CreditMemoReqPrcgElmnt as _PricingElement on _PricingElement.CreditMemoRequest = $projection.CreditMemoRequest
  association [0..*] to A_CreditMemoReqText as _Text on _Text.CreditMemoRequest = $projection.CreditMemoRequest
  association [0..*] to A_CreditMemoReqSubsqntProcFlow    as _SubsequentProcFlowDoc  on _SubsequentProcFlowDoc.CreditMemoRequest = $projection.CreditMemoRequest

  //Extensibility

  association [0..1] to E_SalesDocumentBasic     as _Extension      on $projection.CreditMemoRequest = _Extension.SalesDocument

{

  key CreditMemoRequest,

      
      CreditMemoRequestType,

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,

      @ObjectModel.readOnly: true
      CreationDate,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDate,

      @ObjectModel.readOnly: true
      case tstmp_is_valid(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end as LastChangeDateTime,

      PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,

      CreditMemoRequestDate,
      
      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      @Semantics.currencyCode: true
      TransactionCurrency,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,
      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9, 
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerAccountAssignmentGroup'
      CustomerAccountAssignmentGroup,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      HeaderBillingBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      CustomerPaymentTerms,
      PaymentMethod,

      BillingDocumentDate,
      ServicesRenderedDate,

      ReferenceSDDocument,
      
      @ObjectModel.readOnly: true
      ReferenceSDDocumentCategory,
      
      
      @ObjectModel.readOnly: true
      CreditMemoReqApprovalReason,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
      @ObjectModel.readOnly: true
      SalesDocApprovalStatus,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      @ObjectModel.readOnly: true
      OverallSDProcessStatus,

      
      @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
      @ObjectModel.readOnly: true
      TotalCreditCheckStatus,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      @ObjectModel.readOnly: true
      OverallSDDocumentRejectionSts,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallOrdReltdBillgStatus'
      @ObjectModel.readOnly: true
      OverallOrdReltdBillgStatus,
      
      AccountingDocExternalReference,
      AssignmentReference,
      // Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _SubsequentProcFlowDoc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CREDITMEMOREQUEST"
],
"ASSOCIATED":
[
"A_CREDITMEMOREQPARTNER",
"A_CREDITMEMOREQPRCGELMNT",
"A_CREDITMEMOREQSUBSQNTPROCFLOW",
"A_CREDITMEMOREQTEXT",
"A_CREDITMEMOREQUESTITEM",
"E_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/