A_BillingDocumentRequestItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Billing Document Request Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASDBDREQITEM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: false,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
  }
} 
@Metadata: {
  ignorePropagatedAnnotations: true
}

define view A_BillingDocumentRequestItem as select from I_BillingDocumentRequestItem

  association [1..1] to A_BillingDocumentRequest     as _BillingDocumentRequest   on  $projection.BillingDocumentRequest     = _BillingDocumentRequest.BillingDocumentRequest 
  association [0..*] to A_BillingDocReqItemPartner   as _Partner                  on  $projection.BillingDocumentRequest     = _Partner.BillingDocumentRequest    
                                                                                  and $projection.BillingDocumentRequestItem = _Partner.BillingDocumentRequestItem 
  association [0..*] to A_BillingDocReqItemPrcgElmnt as _PricingElement           on  $projection.BillingDocumentRequest     = _PricingElement.BillingDocumentRequest     
                                                                                  and $projection.BillingDocumentRequestItem = _PricingElement.BillingDocumentRequestItem 

//Extensibility

  association [0..1] to E_BillingDocumentItem        as _Extension                on  $projection.BillingDocumentRequest     = _Extension.BillingDocument
                                                                                  and $projection.BillingDocumentRequestItem = _Extension.BillingDocumentItem
{

      //Key

  key BillingDocumentRequest,
  key BillingDocumentRequestItem,

      //Category

      //SalesDocumentItemCategory,

      
      //Admin

      CreationDate,
      CreationTime,
      ReferenceLogicalSystem,
      
      //Organization

      @ObjectModel.sapObjectNodeTypeReference: 'Division'          
      Division,
      
      //Product

      Material,
      ProductHierarchyNode,
      Plant,
      
      //Billing

      BillingDocumentRequestItemText,
      ServicesRenderedDate,
      @Semantics.quantity.unitOfMeasure: 'BillingQuantityUnit'
      BillingQuantity,
      @Semantics.unitOfMeasure: true
      BillingQuantityUnit,

      //Pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      NetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'                
      TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      GrossAmount,
      PricingDate,
      cast(abs( PriceDetnExchangeRate ) as kursk_abs) as AbsltPriceDetnExchangeRate,
      cast(case when PriceDetnExchangeRate < 0 then 'X' else ' ' end  as kursk_quotatn_is_indirect) as PriceDetnExchRateIsIndrctQtan,     
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TaxAmount,
      
      //Tax

      DepartureCountry,
      @ObjectModel.sapObjectNodeTypeReference: 'TaxJurisdiction'                      
      TaxJurisdiction,
      ProductTaxClassification1,
      
      //Accounting

      BusinessArea,
      ProfitCenter,
      cast( WBSElementInternalID as ps_psp_pnr preserving type ) as WBSElement,
      ControllingArea,
      ProfitabilitySegment_2 as ProfitabilitySegment,      
      OrderID,
      CostCenter,
      @ObjectModel.sapObjectNodeTypeReference: 'MaterialAccountAssignmentGroup'                
      MatlAccountAssignmentGroup,
      
      //Reference

      ReferenceDocument,
      ReferenceDocumentItem,
      //ReferenceDocSDDocCategory,

      HigherLevelItem,
      BillgDocRequestItemInPartSgmt,

      //For Access control

      @Consumption.hidden: true
      _BillingDocumentRequest.BillingDocumentRequestType,
      @Consumption.hidden: true
      _BillingDocumentRequest.SalesOrganization,

          
      //Make associations public

      _BillingDocumentRequest,
      _Partner,
      _PricingElement  
  
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_BILLINGDOCUMENTREQUEST",
"I_BILLINGDOCUMENTREQUESTITEM"
],
"ASSOCIATED":
[
"A_BILLINGDOCREQITEMPARTNER",
"A_BILLINGDOCREQITEMPRCGELMNT",
"A_BILLINGDOCUMENTREQUEST",
"E_BILLINGDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/