A_CreditMemoReqItemPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACMRITMPARTNER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_CreditMemoReqItemPartner
  as select from I_SDDocumentItemPartner as Partner
    inner join   I_SalesDocumentBasic    as CreditMemoRequest on  CreditMemoRequest.SalesDocument = Partner.SDDocument
                                                       and SDDocumentCategory       = 'K'

  association [1..1] to A_CreditMemoRequest     as _CreditMemoRequest     on  $projection.CreditMemoRequest = _CreditMemoRequest.CreditMemoRequest
  association [1..1] to A_CreditMemoRequestItem as _CreditMemoRequestItem on  $projection.CreditMemoRequest     = _CreditMemoRequestItem.CreditMemoRequest
                                                            and $projection.CreditMemoRequestItem = _CreditMemoRequestItem.CreditMemoRequestItem
                                                            
  association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP      on Partner.AddressID = _BusinessPartnerAddressCP.AddressID
                                                                           and $projection.ContactPerson is not initial
                                                                           and Partner.SDDocPartnerAddressRefType =  'I'                                                          
  
{
      @ObjectModel.readOnly: true
  key SDDocument                                      as CreditMemoRequest,

      @ObjectModel.readOnly: true
  key SDDocumentItem                                  as CreditMemoRequestItem,
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,

      Customer,

      Supplier,

      Personnel,

      ContactPerson,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID,    

      // For Access control

      @Consumption.hidden: true
      CreditMemoRequest.SalesDocumentType as CreditMemoRequestType,
      @Consumption.hidden: true
      CreditMemoRequest.OrganizationDivision,
      @Consumption.hidden: true
      CreditMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      CreditMemoRequest.DistributionChannel,

      //Expose associations

      _CreditMemoRequest,
      _CreditMemoRequestItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTADDRESS",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTITEMPARTNER"
],
"ASSOCIATED":
[
"A_CREDITMEMOREQUEST",
"A_CREDITMEMOREQUESTITEM",
"I_BUSPARTADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/