A_BusSolnOrderItemScheduleLine

DDL: A_BUSSOLNORDERITEMSCHEDULELINE Type: view COMPOSITE

Sales Item Schedule Line

A_BusSolnOrderItemScheduleLine is a Composite CDS View that provides data about "Sales Item Schedule Line" in SAP S/4HANA. It reads from 1 data source (I_SrvcDocItmScheduleLines) and exposes 5 fields with key fields BusinessSolutionOrder, BusinessSolutionOrderItem, ScheduleLine. It has 2 associations to related views.

1 data source(s) 5 fields

Data Sources (1)

SourceAliasJoin Type
I_SrvcDocItmScheduleLines I_SrvcDocItmScheduleLines from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_ServiceDocumentItemEnhcd _BusinessSolutionOrderItem $projection.BusinessSolutionOrder = _BusinessSolutionOrderItem.ServiceDocument and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItem.ServiceDocumentItem
[1..1] A_BusinessSolutionOrder _BusinessSolutionOrder $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

Annotations (15)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Sales Item Schedule Line view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AbapCatalog.sqlViewName ABSOSLINE view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ObjectModel.createEnabled false view
ObjectModel.updateEnabled false view
ObjectModel.deleteEnabled false view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder ServiceDocument
KEY BusinessSolutionOrderItem ServiceDocumentItem
KEY ScheduleLine ScheduleLine
OrderQuantityUnit _BusinessSolutionOrderItem ServiceDocItemQuantityUnit
_BusinessSolutionOrder _BusinessSolutionOrder 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Sales Item Schedule Line'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSOSLINE',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: false,
   updateEnabled: false,
   deleteEnabled: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view A_BusSolnOrderItemScheduleLine
  as select from I_SrvcDocItmScheduleLines
  association [1..1] to I_ServiceDocumentItemEnhcd as _BusinessSolutionOrderItem on  $projection.BusinessSolutionOrder     = _BusinessSolutionOrderItem.ServiceDocument
                                                                                 and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItem.ServiceDocumentItem
  association [1..1] to A_BusinessSolutionOrder    as _BusinessSolutionOrder     on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

{
      @ObjectModel.readOnly: true
  key ServiceDocument                                                     as BusinessSolutionOrder,
      @ObjectModel.readOnly: true
  key ServiceDocumentItem                                                 as BusinessSolutionOrderItem,
  key ScheduleLine,
  
      @Semantics.quantity.unitOfMeasure:'OrderQuantityUnit'  
      case SrvcDocItmSchdLnEvtType
         when 'ORDER' then ScheduleLineOrderQuantity end                  as RequestedQuantity,

      @Semantics.dateTime: true
      case SrvcDocItmSchdLnEvtType
         when 'ORDER' then cast( ScheduleLineDateTime as tzntstmps ) end  as RequestedDeliveryDateTime,

      @Semantics.quantity.unitOfMeasure:'OrderQuantityUnit'
      case SrvcDocItmSchdLnEvtType
      when 'CONFIRMED' then  ScheduleLineOrderQuantity end                as ConfdOrderQtyByMatlAvailCheck,

      @Semantics.dateTime: true
      case SrvcDocItmSchdLnEvtType
      when 'CONFIRMED' then cast( ScheduleLineDateTime as tzntstmps ) end as ConfirmedDeliveryDateTime,

      @Semantics.unitOfMeasure: true
      _BusinessSolutionOrderItem.ServiceDocItemQuantityUnit               as OrderQuantityUnit,

      _BusinessSolutionOrder
}
where
  ServiceObjectType = 'BUS2000172'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEMENHCD",
"I_SRVCDOCITMSCHEDULELINES"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONORDER",
"I_SERVICEDOCUMENTITEMENHCD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More