A_BillingDocumentItemText

DDL: A_BILLINGDOCUMENTITEMTEXT SQL: ASDBILTEXTITEM Type: view COMPOSITE

Item Text

A_BillingDocumentItemText is a Composite CDS View that provides data about "Item Text" in SAP S/4HANA. It reads from 2 data sources (I_BillingDocument, P_BillingDocumentText) and exposes 10 fields with key fields BillingDocument, BillingDocumentItem, Language, LongTextID. It has 2 associations to related views.

2 data source(s) 10 fields

Data Sources (2)

SourceAliasJoin Type
I_BillingDocument BillingDocument inner
P_BillingDocumentText P_BillingDocumentText from

Associations (2)

CardinalityTargetAliasCondition
[1..1] A_BillingDocument _BillingDocument _BillingDocument.BillingDocument = $projection.BillingDocument
[1..1] A_BillingDocumentItem _BillingDocumentItem _BillingDocumentItem.BillingDocument = $projection.BillingDocument and _BillingDocumentItem.BillingDocumentItem = $projection.BillingDocumentItem

Annotations (15)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Item Text view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AbapCatalog.sqlViewName ASDBILTEXTITEM view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ObjectModel.createEnabled false view
ObjectModel.updateEnabled false view
ObjectModel.deleteEnabled false view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument
KEY BillingDocumentItem
KEY Language Language
KEY LongTextID LongTextID
LongText LongText
BillingDocumentType I_BillingDocument BillingDocumentType
SalesOrganization I_BillingDocument SalesOrganization
DistributionChannel I_BillingDocument DistributionChannel
_BillingDocument _BillingDocument
_BillingDocumentItem _BillingDocumentItem 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Text'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}

@AbapCatalog.sqlViewName: 'ASDBILTEXTITEM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: false,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BillingDocumentItemText
  as select from P_BillingDocumentText ( P_SAPClient : $session.client, P_td_object : 'VBBP' ) as BillingItemText
    inner join   I_BillingDocument                                      as BillingDocument on  BillingDocument.BillingDocument = BillingItemText.BillingDocument
                                                                                                                                                                                                       
  association [1..1] to A_BillingDocument as _BillingDocument on _BillingDocument.BillingDocument = $projection.BillingDocument
  association [1..1] to A_BillingDocumentItem as _BillingDocumentItem on  _BillingDocumentItem.BillingDocument     = $projection.BillingDocument
                                                                      and _BillingDocumentItem.BillingDocumentItem = $projection.BillingDocumentItem
{
 @ObjectModel.readOnly: true
  key cast(BillingItemText.BillingDocument as vbeln_vf) as BillingDocument,
      @ObjectModel.readOnly: true
  key cast(BillingItemText.BillingDocumentItem as posnr_vf) as BillingDocumentItem,

  key Language,
  key LongTextID,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_BIL_S4H_STXL_BILDOC'
      LongText,

      // For Access control

      @Consumption.hidden: true
      BillingDocument.BillingDocumentType,
      @Consumption.hidden: true
      BillingDocument.SalesOrganization,
      @Consumption.hidden: true
      BillingDocument.DistributionChannel,

      _BillingDocument, // Make association public

      _BillingDocumentItem
}

where BillingDocument.BillingDocumentIsTemporary = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT"
],
"ASSOCIATED":
[
"A_BILLINGDOCUMENT",
"A_BILLINGDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More