A_CreditMemoReqItemText

DDL: A_CREDITMEMOREQITEMTEXT Type: view COMPOSITE

Item Text

A_CreditMemoReqItemText is a Composite CDS View that provides data about "Item Text" in SAP S/4HANA. It reads from 2 data sources (I_SalesDocumentBasic, P_SalesDocumentItemText) and exposes 11 fields with key fields CreditMemoRequest, CreditMemoRequestItem, Language, LongTextID. It has 2 associations to related views.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
I_SalesDocumentBasic CreditMemoRequest inner
P_SalesDocumentItemText P_SalesDocumentItemText from

Associations (2)

CardinalityTargetAliasCondition
[1..1] A_CreditMemoRequest _CreditMemoRequest _CreditMemoRequest.CreditMemoRequest = $projection.CreditMemoRequest
[1..1] A_CreditMemoRequestItem _CreditMemoRequestItem $projection.CreditMemoRequest = _CreditMemoRequestItem.CreditMemoRequest and $projection.CreditMemoRequestItem = _CreditMemoRequestItem.CreditMemoRequestItem

Annotations (14)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Item Text view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AbapCatalog.sqlViewName ACMRITEXT view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY CreditMemoRequest
KEY CreditMemoRequestItem
KEY Language Language
KEY LongTextID LongTextID
LongText LongText
CreditMemoRequestType I_SalesDocumentBasic SalesDocumentType
OrganizationDivision I_SalesDocumentBasic OrganizationDivision
SalesOrganization I_SalesDocumentBasic SalesOrganization
DistributionChannel I_SalesDocumentBasic DistributionChannel
_CreditMemoRequest _CreditMemoRequest
_CreditMemoRequestItem _CreditMemoRequestItem 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Text'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACMRITEXT',
  preserveKey :true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true


define view A_CreditMemoReqItemText 
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as CreditMemoReqItemText
    inner join   I_SalesDocumentBasic                                     as CreditMemoRequest on  CreditMemoRequest.SalesDocument = CreditMemoReqItemText.SalesDocument
                                                                                              and SDDocumentCategory               = 'K'
                                                                                                
  association [1..1] to A_CreditMemoRequest     as _CreditMemoRequest     on  _CreditMemoRequest.CreditMemoRequest = $projection.CreditMemoRequest
  association [1..1] to A_CreditMemoRequestItem as _CreditMemoRequestItem on  $projection.CreditMemoRequest        = _CreditMemoRequestItem.CreditMemoRequest
                                                                          and $projection.CreditMemoRequestItem    = _CreditMemoRequestItem.CreditMemoRequestItem
{

      @ObjectModel.readOnly: true
  key cast(CreditMemoReqItemText.SalesDocument as credit_memo_request preserving type) as CreditMemoRequest,

      @ObjectModel.readOnly: true
  key cast(CreditMemoReqItemText.SalesDocumentItem as credit_memo_request_item preserving type) as CreditMemoRequestItem,

  key Language,
  key LongTextID,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_STXL_CMR'
      LongText,

      // For Access control

      @Consumption.hidden: true
      CreditMemoRequest.SalesDocumentType as CreditMemoRequestType,
      @Consumption.hidden: true
      CreditMemoRequest.OrganizationDivision,
      @Consumption.hidden: true
      CreditMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      CreditMemoRequest.DistributionChannel,

      // Expose own associations

      _CreditMemoRequest,
      _CreditMemoRequestItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTBASIC"
],
"ASSOCIATED":
[
"A_CREDITMEMOREQUEST",
"A_CREDITMEMOREQUESTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More