P_MX_DueDeferredTaxItem

@AbapCatalog: {
  compiler.compareFilter: true,
  preserveKey: true,
  sqlViewName: 'PMXDUEDEFTXITM'
}
@AccessControl:{
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #P,
  sizeCategory: #XL
}
@VDM: {
  private: true,
  viewType: #COMPOSITE
}
define view P_MX_DueDeferredTaxItem

  as select from P_StRpTaxItem                                               as StRpTaxItem

    inner join   P_MX_DefTaxDocSupplierDetails                               as DefTaxTransfer on  DefTaxTransfer.CompanyCode        = StRpTaxItem.CompanyCode
                                                                                               and DefTaxTransfer.AccountingDocument = StRpTaxItem.AccountingDocument
                                                                                               and DefTaxTransfer.FiscalYear         = StRpTaxItem.FiscalYear

    inner join   I_TaxCode                                                   as TaxCode        on  TaxCode.TaxCode                 = StRpTaxItem.TaxCode
                                                                                               and TaxCode.TaxCalculationProcedure = StRpTaxItem.TaxCalculationProcedure

    inner join   I_StRpTaxItemBoxConfiguration( P_TaxBoxConfiguration: '1' ) as StRpTaxItemBox on  StRpTaxItemBox.Country                      =  'MX'
                                                                                               and StRpTaxItemBox.TaxBoxStrucValidityStartDate <= StRpTaxItem.ReportingDate
                                                                                               and StRpTaxItemBox.TaxBoxStrucValidityEndDate   >= StRpTaxItem.ReportingDate
                                                                                               and StRpTaxItemBox.TaxCode                      =  TaxCode.TaxCode
                                                                                               and StRpTaxItemBox.TransactionTypeDetermination =  StRpTaxItem.TransactionTypeDetermination
{
  key StRpTaxItem.CompanyCode                     as CompanyCode,
  key StRpTaxItem.AccountingDocument              as AccountingDocument,
  key cast( StRpTaxItem.FiscalYear as fis_gjahr_no_conv preserving type ) as FiscalYear,
  key StRpTaxItem.TaxItem                         as TaxItem,
  key StRpTaxItemBox.TaxBoxStrucValidityEndDate   as TaxBoxStrucValidityEndDate,
      --- Based on T007K/L
  key cast( case
              when StRpTaxItemBox.TaxItemGroupingVersion is not null and StRpTaxItemBox.TaxItemGroupingVersion <> ''
              then StRpTaxItemBox.TaxItemGroupingVersion
              else left( StRpTaxItemBox.TaxBoxStructureType, 4 )
            end as verstax preserving type )      as TaxItemGroupingVersion,

      StRpTaxItem.ReportingDate                   as ReportingDate,
      StRpTaxItem.PostingDate                     as PostingDate,
      StRpTaxItem.DocumentDate                    as DocumentDate,
      StRpTaxItem.TaxReportingDate                as TaxReportingDate,
      StRpTaxItem.TaxReportingDocumentDate        as TaxReportingDocumentDate,
      StRpTaxItem.DocumentReferenceID             as DocumentReferenceID,
      StRpTaxItem.AccountingDocumentType          as AccountingDocumentType,
      StRpTaxItem.TransactionTypeDetermination    as TransactionTypeDetermination,
      StRpTaxItem.GLAccount                       as GLAccount,
      StRpTaxItem.BusinessPlace                   as BusinessPlace,
      StRpTaxItem.TaxJurisdiction                 as TaxJurisdiction,
      StRpTaxItem.LowestLevelTaxJurisdiction      as LowestLevelTaxJurisdiction,
      StRpTaxItem.ReportingCountry                as ReportingCountry,
      StRpTaxItem.SenderCompanyCode               as SenderCompanyCode,
      StRpTaxItem.SenderAccountingDocument        as SenderAccountingDocument,
      cast( StRpTaxItem.SenderFiscalYear as fis_gjahr_no_conv preserving type ) as SenderFiscalYear,
      StRpTaxItem.TaxCode                         as TaxCode,
      StRpTaxItemBox.TaxDeclnAmountType           as TaxDeclnAmountType,
      StRpTaxItemBox.TaxBoxStrucValidityStartDate as TaxBoxStrucValidityStartDate,

      --- Based on FOT*
      StRpTaxItemBox.TaxBoxStructureType          as TaxBoxStructureType,
      DefTaxTransfer.BusinessType                 as BusinessType
}
where
  StRpTaxItem.DocumentReferenceID is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXITEMBOXCONFIGURATION",
"I_TAXCODE",
"P_MX_DEFTAXDOCSUPPLIERDETAILS",
"P_STRPTAXITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/