A_CnsldtnPartnerPrftCtrHier

@AbapCatalog.sqlViewName: 'ACSPARTPRFTCTRH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Combined Partner Profit Center Hierarchy'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
  }
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@OData.entitySet.name: 'PartnerProfitCenterHier'

define view A_CnsldtnPartnerPrftCtrHier

  as select from I_CnsldtnProfitCenterHierNode as I_CnsldtnPartPrftCtrHierarchy

  association [0..*] to A_CnsldtnPartnerPrftCtrHierT as _CnsldtnPartnerPrftCtrHierT   on  $projection.ControllingArea               = _CnsldtnPartnerPrftCtrHierT.ControllingArea
                                                                                      and $projection.AdditionalMasterDataHierarchy = _CnsldtnPartnerPrftCtrHierT.AdditionalMasterDataHierarchy
                                                                                      and $projection.HierarchyNode                 = _CnsldtnPartnerPrftCtrHierT.HierarchyNode
                                                                                      and $projection.ProfitCenter                  = ''

  association [0..*] to A_CnsldtnPartnerPrftCtrHierT as _CnsldtnPartnerPrftCtrHierT_2 on  $projection.ControllingArea               = _CnsldtnPartnerPrftCtrHierT_2.ControllingArea
                                                                                      and $projection.AdditionalMasterDataHierarchy = _CnsldtnPartnerPrftCtrHierT_2.AdditionalMasterDataHierarchy
                                                                                      and $projection.HierarchyNode                 = _CnsldtnPartnerPrftCtrHierT_2.HierarchyNode
                                                                                      and $projection.ValidityEndDate               = _CnsldtnPartnerPrftCtrHierT_2.ValidityEndDate
                                                                                      and $projection.ProfitCenter                  = ''

  association [0..1] to A_CnsldtnPartnerProfitCenter as _CnsldtnPartnerProfitCenter   on  $projection.ControllingArea = _CnsldtnPartnerProfitCenter.ControllingArea
                                                                                      and $projection.ProfitCenter    = _CnsldtnPartnerProfitCenter.ProfitCenter


  association [0..1] to A_CnsldtnControllingArea     as _CnsldtnControllingArea       on  $projection.ControllingArea = _CnsldtnControllingArea.ControllingArea
  association [0..*] to A_CnsldtnPartnerPrftCtrT     as _CnsldtnPartnerPrftCtrT       on  $projection.ProfitCenter    = _CnsldtnPartnerPrftCtrT.ProfitCenter
                                                                                      and $projection.ControllingArea = _CnsldtnPartnerPrftCtrT.ControllingArea

{
      @ObjectModel.foreignKey.association: '_CnsldtnControllingArea'
  key ControllingArea,
  key cast(left(ConsolidationPrftCtrHierarchy, 40) as fincs_hryid_profitcenter preserving type ) as AdditionalMasterDataHierarchy,
      @ObjectModel.text.association: '_CnsldtnPartnerPrftCtrHierT_2'
  key HierarchyNode,
      @Semantics.businessDate.to: true
  key I_CnsldtnPartPrftCtrHierarchy.ValidityEndDate,
      ParentNode,
      HierarchyVersion,
      @Semantics.businessDate.from: true
      I_CnsldtnPartPrftCtrHierarchy.ValidityStartDate,
      @EndUserText.label: 'Partner Profit Center'
      @ObjectModel.text.association: '_CnsldtnPartnerPrftCtrT'
      ProfitCenter,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                            as SequenceNumber,
      // STS - compatible ATC cleanup change - to be removed


      // STS - compatible ATC cleanup change

      HierarchyNodeSequence,
      // STS - compatible ATC cleanup change


      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true
      cast( 'CS04' as hrytype preserving type )                                                  as MDHierType,

      @Consumption.hidden: true
      cast( 'CS04' as hrytype preserving type )                                                  as HierarchyType,


      _CnsldtnPartnerProfitCenter,
      _CnsldtnPartnerPrftCtrHierT,
      _CnsldtnPartnerPrftCtrHierT_2,
      _CnsldtnControllingArea,
      _CnsldtnPartnerPrftCtrT
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNPROFITCENTERHIERNODE"
],
"ASSOCIATED":
[
"A_CNSLDTNCONTROLLINGAREA",
"A_CNSLDTNPARTNERPRFTCTRHIERT",
"A_CNSLDTNPARTNERPRFTCTRT",
"A_CNSLDTNPARTNERPROFITCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/