A_BusSolnQtanItemDteParam

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Convergent Charging Date Parameters'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSQITDTEPAR',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view A_BusSolnQtanItemDteParam
  as select from I_BusSolnQtnItmCnvChrgParam as BusSolnQtnItmCnvChrgParam
  association [0..1] to I_ChargePlanParameter       as _Chargeplanparameter       on  $projection.ChargePlanAssignmentUUID = _Chargeplanparameter.ChargePlanAssignmentUUID
                                                                                  and $projection.ChargePlanParameterID    = _Chargeplanparameter.ChargePlanParameterID
  association [1..1] to A_BusinessSolutionQuotation as _BusinessSolutionQuotation on  $projection.BusinessSolutionQuotation = _BusinessSolutionQuotation.BusinessSolutionQuotation
{

  key BusinessSolutionQuotation,
  key ServiceDocumentItem as BusSolutionQuotationItem,
  key    _Chargeplanparameter.ChargePlanParameterUUID,
      @Consumption.hidden: true
      BusSolnQtnItmCnvChrgParam.ChargePlanAssignmentUUID,
      @Consumption.hidden: true
      BusSolnQtnItmCnvChrgParam.ChargePlanParameterID,
      BusSolnQtnItmCnvChrgParam.ChargePlanParameterUseValue,
      BusSolnQtnItmCnvChrgParam.ChargePlanParameterValue,
      BusSolnQtnItmCnvChrgParam.ChargePlanParameterType,
      
      case when BusSolnQtnItmCnvChrgParam.ChargePlanParameterUseValue = '2'
       then cast(BusSolnQtnItmCnvChrgParam.ChargePlanParameterValue as crms4_som_date_value ) 
       else cast('00000000' as crms4_som_date_value )
       end                 as ChargePlanParameterDateValue,

      case when BusSolnQtnItmCnvChrgParam.ChargePlanParameterUseValue = '3'
       then BusSolnQtnItmCnvChrgParam.ChargePlanParameterValue
      else ''
      end                  as Characteristic,


      @ObjectModel: { virtualElement: true,
                     virtualElementCalculatedBy: 'CL_CRMS4_SOM_CC_PAR_BRFPLUSTXT'
      }
      cast('' as fdt_text) as BRFFunction,
      
      @Consumption.hidden: true     
      _BusinessSolutionQuotation
} where _Chargeplanparameter.ChargePlanParameterType = '3' and _Chargeplanparameter.ChargePlanParameterUsage = '1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLNQTNITMCNVCHRGPARAM",
"I_CHARGEPLANPARAMETER"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONQUOTATION",
"I_CHARGEPLANPARAMETER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/