A_CnsldtnFSItemHierT

@AbapCatalog.sqlViewName: 'ACSFSITEMHIERT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #XL
  }
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'HierarchyNode'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@EndUserText.label: 'Financial Statement Item Hier Node - Txt'
@OData.entitySet.name: 'FinancialStmntItemHierText'

define view A_CnsldtnFSItemHierT
  as select from I_CnsldtnFSItemHierNodeText_2 as _CnsldtnFSItemHierNodeText_2

  association [0..1] to A_CnsldtnFSItemHierDir    as _CnsldtnFSItemHierDir    on  $projection.FinancialStatementItemHier   = _CnsldtnFSItemHierDir.FinancialStatementItemHier
                                                                              and $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemHierDir.ConsolidationChartOfAccounts

  association [0..1] to A_CnsldtnChartOfAccounts  as _CnsldtnChartOfAccounts  on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccounts.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnChartOfAccountsT as _CnsldtnChartOfAccountsT on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccountsT.ConsolidationChartOfAccounts

  association [1..1] to A_CnsldtnFSItemHier       as _CnsldtnFSItemHier       on  $projection.FinancialStatementItemHier   = _CnsldtnFSItemHier.FinancialStatementItemHier
                                                                              and $projection.HierarchyNode                = _CnsldtnFSItemHier.HierarchyNode
                                                                              and $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemHier.ConsolidationChartOfAccounts

{
      @EndUserText: {
        label: 'Consolidation Chart of Accounts',
        quickInfo: 'Consolidation Chart of Accounts'
      }
      @ObjectModel.foreignKey.association: '_CnsldtnChartOfAccounts'
      @ObjectModel.text.association: '_CnsldtnChartOfAccountsT'
  key _CnsldtnFSItemHierNodeText_2.ConsolidationChartOfAccounts,

      @ObjectModel.foreignKey.association: '_CnsldtnFSItemHierDir'
  key _CnsldtnFSItemHierNodeText_2.CnsldtnFSItemHierarchy as FinancialStatementItemHier,

      @ObjectModel.foreignKey.association: '_CnsldtnFSItemHier'
  key _CnsldtnFSItemHierNodeText_2.HierarchyNode,

      @Semantics.language: true
  key _CnsldtnFSItemHierNodeText_2.Language,

      @Semantics.text: true
      @EndUserText.label: 'Node Description'
      _CnsldtnFSItemHierNodeText_2.HierarchyNodeText,

      _CnsldtnFSItemHier.NodeType,


      // associations

      @Consumption.hidden: true
      _CnsldtnChartOfAccountsT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnChartOfAccounts, // required for value help retrieval


      @Consumption.hidden: true
      _CnsldtnFSItemHierDir, // required for value help retrieval


      _CnsldtnFSItemHier // required for value help retrieval and navigation

}
where
  (
    (
          _CnsldtnFSItemHierNodeText_2.ValidityStartDate = '00000000'
      and _CnsldtnFSItemHierNodeText_2.ValidityEndDate   = '00000000'
    )
    or(
          _CnsldtnFSItemHierNodeText_2.ValidityStartDate <= $session.system_date
      and _CnsldtnFSItemHierNodeText_2.ValidityEndDate   >= $session.system_date
    )
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_CNSLDTNFSITEMHIER",
"I_CNSLDTNFSITEMHIERNODETEXT_2"
],
"ASSOCIATED":
[
"A_CNSLDTNCHARTOFACCOUNTS",
"A_CNSLDTNCHARTOFACCOUNTST",
"A_CNSLDTNFSITEMHIER",
"A_CNSLDTNFSITEMHIERDIR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/