I_CUSTMGMTACTIVITYENHCD

@EndUserText.label: 'Customer Management Activity'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'IACTIVITYENHCD',
  compiler.compareFilter: true,
  preserveKey: true
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel: {
   representativeKey: 'CustMgmtActivity',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XXL
   }
}
//@Analytics.dataCategory: #DIMENSION

@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true


define view I_CustMgmtActivityEnhcd 
  as select from I_CustMgmtActivity
  association [0..*] to I_SrvcDocAppointment           as _SrvcDocAppointment           on  $projection.CustMgmtActivityUUID = _SrvcDocAppointment.SrvcMgmtObjectUUID
  association [0..*] to I_ServiceDocumentDuration      as _ServiceDocumentDuration      on  $projection.CustMgmtObjectType   = _ServiceDocumentDuration.ServiceObjectType
                                                                                        and $projection.CustMgmtActivity     = _ServiceDocumentDuration.ServiceDocument
                                                                                        and _ServiceDocumentDuration.ServiceDocumentItem is initial
  association [0..*] to I_CustMgmtPartner              as _CustMgmtPartner              on  $projection.CustMgmtObjectType   = _CustMgmtPartner.CustMgmtObjectType
                                                                                        and $projection.CustMgmtActivity     = _CustMgmtPartner.CustMgmtDocument
                                                                                        and _CustMgmtPartner.CustMgmtDocumentItem is initial
  association [0..*] to I_SrvcMgmtObjectStatus         as _SrvcMgmtObjectStatus         on  $projection.CustMgmtActivityUUID = _SrvcMgmtObjectStatus.SrvcMgmtObjectUUID
  association [0..*] to I_ServiceDocumentLongText      as _ServiceDocumentLongText      on  $projection.CustMgmtObjectType   = _ServiceDocumentLongText.ServiceObjectType
                                                                                        and $projection.CustMgmtActivity     = _ServiceDocumentLongText.ServiceDocument
                                                                                        and _ServiceDocumentLongText.ServiceDocumentItem is initial 
                                                                                        and _ServiceDocumentLongText.TextObjectCategory = 'CRM_ORDERH'                                                          
 {
      @ObjectModel.foreignKey.association: '_CustMgmtObjectType'
  key CustMgmtObjectType,                                                
  key CustMgmtActivity,
      @ObjectModel.foreignKey.association: '_BusinessActivityCategory'                                               
      CustMgmtActivityCategory,
      @Semantics.text: true                                             
      CustMgmtActivityDescription,
      @ObjectModel.foreignKey.association: '_ServiceDocumentPriority'                                           
      CustMgmtActivityPriority ,
      CustMgmtActivityIsPrivate,
      BusinessActivityClass,
      CustMgmtActivityDirection,
      CustMgmtActivityLocationText,
      CustMgmtActyIsDspdInCalendar,
      CustMgmtTaskCompltnRateInPct,
      CustMgmtActivityUUID,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      CustMgmtActivityType,
      @ObjectModel.foreignKey.association: '_Account'     
      Account,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson,
      @ObjectModel.foreignKey.association: '_RespEmployeeBusinessPartnerId'
      RespEmployeeBusinessPartnerId,
      CustMgmtActivityStatus,                         
      CustMgmtActivityIsRejected,
      CustMgmtActivityStartDateTime,
      CustMgmtActivityEndDateTime,
  /*  orderplan_from          as  CustMgmtActyPlndStartDateTime,      
      orderplan_to            as  CustMgmtActyPlndEndDateTime,     */ 
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit'
      SalesOrganizationOrgUnitID,
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit'
      SalesOfficeOrgUnitID,
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit'
      SalesGroupOrgUnitID,
      @ObjectModel.foreignKey.association: '_ResponsibleSalesOrganization'
      ResponsibleSalesOrganization,
      @ObjectModel.foreignKey.association: '_ServiceOrganization'
      ServiceOrganization,
      @ObjectModel.foreignKey.association: '_ResponsibleServiceOrg'
      ResponsibleServiceOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      TextObjectKey,
      
      // Foreign key associations

      _CustMgmtObjectType,
      _BusinessActivityCategory,
      _ServiceDocumentType,
      _ServiceDocumentPriority,
      _DistributionChannel,
      _Division,
      _SalesOrganizationOrgUnit,
      _SalesOfficeOrgUnit,
      _SalesGroupOrgUnit,
      _ResponsibleSalesOrganization,
      _ServiceOrganization,
      _ResponsibleServiceOrg,
      _Account,
      _ContactPerson,
      _RespEmployeeBusinessPartnerId,
      
      // Associations to complex subobjects

      _SrvcDocAppointment,
      _ServiceDocumentDuration, 
      _CustMgmtPartner,
      _SrvcMgmtObjectStatus,
      _ServiceDocumentLongText         
          
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTACTIVITY"
],
"ASSOCIATED":
[
"I_BUSINESSACTIVITYCATEGORY",
"I_BUSINESSPARTNER",
"I_CUSTMGMTBUSOBJTYPE",
"I_CUSTMGMTPARTNER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SERVICEDOCUMENTDURATION",
"I_SERVICEDOCUMENTLONGTEXT",
"I_SERVICEDOCUMENTPRIORITY",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCDOCAPPOINTMENT",
"I_SRVCMGMTOBJECTSTATUS",
"I_SRVCMGMTORGANIZATIONUNIT"
],
"BASE":
[
"I_CUSTMGMTACTIVITY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/