Which CDS Views use I_CN_TAXINPUTINVC?

I_CN_TAXINPUTINVC is used by 6 CDS view(s), including: A_CN_TaxInputInvoice, C_CN_TaxDeductionItemCube, C_CN_TaxInputInvc, C_CN_TaxInputInvcBind, C_CN_TaxTransferItemCube, I_CN_TaxInputInvcTP.

How many fields does I_CN_TAXINPUTINVC have?

I_CN_TAXINPUTINVC has 57 fields. Key fields: CN_TaxInvcUUID.

I_CN_TAXINPUTINVC

CDS View

Incoming VAT Invoice

I_CN_TAXINPUTINVC is a CDS View in S/4HANA. Incoming VAT Invoice. It contains 57 fields. 6 CDS views read from this table.

CDS Views using this table (6)

View	Type	Join	VDM	Description
A_CN_TaxInputInvoice	view	from	BASIC	China Input Tax Invoice
C_CN_TaxDeductionItemCube	view	from	CONSUMPTION	Input VAT Deduction Item
C_CN_TaxInputInvc	view	from	CONSUMPTION	Incoming VAT Invoice
C_CN_TaxInputInvcBind	view	from	CONSUMPTION	China Tax Invoice for Binding
C_CN_TaxTransferItemCube	view	left_outer	CONSUMPTION	Input VAT Transfer Item Cube
I_CN_TaxInputInvcTP	view_entity	from	TRANSACTIONAL	Incoming VAT Invoice

Fields (57)

Key	Field	CDS Fields	Used in Views
KEY	CN_TaxInvcUUID	CN_TaxInvcUUID	6
	CN_TaxBuyerRegnNmbr	CN_TaxBuyerRegnNmbr	2
	CN_TaxDeclnMonth	CN_TaxDeclnMonth	3
	CN_TaxDeclnTime	CN_TaxDeclnTime	2
	CN_TaxDeclnYear	CN_TaxDeclnYear	3
	CN_TaxEntityID	BusinessPlace,CN_TaxEntityID	3
	CN_TaxInvcCode	CN_TaxInvcCode	4
	CN_TaxInvcComment	CN_TaxInvcComment	4
	CN_TaxInvcCrcy	CN_TaxInvcCrcy	5
	CN_TaxInvcDate	CN_TaxInvcDate	4
	CN_TaxInvcDeductAmtInInvcCrcy	CN_TaxInvcDeductAmtInInvcCrcy	3
	CN_TaxInvcDeductionType	CN_TaxInvcDeductionType	4
	CN_TaxInvcDiscNetAmtInInvcCrcy	CN_TaxInvcDiscNetAmtInInvcCrcy	4
	CN_TaxInvcDiscTaxAmtInInvcCrcy	CN_TaxInvcDiscTaxAmtInInvcCrcy	4
	CN_TaxInvcGldnTxSystSts	CN_TaxInvcGldnTxSystSts	4
	CN_TaxInvcGldnTxSystStsSyncTme	CN_TaxInvcGldnTxSystStsSyncTme	4
	CN_TaxInvcInptProcgSts	CN_TaxInvcInptProcgSts	5
	CN_TaxInvcIsElectronic	CN_TaxInvcIsElectronic	3
	CN_TaxInvcNetAmtInInvcCrcy	CN_TaxInvcNetAmtInInvcCrcy,ZeroTaxBaseAmountInCoCodeCrcy	5
	CN_TaxInvcNmbr	CN_TaxInvcNmbr	4
	CN_TaxInvcTaxAmtInInvcCrcy	CN_TaxInvcTaxAmtInInvcCrcy,TaxAmount	5
	CN_TaxInvcType	CN_TaxInvcType	3
	CN_TaxInvcVehTotAmtInInvcCrcy	CN_TaxInvcVehTotAmtInInvcCrcy	2
	CN_TaxInvoiceDataSource	CN_TaxInvoiceDataSource	3
	CN_TaxInvoiceExpenseReportNmbr	CN_TaxInvoiceExpenseReportNmbr	3
	CN_TaxInvoiceUsage	CN_TaxInvoiceUsage	3
	CN_TaxInvoiceVehFactoryModel	CN_TaxInvoiceVehFactoryModel	2
	CN_TaxInvoiceVehicleCertNumber	CN_TaxInvoiceVehicleCertNumber	2
	CN_TaxInvoiceVehicleEngineNmbr	CN_TaxInvoiceVehicleEngineNmbr	2
	CN_TaxInvoiceVehicleInspNumber	CN_TaxInvoiceVehicleInspNumber	2
	CN_TaxInvoiceVehicleNumber	CN_TaxInvoiceVehicleNumber	2
	CN_TaxInvoiceVehicleProdnPlace	CN_TaxInvoiceVehicleProdnPlace	2
	CN_TaxInvoiceVehicleTonnage	CN_TaxInvoiceVehicleTonnage	2
	CN_TaxInvoiceVehicleType	CN_TaxInvoiceVehicleType	2
	CN_TaxInvoiceVehImportCertNmbr	CN_TaxInvoiceVehImportCertNmbr	2
	CN_TaxInvoiceVehPassengerLimit	CN_TaxInvoiceVehPassengerLimit	2
	CN_TaxInvoiceVehTxnRecordNmbr	CN_TaxInvoiceVehTxnRecordNmbr	2
	CN_TaxSellerName	CN_TaxSellerName	4
	CN_TaxSellerRegnNmbr	CN_TaxSellerRegnNmbr	2
	CompanyCode	CompanyCode	3
	CreatedByUser	CreatedByUser	3
	CreationUTCDateTime	CreationUTCDateTime	3
	FiscalYear	FiscalYear	1
	IsPostedOnAccount	IsPostedOnAccount	3
	LastChangeDateTime	LastChangeDateTime	3
	LastChangedByUser	LastChangedByUser	3
	PurchasingGroup	PurchasingGroup	4
	PurchasingOrganization	PurchasingOrganization	4
	Supplier	Supplier	4
	TaxCategory	TaxCategory	3
	TaxInvoiceBuyerAddressPhone	TaxInvoiceBuyerAddressPhone	2
	TaxInvoiceBuyerBankAccount	TaxInvoiceBuyerBankAccount	2
	TaxInvoiceDeclarationTypeCode	TaxInvoiceDeclarationTypeCode	1
	TaxInvoiceIsTaxRebate	TaxInvoiceIsTaxRebate	1
	TaxInvoiceSellerAddressPhone	TaxInvoiceSellerAddressPhone	2
	TaxInvoiceSellerBankAccount	TaxInvoiceSellerBankAccount	2
	TaxRate	TaxRate	2

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
    sqlViewName: 'ICNTXIIPT',
    compiler.compareFilter: true
}
@VDM: {
    viewType: #BASIC,
    private: false
}
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Incoming VAT Invoice'
@ObjectModel: {
  representativeKey: 'CN_TaxInvcUUID',
  usageType: {
    serviceQuality: #A,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  }
}

define view I_CN_TaxInputInvc
  as select from P_CN_TaxInputInvc as hdr

  // foreign keys

  association [1]    to I_Currency                as _Currency               on $projection.CN_TaxInvcCrcy = _Currency.Currency

  association [1]    to I_CompanyCode             as _CompanyCode            on $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_PurchasingOrganization  as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [0..1] to I_PurchasingGroup         as _PurchasingGroup        on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

  association [0..1] to I_Supplier                as _Supplier               on $projection.Supplier = _Supplier.Supplier

  association [1]    to I_CN_TaxEntity            as _TaxEntity              on $projection.CN_TaxEntityID = _TaxEntity.CN_TaxEntityID
                                                                             and $projection.CompanyCode = _TaxEntity.CompanyCode

  association [1]    to I_CN_TaxInvcType          as _InvoiceType            on $projection.CN_TaxInvcType = _InvoiceType.CN_TaxInvcType

  association [1]    to I_CN_TaxInvcDeductionType as _DeductionType          on $projection.CN_TaxInvcDeductionType = _DeductionType.CN_TaxInvcDeductionType

  association [0..*] to I_CN_TaxInputInvcStsChgLg as _ChangeLog              on $projection.CN_TaxInvcUUID = _ChangeLog.CN_TaxInvcUUID

  association [1..1] to I_CN_TaxInvcInptProcgSts  as _InvoiceStatus          on $projection.CN_TaxInvcInptProcgSts = _InvoiceStatus.CN_TaxInvcInptProcgSts

  association [1..1] to I_CN_TaxInvcGldnTxSystSts as _GoldenTaxStatus        on $projection.CN_TaxInvcGldnTxSystSts = _GoldenTaxStatus.CN_TaxInvcGldnTxSystSts

  association [0..1] to I_CN_TaxInptVATCat        as _VATCategory            on $projection.TaxCategory = _VATCategory.TaxCategory

  association [1..1] to I_CN_TaxInvoiceDeclnType  as _DeclnType              on $projection.TaxInvoiceDeclarationTypeCode = _DeclnType.TaxInvoiceDeclarationTypeCode

  association [1..*] to I_CN_TaxInputInvoiceItem  as _InvoiceItem            on $projection.CN_TaxInvcUUID = _InvoiceItem.CN_TaxInvcUUID

{
  key hdr.CN_TaxInvcUUID,

      hdr.CN_TaxInvcCode,
      hdr.CN_TaxInvcNmbr,

      cast ( hdr.CN_TaxSellerRegnNmbr as ficntax_slr_reg_nmbr )                as CN_TaxSellerRegnNmbr,
      cast ( hdr.CN_TaxBuyerRegnNmbr as ficntax_buyr_reg_nmbr)                 as CN_TaxBuyerRegnNmbr,
      @ObjectModel.foreignKey.association: '_InvoiceType'
      hdr.CN_TaxInvcType,
      @Semantics.businessDate.at: true
      hdr.CN_TaxInvcDate,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      hdr.CN_TaxInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      @DefaultAggregation: #NONE
      hdr.CN_TaxInvcNetAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      @DefaultAggregation: #NONE
      hdr.CN_TaxInvcTaxAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      @DefaultAggregation: #NONE
      hdr.CN_TaxInvcDeductAmtInInvcCrcy,
      @ObjectModel.foreignKey.association: '_TaxEntity'
      hdr.CN_TaxEntityID,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      @DefaultAggregation: #NONE
      hdr.CN_TaxInvcDiscNetAmtInInvcCrcy,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      @DefaultAggregation: #NONE
      hdr.CN_TaxInvcDiscTaxAmtInInvcCrcy,
      hdr.CN_TaxInvcIsElectronic,
      hdr.TaxRate,
      hdr.IsDeleted,
      hdr.CN_TaxInvoiceUsage,
      hdr.CN_TaxInvoiceDataSource,
      hdr.CN_TaxInvoiceExpenseReportNmbr,
      hdr.IsPostedOnAccount,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      hdr.CompanyCode,
      @ObjectModel.foreignKey.association: '_GoldenTaxStatus'
      hdr.CN_TaxInvcGldnTxSystSts,
      hdr.CN_TaxInvcGldnTxSystStsSyncTme,
      @ObjectModel.foreignKey.association: '_InvoiceStatus'
      hdr.CN_TaxInvcInptProcgSts,
      @ObjectModel.foreignKey.association: '_DeductionType'
      hdr.CN_TaxInvcDeductionType,
      hdr.FiscalYear,
      hdr.CN_TaxSellerName,
      hdr.CN_TaxInvcComment,
      @ObjectModel.foreignKey.association: '_VATCategory'
      hdr.TaxCategory,
      // *** RAP migration ***

      //@ObjectModel.readOnly: true

      // *** end of RAP migration *

      hdr.CN_TaxDeclnTime,
            // *** RAP migration ***

      //@ObjectModel.readOnly: true

      // *** end of RAP migration *

      hdr.CN_TaxDeclnYear,
            // *** RAP migration ***

      //@ObjectModel.readOnly: true

      // *** end of RAP migration *

      hdr.CN_TaxDeclnMonth,
      cast ( hdr.TaxInvoiceBuyerAddressPhone as ficntaxinvc_buyer_addr )       as TaxInvoiceBuyerAddressPhone,
      cast ( hdr.TaxInvoiceBuyerBankAccount as ficntaxinvc_buyer_bank_acct )   as TaxInvoiceBuyerBankAccount,
      cast ( hdr.TaxInvoiceSellerAddressPhone as ficntaxinvc_seller_addr )     as TaxInvoiceSellerAddressPhone,
      cast ( hdr.TaxInvoiceSellerBankAccount as ficntaxinvc_seller_bank_acct ) as TaxInvoiceSellerBankAccount,
      // *** RAP migration ***

      //@ObjectModel.readOnly: true

      // *** end of RAP migration ***

      hdr.TaxInvoiceIsTaxRebate,
      @ObjectModel.foreignKey.association: '_DeclnType'
      // *** RAP migration ***

      //@ObjectModel.readOnly: true

      // *** end of RAP migration ***

      hdr.TaxInvoiceDeclarationTypeCode,

      // Vehicle Invoice

      hdr.CN_TaxInvoiceVehicleType,
      hdr.CN_TaxInvoiceVehFactoryModel,
      hdr.CN_TaxInvoiceVehicleProdnPlace,
      hdr.CN_TaxInvoiceVehicleCertNumber,
      hdr.CN_TaxInvoiceVehImportCertNmbr,
      hdr.CN_TaxInvoiceVehicleInspNumber,
      hdr.CN_TaxInvoiceVehicleEngineNmbr,
      hdr.CN_TaxInvoiceVehicleNumber,
      @Semantics.amount.currencyCode: 'CN_TaxInvcCrcy'
      hdr.CN_TaxInvcVehTotAmtInInvcCrcy,
      hdr.CN_TaxInvoiceVehTxnRecordNmbr,
      hdr.CN_TaxInvoiceVehicleTonnage,
      hdr.CN_TaxInvoiceVehPassengerLimit,

      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      hdr.PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      hdr.PurchasingGroup,
      @ObjectModel.foreignKey.association: '_Supplier'
      hdr.Supplier,

      @Semantics.user.createdBy: true
      hdr.CreatedByUser,
      //@Semantics.systemDate.createdAt: true

      hdr.CreationUTCDateTime,
      @Semantics.user.lastChangedBy: true
      hdr.LastChangedByUser,
      //@Semantics.systemDate.lastChangedAt: true

      hdr.LastChangeDateTime,

      _Currency,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _Supplier,
      _TaxEntity,
      _InvoiceType,
      _DeductionType,
      _ChangeLog,
      _InvoiceStatus,
      _GoldenTaxStatus,
      _VATCategory,
      _DeclnType,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _InvoiceItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CN_TAXINPUTINVC"
],
"ASSOCIATED":
[
"I_CN_TAXENTITY",
"I_CN_TAXINPTVATCAT",
"I_CN_TAXINPUTINVCSTSCHGLG",
"I_CN_TAXINPUTINVOICEITEM",
"I_CN_TAXINVCDEDUCTIONTYPE",
"I_CN_TAXINVCGLDNTXSYSTSTS",
"I_CN_TAXINVCINPTPROCGSTS",
"I_CN_TAXINVCTYPE",
"I_CN_TAXINVOICEDECLNTYPE",
"I_COMPANYCODE",
"I_CURRENCY",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Depth:

I_CN_TAXINPUTINVC

CDS Views using this table (6)

Fields (57)

Learn More