A_AppointmentActivity

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Appointment Activity'

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'AAPPTACT',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'AppointmentActivity',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   }
}


@Metadata.ignorePropagatedAnnotations: true

define view A_AppointmentActivity
     as select from I_CustMgmtActivityEnhcd as AppointmentActivity
 
association [0..*] to A_AppointmentActyPersonResp as _PersonResponsible on $projection.AppointmentActivity = _PersonResponsible.AppointmentActivity
association [0..*] to A_AppointmentActyAttendee   as _AppointmentActivityAttendee on $projection.AppointmentActivity = _AppointmentActivityAttendee.AppointmentActivity
association [0..*] to A_AppointmentActivityText   as _Text on $projection.AppointmentActivity = _Text.AppointmentActivity

  //Extensibility

association [0..1] to E_ActivityDocument       as _Extension            on  _Extension.BusinessObjectType  = 'BUS2000126'
                                                                        and $projection.AppointmentActivity  = _Extension.ActivityDocument

{
  key CustMgmtActivity            as AppointmentActivity,
      CustMgmtActivityType        as AppointmentActivityType,
      CustMgmtActivityUUID        as AppointmentActivityUUID,     
      CustMgmtActivityDescription as AppointmentActivityDescription,
      CustMgmtActivityCategory,
      CustMgmtActivityPriority,
      CustMgmtActivityIsPrivate,
      CustMgmtActyIsDspdInCalendar,
      CustMgmtActivityLocationText as ApptActivityLocationText,      
      Account,
      ContactPerson,      
      case CustMgmtActivityStatus
       when 'C' then 'X'
       else ''
       end                        as AppointmentActivityIsCompleted,
      CustMgmtActivityIsRejected  as AppointmentActivityIsRejected,
      CustMgmtActivityStartDateTime,
      CustMgmtActivityEndDateTime,
      ResponsibleSalesOrganization,
      ServiceOrganization,
      ResponsibleServiceOrganization,
      DistributionChannel,
      Division,
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      _PersonResponsible,
      _AppointmentActivityAttendee,
      _Text
}
where
  CustMgmtObjectType = 'BUS2000126' // Customer Management Activity

  and BusinessActivityClass = 'F' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTACTIVITYENHCD"
],
"ASSOCIATED":
[
"A_APPOINTMENTACTIVITYTEXT",
"A_APPOINTMENTACTYATTENDEE",
"A_APPOINTMENTACTYPERSONRESP",
"E_ACTIVITYDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/