A_BusinessPartnerAddress

@AbapCatalog.sqlViewName: 'ABUPARTADDRESS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Address'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL 
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled:true
@ObjectModel.deleteEnabled:true
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
//@AccessControl.privilegedAssociations:  [ '_PhoneNumber','_MobilePhoneNumber','_FaxNumber','_EmailAddress','_URLAddress' ]


define view A_BusinessPartnerAddress as select from I_BusPartAddress 
inner join I_Address as _Address on I_BusPartAddress.AddressID = _Address.AddressID

  association [1..1] to A_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
   
  association [0..*] to A_AddressPhoneNumber as _PhoneNumber on _PhoneNumber.AddressID = $projection.AddressID
                                                             and ( _PhoneNumber.Person = $projection.Person or _PhoneNumber.Person = ' ' )
                                                             and ( _PhoneNumber.PhoneNumberType = '1' or _PhoneNumber.PhoneNumberType = ' ' )                                                                    

  association [0..*] to A_AddressPhoneNumber as _MobilePhoneNumber on _MobilePhoneNumber.AddressID = $projection.AddressID
                                                                   and ( _MobilePhoneNumber.Person = $projection.Person or _MobilePhoneNumber.Person = ' ' )
                                                                   and ( _MobilePhoneNumber.PhoneNumberType = '2' or _MobilePhoneNumber.PhoneNumberType = '3' )
                                                                
  association [0..*] to A_AddressFaxNumber as _FaxNumber on _FaxNumber.AddressID = $projection.AddressID
                                                         and ( _FaxNumber.Person = $projection.Person or _FaxNumber.Person = ' ' )                                                                         

  association [0..*] to A_AddressEmailAddress as _EmailAddress on _EmailAddress.AddressID = $projection.AddressID
                                                               and ( _EmailAddress.Person = $projection.Person or _EmailAddress.Person = ' ' )                                                                     

  association [0..*] to A_AddressHomePageURL as _URLAddress on _URLAddress.AddressID = $projection.AddressID
                                                            and ( _URLAddress.Person = $projection.Person or _URLAddress.Person = ' ' )
                         
  association [0..*] to A_BuPaAddressUsage as _AddressUsage on  _AddressUsage.BusinessPartner = $projection.BusinessPartner
                                                            and _AddressUsage.AddressID = $projection.AddressID
                                                                   
  association [0..1] to A_BPAddrDepdntIntlLocNumber as _BPAddrDepdntIntlLocNumber on  _BPAddrDepdntIntlLocNumber.BusinessPartner = $projection.BusinessPartner
                                                                                  and _BPAddrDepdntIntlLocNumber.AddressID = $projection.AddressID    
                                                                                  
  association [0..*] to A_BPIntlAddressVersion as _BPIntlAddressVersion on _BPIntlAddressVersion.BusinessPartner = $projection.BusinessPartner
                                                                       and _BPIntlAddressVersion.AddressID = $projection.AddressID                                                                                                                   
                                                                             
{
  key I_BusPartAddress.BusinessPartner,
  key I_BusPartAddress.AddressID, 
      I_BusPartAddress.ValidityStartDate,
      I_BusPartAddress.ValidityEndDate ,
      I_BusPartAddress.AuthorizationGroup,
      @ObjectModel.readOnly: true
      I_BusPartAddress.AddressUUID,
      @Consumption.hidden: true
      I_BusPartAddress._BPProtectedAddress.BPAddressIsProtected,
      _Address.AdditionalStreetPrefixName, 
      _Address.AdditionalStreetSuffixName, 
      _Address.AddressTimeZone, 
      _Address.CareOfName, 
      _Address.CityCode, 
      _Address.CityName, 
      _Address.CompanyPostalCode, 
      _Address.Country, 
      _Address.County, 
      _Address.DeliveryServiceNumber, 
      _Address.DeliveryServiceTypeCode, 
      _Address.District, 
      @ObjectModel.readOnly: true
      _Address.FormOfAddress,
      @ObjectModel.readOnly: true   
      _Address.FullName, 
      _Address.HomeCityName, 
      _Address.HouseNumber, 
      _Address.HouseNumberSupplementText, 
      _Address.CorrespondenceLanguage as Language,
      _Address.POBox, 
      _Address.POBoxDeviatingCityName, 
      _Address.POBoxDeviatingCountry, 
      _Address.POBoxDeviatingRegion, 
      _Address.POBoxIsWithoutNumber, 
      _Address.POBoxLobbyName, 
      _Address.POBoxPostalCode, 
      @ObjectModel.readOnly: true
      _Address.Person, 
      _Address.PostalCode, 
      _Address.PrfrdCommMediumType, 
      _Address.Region, 
      _Address.StreetName, 
      _Address.StreetPrefixName, 
      _Address.StreetSuffixName, 
      _Address.TaxJurisdiction, 
      _Address.TransportZone,
      I_BusPartAddress.AddressIDByExternalSystem,
      _Address.CountyCode,
      _Address.TownshipCode,
      _Address.TownshipName,
      _PhoneNumber,
      _MobilePhoneNumber,
      _FaxNumber,
      _EmailAddress,
      _URLAddress,
      _BusinessPartner,
      _AddressUsage,
      _BPAddrDepdntIntlLocNumber,
      _BPIntlAddressVersion
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_BPPROTECTEDADDRESS",
"I_BUSPARTADDRESS"
],
"ASSOCIATED":
[
"A_ADDRESSEMAILADDRESS",
"A_ADDRESSFAXNUMBER",
"A_ADDRESSHOMEPAGEURL",
"A_ADDRESSPHONENUMBER",
"A_BPADDRDEPDNTINTLLOCNUMBER",
"A_BPINTLADDRESSVERSION",
"A_BUPAADDRESSUSAGE",
"A_BUSINESSPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/