A_CreditMemoReqPartner

DDL: A_CREDITMEMOREQPARTNER Type: view COMPOSITE

Header Partner

A_CreditMemoReqPartner is a Composite CDS View that provides data about "Header Partner" in SAP S/4HANA. It reads from 2 data sources (I_SalesDocumentBasic, I_SDDocumentPartner) and exposes 12 fields with key fields CreditMemoRequest, PartnerFunction. It has 2 associations to related views.

2 data source(s) 12 fields

Data Sources (2)

SourceAliasJoin Type
I_SalesDocumentBasic CreditMemoRequest inner
I_SDDocumentPartner Partner from

Associations (2)

CardinalityTargetAliasCondition
[1..1] A_CreditMemoRequest _CreditMemoRequest _CreditMemoRequest.CreditMemoRequest = $projection.CreditMemoRequest
[0..1] I_BusPartAddress _BusinessPartnerAddressCP Partner.AddressID = _BusinessPartnerAddressCP.AddressID and $projection.ContactPerson is not initial and Partner.SDDocPartnerAddressRefType = 'I'

Annotations (13)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Header Partner view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AbapCatalog.sqlViewName ACMRPARTNER view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY CreditMemoRequest SDDocument
KEY PartnerFunction PartnerFunction
Customer Customer
Supplier Supplier
Personnel Personnel
ContactPerson ContactPerson
BPRefAddrForDocSpcfcAddrUUID
CreditMemoRequestType I_SalesDocumentBasic SalesDocumentType
OrganizationDivision I_SalesDocumentBasic OrganizationDivision
SalesOrganization I_SalesDocumentBasic SalesOrganization
DistributionChannel I_SalesDocumentBasic DistributionChannel
_CreditMemoRequest _CreditMemoRequest 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Header Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACMRPARTNER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_CreditMemoReqPartner
  as select from I_SDDocumentPartner as Partner
    inner join I_SalesDocumentBasic as CreditMemoRequest on CreditMemoRequest.SalesDocument = Partner.SDDocument // needed for DCL

                                                  and CreditMemoRequest.SDDocumentCategory     = 'K'
    
   association [1..1] to A_CreditMemoRequest              as _CreditMemoRequest     on  _CreditMemoRequest.CreditMemoRequest = $projection.CreditMemoRequest

  association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP      on Partner.AddressID = _BusinessPartnerAddressCP.AddressID
                                                                           and $projection.ContactPerson is not initial
                                                                           and Partner.SDDocPartnerAddressRefType =  'I'
                                                
{
      @ObjectModel.readOnly: true
  key SDDocument as CreditMemoRequest,
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,

      Customer,
      
      Supplier,

      Personnel,

      ContactPerson,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID,   

      // For Access control

      @Consumption.hidden: true
      CreditMemoRequest.SalesDocumentType as CreditMemoRequestType,
      @Consumption.hidden: true
      CreditMemoRequest.OrganizationDivision,
      @Consumption.hidden: true
      CreditMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      CreditMemoRequest.DistributionChannel,
      
      //Expose associations

      _CreditMemoRequest 
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTADDRESS",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTPARTNER"
],
"ASSOCIATED":
[
"A_CREDITMEMOREQUEST",
"I_BUSPARTADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More