P_CollabnApplFreightQuotation

@AbapCatalog.sqlViewName: 'PCOLLABFRTQUOT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
 
define view P_CollabnApplFreightQuotation
  as select from I_TenderingResponse            as TenderingResponse
    inner join   I_TenderingRequest             as TenderingRequest       on TenderingResponse.TenderingRequestUUID = TenderingRequest.TenderingRequestUUID
    inner join   P_CollabnApplCarrierUser       as CollabnApplCarrierUser on CollabnApplCarrierUser.BusinessPartnerCompany = TenderingRequest.TenderingRequestedCarrier
    inner join   I_TenderingStep                as TenderingStep          on TenderingRequest.TenderingStepUUID = TenderingStep.TenderingStepUUID
    inner join   I_Tendering                    as Tendering              on TenderingStep.TenderingUUID = Tendering.TenderingUUID

  association [1..1] to I_TransportationOrder         as _RefTransportationOrder      on $projection.RefTransportationOrderUUID = _RefTransportationOrder.TransportationOrderUUID
  association [0..1] to I_TenderingRejectionReason    as _TenderingRejectionReason    on $projection.TenderingRejectionReason = _TenderingRejectionReason.TenderingRejectionReason
  association [0..1] to I_TenderingResponseCode       as _TenderingResponseCode       on $projection.TenderingResponseCode = _TenderingResponseCode.TenderingResponseCode
  association [0..1] to I_TenderingAwardStatus        as _TenderingAwardStatus        on $projection.TenderingAwardStatus = _TenderingAwardStatus.TenderingAwardStatus
  association [1..1] to I_TenderingVisibilitySettings as _TenderingVisibilitySettings on $projection.TenderingVisibilitySettings = _TenderingVisibilitySettings.TenderingVisibilitySettings
  association [0..1] to C_CollabnApplTenderingManager as _TenderingManager            on $projection.TenderingManager = _TenderingManager.TenderingManager
{
  key TenderingResponse.TenderingResponseUUID                                                            as FreightQuotationUUID,
      TenderingResponse.TenderingRequestUUID                                                             as FreightRequestForQuotationUUID,
      TenderingResponse.TransportationOrderUUID                                                          as TransportationOrderUUID,
      TenderingStep.TenderingUUID,
      cast ( TenderingRequest.TenderingRequest as /scmtms/vdm_freight_rfq)                               as FreightRequestForQuotation,

      cast ( concat( ltrim( TenderingRequest.TenderingRequest, '0' ) ,
             concat('-', TenderingResponse.TenderingResponseSqncNumber) ) as /scmtms/vdm_frt_quotation ) as FreightQuotation,

      Tendering.RefTransportationOrderUUID                                                               as RefTransportationOrderUUID,
      Tendering.TenderingManager,
      TenderingRequest.TenderingRequestedCarrier                                                         as TenderingRequestedCarrier,

      TenderingResponse.TenderingResponseSqncNumber                                                      as TenderingResponseSqncNumber,
      TenderingResponse.TenderingAwardStatus                                                             as TenderingAwardStatus,

      TenderingResponse.TenderingResponseCode                                                            as TenderingResponseCode,
      TenderingResponse.TenderingRejectionReason                                                         as TenderingRejectionReason,

      TenderingResponse.TenderingSubmissionDateTime                                                      as TenderingSubmissionDateTime,
      TenderingResponse.TndrgRspSubmdAmtCrcy                                                             as TndrgRspSubmdAmtCrcy,
      TenderingResponse.TndrgRspSubmdAmt                                                                 as TndrgRspSubmdAmt,
      TenderingRequest.TenderingVisibilitySettings                                                       as TenderingVisibilitySettings,

      /* Associations */
      _RefTransportationOrder,
      _TenderingManager,
      _TenderingRejectionReason,
      _TenderingResponseCode,
      _TenderingAwardStatus,
      _TenderingVisibilitySettings

}
where
  (
       TenderingRequest.TndrgReqLifeCycleStatus             = '02'
    or TenderingRequest.TndrgReqLifeCycleStatus             = '03'
  )
  and(
       TenderingStep.TenderingProcessMode = 'RM'
    or TenderingStep.TenderingProcessMode = 'RA'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TENDERING",
"I_TENDERINGREQUEST",
"I_TENDERINGRESPONSE",
"I_TENDERINGSTEP",
"P_COLLABNAPPLCARRIERUSER"
],
"ASSOCIATED":
[
"C_COLLABNAPPLTENDERINGMANAGER",
"I_TENDERINGAWARDSTATUS",
"I_TENDERINGREJECTIONREASON",
"I_TENDERINGRESPONSECODE",
"I_TENDERINGVISIBILITYSETTINGS",
"I_TRANSPORTATIONORDER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/