A_BillingDocumentRequest

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Billing Document Request Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASDBDREQ',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  representativeKey: 'BillingDocumentRequest',
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: true,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #XL
  }
} 
@Metadata: {
  ignorePropagatedAnnotations: true
}

define view A_BillingDocumentRequest as select from I_BillingDocumentRequest

  association [0..*] to A_BillingDocumentRequestItem  as _Item                        on  $projection.BillingDocumentRequest = _Item.BillingDocumentRequest
  association [0..*] to A_BillingDocReqPartner        as _Partner                     on  $projection.BillingDocumentRequest = _Partner.BillingDocumentRequest 
  association [0..*] to A_BillingDocReqPrcgElmnt      as _PricingElement              on  $projection.BillingDocumentRequest = _PricingElement.BillingDocumentRequest                                                                        

  //Extensibility

  association [0..1] to E_BillingDocument             as _Extension                   on  $projection.BillingDocumentRequest = _Extension.BillingDocument

{

      //key

  key BillingDocumentRequest,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocumentRequestType'                
      BillingDocumentRequestType,      
      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocumentType'                
      ProposedBillingDocumentType, 

      //admin

      CreationDate,
      CreationTime,
      LastChangeDate,
      LastChangeDateTime,
      LogicalSystem,

      //org

      SalesOrganization,
      DistributionChannel,
      @ObjectModel.sapObjectNodeTypeReference: 'Division'                
      Division,

      //billing

      BillingDocumentDate,

      //pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'                
      TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalTaxAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      (TotalTaxAmount + TotalNetAmount) as TotalGrossAmount,     
      TaxDepartureCountry,
      
      //payment

      PayerParty,
      ContractAccount,
      CustomerPaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'          
      PaymentMethod,
      SEPAMandate,

      //accounting

      CompanyCode,

      //reference

      ReferenceDocument,//BillingDocRequestReference,

      ReferenceDocumentLogicalSystem,//BillgDocReqRefLgclSyst,

      ReferenceDocSDDocCategory,//BillgDocReqRefSDDocCategory,


      //sales

      SoldToParty,
      PurchaseOrderByCustomer,
      PricingDocument,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingIssueType'          
      BillingIssueType,

      //shipping

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'          
      IncotermsVersion,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'          
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,

      //status

      @ObjectModel.sapObjectNodeTypeReference: 'OverallBillingDocRequestStatus'          
      OverallBillingDocReqStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocPrcgIncompltnSts'          
      OverallPricingIncompletionSts,

      //associations

      @ObjectModel.readOnly: true
      _Item,
      @ObjectModel.readOnly: true
      _Partner,
      @ObjectModel.readOnly: true
      _PricingElement
      
}
      
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENTREQUEST"
],
"ASSOCIATED":
[
"A_BILLINGDOCREQPARTNER",
"A_BILLINGDOCREQPRCGELMNT",
"A_BILLINGDOCUMENTREQUESTITEM",
"E_BILLINGDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/