I_TENDERING

CDS View

Tendering

I_TENDERING is a CDS View in S/4HANA. Tendering. It contains 2 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 2 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_CollabnApplFrtOrdQtanStop view inner CONSUMPTION Transportation Order Stop
C_CollabnApplFrtOrdRFQStop view inner CONSUMPTION Transportation Order Stop
I_TenderingEnrcd view from COMPOSITE Tendering Enriched
P_CollabnApplFreightOrdForConf view inner CONSUMPTION Private view for confirm freight order
P_CollabnApplFreightQuotation view inner CONSUMPTION

Fields (2)

KeyField CDS FieldsUsed in Views
RefTransportationOrderUUID RefTransportationOrderUUID 3
TenderingManager TenderingManager,TranspOrdResponsiblePerson 4 
@EndUserText:   {label:              'Tendering'}
@ClientHandling.algorithm:           #SESSION_VARIABLE
@AbapCatalog:   {compiler:           {compareFilter: true},
                 sqlViewName:        'ITENDERING',
                 preserveKey:        true}
@ObjectModel:   {representativeKey:  'TenderingUUID',
                 usageType:          {serviceQuality: #A,
                                      sizeCategory:   #XL,
                                      dataClass:      #TRANSACTIONAL}}
@VDM:           {viewType:           #BASIC,
                lifecycle.contract.type: #NONE}

@AccessControl: {authorizationCheck: #CHECK,
                 privilegedAssociations:  [ '_TenderingCreatedByUser', '_TenderingChangedByUser' ]
                 }

define view I_Tendering
  as select from /scmtms/d_torten

  association [0..*] to I_TenderingStep            as _TenderingStep              on $projection.TenderingUUID = _TenderingStep.TenderingUUID
  association [1..1] to I_TransportationOrder      as _TransportationOrder        on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  association [1..1] to I_TransportationOrder      as _RefTransportationOrder     on $projection.RefTransportationOrderUUID = _RefTransportationOrder.TransportationOrderUUID
  association [0..1] to I_TenderingProcessResult   as _TenderingProcessResult     on $projection.TenderingProcessResult = _TenderingProcessResult.TenderingProcessResult
  association [0..1] to I_TenderingLifeCycleStatus as _TenderingLifeCycleStatus   on $projection.TenderingLifeCycleStatus = _TenderingLifeCycleStatus.TenderingLifeCycleStatus
  association [0..1] to I_User                     as _TenderingCreatedByUser     on $projection.TenderingCreatedByUser = _TenderingCreatedByUser.UserID
  association [0..1] to I_User                     as _TenderingChangedByUser     on $projection.TenderingChangedByUser = _TenderingChangedByUser.UserID

{
  key cast(db_key as /scmtms/vdm_tend_uuid preserving type)                                       as TenderingUUID,
      @ObjectModel.foreignKey.association: '_TransportationOrder'
      cast(parent_key  as /scmtms/vdm_tor_db_key preserving type)                                 as TransportationOrderUUID,
      @ObjectModel.foreignKey.association: '_RefTransportationOrder'
      cast(rel_torq_uuid as /scmtms/vdm_tor_ref_db_key preserving type )                          as RefTransportationOrderUUID,
      cast(tend_seq_nr as /scmtms/vdm_tend_sqnc_number preserving type )                          as TenderingSequenceNumber,
      @ObjectModel.foreignKey.association: '_TenderingProcessResult'
      tend_process_res                                                                            as TenderingProcessResult,
      @ObjectModel.foreignKey.association: '_TenderingLifeCycleStatus'
      cast(lifecycle as /scmtms/tend_lifecycle_status preserving type )                           as TenderingLifeCycleStatus,
      @Semantics.user.createdBy: true
      cast(created_by as /scmtms/vdm_tend_crted_by_user preserving type )                         as TenderingCreatedByUser,
      @Semantics.user.lastChangedBy: true
      cast(changed_by as /scmtms/vdm_tend_chgd_by_user preserving type )                          as TenderingChangedByUser,
      cast(start_datetime as /scmtms/vdm_tend_start_dtetime preserving type)                      as TenderingStartDateTime,
      cast(end_datetime as /scmtms/vdm_tend_end_datetime preserving type)                         as TenderingEndDateTime,
      tend_manager                                                                                as TenderingManager,
      @Semantics.amount.currencyCode: 'TenderingLowestProposedAmtCrcy'
      cast(cast( lowest_price_prop as abap.dec(31,6)) * 10000 as /scmtms/vdm_tend_lowest_amount ) as TenderingLowestProposedAmount,
      @Semantics.currencyCode: true
      cast(lowest_price_prop_curr as /scmtms/vdm_tend_lowestamtcrcy preserving type )             as TenderingLowestProposedAmtCrcy,

      /* Associations */
      _TransportationOrder,
      _RefTransportationOrder,
      _TenderingStep,
      _TenderingProcessResult,
      _TenderingLifeCycleStatus,
      _TenderingCreatedByUser,
      _TenderingChangedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SCMTMS/D_TORTEN"
],
"ASSOCIATED":
[
"I_TENDERINGLIFECYCLESTATUS",
"I_TENDERINGPROCESSRESULT",
"I_TENDERINGSTEP",
"I_TRANSPORTATIONORDER",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More