A_CnsldtnPartnerPrftCtrHierT

@AbapCatalog:{
  sqlViewName: 'ACSPARTPRFTCTRHT',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #XL},
  dataCategory: #TEXT,
  representativeKey: 'HierarchyNode'
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Partner PrftCtr HierNode - Txt'
@OData.entitySet.name: 'PartnerProfitCenterHierText'

define view A_CnsldtnPartnerPrftCtrHierT
  as select from I_CnsldtnProfitCenterHierNodeT as _HierNodeText

    inner join   A_CnsldtnPartnerPrftCtrHier    as _HierNode on  _HierNodeText.ControllingArea               = _HierNode.ControllingArea
                                                             and _HierNodeText.ConsolidationPrftCtrHierarchy = _HierNode.AdditionalMasterDataHierarchy
                                                             and _HierNodeText.HierarchyNode                 = _HierNode.HierarchyNode
                                                             and _HierNodeText.ValidityEndDate               = _HierNode.ValidityEndDate

  association [0..1] to A_CnsldtnPartPrftCtrHierDir as _CnsldtnPartPrftCtrHierDir on  $projection.AdditionalMasterDataHierarchy = _CnsldtnPartPrftCtrHierDir.AdditionalMasterDataHierarchy
                                                                                  and $projection.ValidityEndDate               = _CnsldtnPartPrftCtrHierDir.ValidityEndDate

  association [0..1] to A_CnsldtnControllingArea    as _CnsldtnControllingArea    on  $projection.ControllingArea = _CnsldtnControllingArea.ControllingArea
{
      @ObjectModel.foreignKey.association: '_CnsldtnControllingArea'
  key _HierNodeText.ControllingArea,

      @ObjectModel.foreignKey.association: '_CnsldtnPartPrftCtrHierDir'
  key cast(left(_HierNodeText.ConsolidationPrftCtrHierarchy, 40) as fincs_hryid_profitcenter preserving type ) as AdditionalMasterDataHierarchy,

  key _HierNodeText.HierarchyNode,

      @Semantics.businessDate.to: true
  key _HierNodeText.ValidityEndDate,

      @Semantics.language: true
  key _HierNodeText.Language,

      @Semantics.text: true
      @EndUserText.label: 'Node Description'
      _HierNodeText.HierarchyNodeText,

      @Semantics.businessDate.from: true
      _HierNodeText.ValidityStartDate,

      _HierNode.NodeType,


      _CnsldtnPartPrftCtrHierDir,
      _CnsldtnControllingArea
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_CNSLDTNPARTNERPRFTCTRHIER",
"I_CNSLDTNPROFITCENTERHIERNODET"
],
"ASSOCIATED":
[
"A_CNSLDTNCONTROLLINGAREA",
"A_CNSLDTNPARTPRFTCTRHIERDIR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/