I_TAXCODE

@AbapCatalog.sqlViewName: 'IFITAXCODE'
@EndUserText.label: 'Tax Code'

@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.representativeKey: 'TaxCode'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@Search.searchable: true

define view I_TaxCode
  as select from t007a

  association [0..*] to I_TaxCodeText             as _Text                    on  $projection.TaxCalculationProcedure = _Text.TaxCalculationProcedure
                                                                              and $projection.TaxCode                 = _Text.TaxCode

  association [0..1] to I_TaxType                 as _TaxType                 on  $projection.TaxType = _TaxType.TaxType

  association [0..1] to I_TaxCalculationProcedure as _TaxCalculationProcedure on  $projection.TaxCalculationProcedure = _TaxCalculationProcedure.TaxCalculationProcedure

{
      @ObjectModel.foreignKey.association: '_TaxCalculationProcedure'
  key kalsm                                                 as TaxCalculationProcedure,
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
  key cast(mwskz as fis_mwskz preserving type)              as TaxCode,
      @ObjectModel.foreignKey.association: '_TaxType'
      mwart                                                 as TaxType,
      cast (zmwsk as farp_dzmwsk preserving type)           as TargetTaxCode,
      egrkz                                                 as EUTaxClassification,
      xslta                                                 as IsSalesTaxes,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'UnitedStatesTaxCategory'  
      @Consumption.filter.hidden: true          
      cast ( txind as smwsk )                               as TaxCategory,
      cast ( txind as txind_007a)                           as UnitedStatesTaxCategory,
      lstml                                                 as TaxReturnCountry,
      cast( tolerance as fot_tax_tolerance preserving type) as TaxTolerancePercent,
      zmwsk_esa                                             as EUAcqnInputTaxCode,
      zmwsk_ese                                             as EUAcqnOutputTaxCode,
      mossc                                                 as MiniOneStopShopTxRptgCntry,

      _TaxCalculationProcedure,
      _TaxType,
      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T007A"
],
"ASSOCIATED":
[
"I_TAXCALCULATIONPROCEDURE",
"I_TAXCODETEXT",
"I_TAXTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/