A_CN_TaxInputInvoice

@AbapCatalog.sqlViewName: 'ACNTXIIPT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ObjectModel: {
  createEnabled: true,
  updateEnabled: false,
  deleteEnabled: false,
  compositionRoot: true,
  usageType: {
    serviceQuality: #B,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  }
}
@EndUserText.label: 'China Input Tax Invoice'
@Metadata: {
  ignorePropagatedAnnotations: true
}

define view A_CN_TaxInputInvoice

  as select from I_CN_TaxInputInvc as hdr

  association [1..*] to A_CN_TaxInputInvoiceItem     as _Item            on $projection.CN_TaxInvcUUID = _Item.CN_TaxInvcUUID

  association [1..*] to A_CN_TaxInvoiceBindingRecord as _Binding         on $projection.CN_TaxInvcUUID = _Binding.CN_TaxInvcUUID
  
  association [1..1] to A_Supplier                   as _Supplier        on $projection.Supplier = _Supplier.Supplier

  association [1..1] to E_CN_TaxInputInvc            as _CommonExtension on $projection.CN_TaxInvcUUID = _CommonExtension.CN_TaxInvcUUID

  association [1..1] to E_CN_TaxInputInvcMng         as _ManageExtension on $projection.CN_TaxInvcUUID = _ManageExtension.CN_TaxInvcUUID  

{
      @ObjectModel.readOnly: true
  key hdr.CN_TaxInvcUUID,

      hdr.CN_TaxInvcCode,
      hdr.CN_TaxInvcNmbr,
      hdr.CN_TaxSellerRegnNmbr,
      hdr.CN_TaxBuyerRegnNmbr,
      @ObjectModel.sapObjectNodeTypeReference:'CN_ValueAddedTaxInvoiceType'
      hdr.CN_TaxInvcType,
      @Semantics.businessDate.at: true
      hdr.CN_TaxInvcDate,
      @Semantics.currencyCode: true
      hdr.CN_TaxInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcNetAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcTaxAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcDeductAmtInInvcCrcy,
      hdr.CN_TaxEntityID as BusinessPlace,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcDiscNetAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcDiscTaxAmtInInvcCrcy,
      hdr.TaxRate,
      hdr.CompanyCode,
      @ObjectModel.sapObjectNodeTypeReference:'CN_ValueAddedTaxInvoiceSystSts'
      hdr.CN_TaxInvcGldnTxSystSts,
      hdr.CN_TaxInvcGldnTxSystStsSyncTme,
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference:'CN_ValueAddedTaxInvcProcgSts'
      hdr.CN_TaxInvcInptProcgSts,
      @ObjectModel.sapObjectNodeTypeReference:'CN_ValueAddedTaxDeductionType'
      hdr.CN_TaxInvcDeductionType,
      hdr.CN_TaxSellerName,
      hdr.CN_TaxInvcComment,
      hdr.CN_TaxInvoiceUsage,
      hdr.CN_TaxInvoiceDataSource,
      hdr.CN_TaxInvoiceExpenseReportNmbr,
      hdr.IsPostedOnAccount,
      @ObjectModel.sapObjectNodeTypeReference:'CN_ValueAddedTaxInvoiceCat'
      hdr.TaxCategory,
      @ObjectModel.readOnly: true
      hdr.CN_TaxDeclnTime,
      @ObjectModel.readOnly: true
      hdr.CN_TaxDeclnYear,
      @ObjectModel.readOnly: true
      hdr.CN_TaxDeclnMonth,
      hdr.TaxInvoiceBuyerAddressPhone,
      hdr.TaxInvoiceBuyerBankAccount,
      hdr.TaxInvoiceSellerAddressPhone,
      hdr.TaxInvoiceSellerBankAccount,

      // Vehicle Invoice

      hdr.CN_TaxInvoiceVehicleType,
      hdr.CN_TaxInvoiceVehFactoryModel,
      hdr.CN_TaxInvoiceVehicleProdnPlace,
      hdr.CN_TaxInvoiceVehicleCertNumber,
      hdr.CN_TaxInvoiceVehImportCertNmbr,
      hdr.CN_TaxInvoiceVehicleInspNumber,
      hdr.CN_TaxInvoiceVehicleEngineNmbr,
      hdr.CN_TaxInvoiceVehicleNumber,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcVehTotAmtInInvcCrcy,
      hdr.CN_TaxInvoiceVehTxnRecordNmbr,
      hdr.CN_TaxInvoiceVehicleTonnage,
      hdr.CN_TaxInvoiceVehPassengerLimit,

      hdr.PurchasingOrganization,
      hdr.PurchasingGroup,
      hdr.Supplier,

      // Association

      _Item,
      _Binding,
      _Supplier
}
where
  hdr.IsDeleted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CN_TAXINPUTINVC"
],
"ASSOCIATED":
[
"A_CN_TAXINPUTINVOICEITEM",
"A_CN_TAXINVOICEBINDINGRECORD",
"A_SUPPLIER",
"E_CN_TAXINPUTINVC",
"E_CN_TAXINPUTINVCMNG"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/