I_ProjectDemandService

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #PUBLIC_LOCAL_API

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@AbapCatalog: {
    sqlViewName: 'IPROJDMNDSERVICE',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ],
   semanticKey:       ['Material' ],
   representativeKey: 'ProjectDemandServiceUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Project Demand for Service'
define view I_ProjectDemandService
  as select from R_ProjectDemandService

  association [0..1] to I_ProjectDemandServiceSupply as _ServiceSupply        on  _ServiceSupply.ProjectDemandUUID = $projection.ProjectDemandUUID
  association [1..1] to I_ProjectDemand              as _RootTP               on  $projection.ProjectDemandUUID = _RootTP.ProjectDemandUUID

  association [0..1] to I_Product                    as _Material             on  $projection.Material = _Material.Product
  association [0..1] to I_ProductGroup_2             as _MaterialGroup        on  $projection.MaterialGroup = _MaterialGroup.ProductGroup
  association [0..1] to I_Supplier                   as _Supplier             on  $projection.Supplier = _Supplier.Supplier

{

  key ProjectDemandServiceUUID    as ProjectDemandServiceUUID,

      ProjectDemandUUID           as ProjectDemandUUID,
      
      @Consumption.valueHelp: '_Material'
      Material                    as Material,

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      MaterialGroup               as MaterialGroup,

      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier                    as Supplier,

      PurchasingInfoRecord        as PurchasingInfoRecord,

      PurchaseContract            as PurchaseContract,

      PurchaseContractItem        as PurchaseContractItem,

      MaterialPlannedDeliveryDurn as MaterialPlannedDeliveryDurn,

      @Semantics.user.createdBy: true
      CreatedByUser               as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime            as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser           as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime          as LastChangeDateTime,

      _RootTP,
      _ServiceSupply,

      _Material,
      _MaterialGroup,
      _Supplier

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PROJECTDEMANDSERVICE"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_PRODUCTGROUP_2",
"I_PROJECTDEMAND",
"I_PROJECTDEMANDSERVICESUPPLY",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/