R_PROJECTDEMANDSERVICE

CDS View

Project Demand for Service

R_PROJECTDEMANDSERVICE is a CDS View in S/4HANA. Project Demand for Service. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_ProjectDemandService view from BASIC Project Demand for Service
I_ProjectDemandServiceTP view_entity from TRANSACTIONAL Project Demand for Service - TP 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel: {
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
   semanticKey:       ['Material' ],
   representativeKey: 'ProjectDemandServiceUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Project Demand for Service'

define view entity R_ProjectDemandService
  as select from servicedemand

  association [0..1] to R_ProjectDemandServiceSupply as _ServiceSupply        on  _ServiceSupply.ProjectDemandUUID = $projection.ProjectDemandUUID
  association [1..1] to R_ProjectDemand              as _RootTP               on  $projection.ProjectDemandUUID = _RootTP.ProjectDemandUUID

  association [0..1] to I_ProductStdVH               as _Material             on  $projection.Material = _Material.Product
  association [1..1] to I_ProductDescription         as _MaterialText         on  $projection.Material   = _MaterialText.Product
                                                                              and _MaterialText.Language = $session.system_language
  association [0..1] to I_ProductGroup_2             as _MaterialGroup        on  $projection.MaterialGroup = _MaterialGroup.ProductGroup
  association [1..1] to I_ProductGroupText_2         as _MaterialGroupText    on  $projection.MaterialGroup   = _MaterialGroupText.ProductGroup
                                                                              and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_Supplier                   as _Supplier             on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_PurchasingInfoRecord       as _PurchasingInfoRecord on  $projection.PurchasingInfoRecord = _PurchasingInfoRecord.PurchasingInfoRecord

{

  key projectdemandserviceuuid    as ProjectDemandServiceUUID,

      projectdemanduuid           as ProjectDemandUUID,

      @Consumption.valueHelp: '_Material'
      material                    as Material,

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      materialgroup               as MaterialGroup,

      @ObjectModel.foreignKey.association: '_Supplier'
      supplier                    as Supplier,

      @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      purchasinginforecord        as PurchasingInfoRecord,

      purchasecontract            as PurchaseContract,

      purchasecontractitem        as PurchaseContractItem,

      materialplanneddeliverydurn as MaterialPlannedDeliveryDurn,

      @Semantics.user.createdBy: true
      createdbyuser               as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      creationdatetime            as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedbyuser           as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime          as LastChangeDateTime,

      _RootTP,
      _ServiceSupply,

      _Material,
      _MaterialText,
      _MaterialGroup,
      _MaterialGroupText,
      _Supplier,
      _PurchasingInfoRecord

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SERVICEDEMAND"
],
"ASSOCIATED":
[
"I_PRODUCTDESCRIPTION",
"I_PRODUCTGROUPTEXT_2",
"I_PRODUCTGROUP_2",
"I_PRODUCTSTDVH",
"I_PURCHASINGINFORECORD",
"I_SUPPLIER",
"R_PROJECTDEMAND",
"R_PROJECTDEMANDSERVICESUPPLY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More