I_RECONDITION

@AbapCatalog.sqlViewName: 'IRECONDITION'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Conditions'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@ObjectModel.representativeKey: 'REConditionUUID'

@VDM.viewType: #BASIC
//@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_RECondition
  as select from vicdcond

  association [0..1] to I_Currency                   as _Currency                      on  $projection.REConditionCurrency = _Currency.Currency
  association [0..1] to I_User                       as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _ChangedByUser                 on  $projection.LastChangedByUser = _ChangedByUser.UserID
  association [1..1] to I_REKeyAssgmt                as _REKeyAssgmt                   on  $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber

  // Condition real estate objects

  association [0..1] to I_REConditionType            as _REConditionType               on  $projection.REConditionType = _REConditionType.REConditionType
  association [0..1] to I_RECndnCalculationRuleExt   as _RECndnCalculationRuleExt      on  $projection.RECalculationRule = _RECndnCalculationRuleExt.RECalculationRule
  association [0..1] to I_REObjectTypeDistribution   as _REObjectTypeDistribution      on  $projection.REObjectTypeDistribution = _REObjectTypeDistribution.REObjectTypeDistribution
  association [0..1] to I_REObjectTypePosting        as _REObjectTypePosting           on  $projection.REObjectTypePosting = _REObjectTypePosting.REObjectTypePosting
  association [0..1] to I_RECndnDistributionRuleExt  as _RECndnDistributionRuleExt     on  $projection.REDistributionRule = _RECndnDistributionRuleExt.REDistributionRule
  association [0..1] to I_REConditionPurposeExt      as _REConditionPurposeExt         on  $projection.REExtConditionPurpose = _REConditionPurposeExt.REExtConditionPurpose
  association [0..1] to I_REConditionChangeReason    as _REConditionChangeReason       on  $projection.REReasonForChange = _REConditionChangeReason.REReasonForChange
                                                                                       and $projection.REConditionType   = _REConditionChangeReason.REConditionType
  // Calc real estate objects

  association [1..1] to I_REObjectType               as _REConditionObjTypeCalculation on  $projection.REConditionObjTypeCalculation = _REConditionObjTypeCalculation.RealEstateObjectType

  association [0..*] to I_REObjectGroup              as _REObjectGroupCalculation      on  $projection.REStatusObjectCalculation = _REObjectGroupCalculation.REStatusObject
  association [0..*] to I_REContractSubject          as _REContractSubjectCalculation  on  $projection.REStatusObjectCalculation = _REContractSubjectCalculation.REStatusObject
  association [0..1] to I_REObjectTypeDetails        as _REObjectCalculation           on  $projection.REStatusObjectCalculation = _REObjectCalculation.REStatusObject
  // Calc FI/CO objects

  association [0..1] to I_CostCenter                 as _CostCenterCalculation         on  $projection.REStatusObjectCalculation = _CostCenterCalculation.ObjectInternalID
  association [0..1] to I_WBSElementBasicData        as _WBSElementCalculation         on  $projection.REStatusObjectCalculation = _WBSElementCalculation.WBSElementObject
  association [0..1] to I_InternalOrder              as _InternalOrderCalculation      on  $projection.REStatusObjectCalculation = _InternalOrderCalculation.ControllingObject
  //Calc technical objects

  association [0..*] to I_TechnicalObject            as _TechnicalObjectCalculation    on  $projection.REStatusObjectCalculation = _TechnicalObjectCalculation.MaintObjectInternalID

  // Dist real estate objects

  association [1..1] to I_REObjectType               as _REConditionObjTypeDistr       on  $projection.REConditionObjTypeDistribution = _REConditionObjTypeDistr.RealEstateObjectType
  association [0..*] to I_REObjectGroup              as _REObjectGroupDistribution     on  $projection.REStatusObjectDistribution = _REObjectGroupDistribution.REStatusObject
  association [0..*] to I_REContractSubject          as _REContractSubjectDistribution on  $projection.REStatusObjectDistribution = _REContractSubjectDistribution.REStatusObject
  association [0..1] to I_REObjectTypeDetails        as _REObjectDistribution          on  $projection.REStatusObjectDistribution = _REObjectDistribution.REStatusObject
  // Dist FI/CO objects

  association [0..1] to I_CostCenter                 as _CostCenterDistribution        on  $projection.REStatusObjectDistribution = _CostCenterDistribution.ObjectInternalID
  association [0..1] to I_WBSElementBasicData        as _WBSElementDistribution        on  $projection.REStatusObjectDistribution = _WBSElementDistribution.WBSElementObject
  association [0..1] to I_InternalOrder              as _InternalOrderDistribution     on  $projection.REStatusObjectDistribution = _InternalOrderDistribution.ControllingObject

  //Calc/Dist Values

  association [0..*] to I_REConditionCalculation     as _REConditionCalculation        on  $projection.REConditionUUID = _REConditionCalculation.REConditionUUID
  association [0..*] to I_REConditionDistribution    as _REConditionDistribution       on  $projection.REConditionUUID = _REConditionDistribution.REConditionUUID

  // Terms

  association [1..*] to I_REOrganizationalAssgmtTerm as _REOrganizationalAssgmtTerm    on  $projection.InternalRealEstateNumber = _REOrganizationalAssgmtTerm.InternalRealEstateNumber
                                                                                       and $projection.REOrglAssignmentTerm     = _REOrganizationalAssgmtTerm.RETermNumber
  association [1..*] to I_REPostingTerm              as _REPostingTerm                 on  $projection.InternalRealEstateNumber = _REPostingTerm.InternalRealEstateNumber
                                                                                       and $projection.REPostingTerm            = _REPostingTerm.RETermNumber
  association [1..*] to I_RERhythmTerm               as _RERhythmTerm                  on  $projection.InternalRealEstateNumber = _RERhythmTerm.InternalRealEstateNumber
                                                                                       and $projection.RERhythmTerm             = _RERhythmTerm.RETermNumber
  association [1..*] to I_REAdjustmentTerm           as _REAdjustmentTerm              on  $projection.InternalRealEstateNumber = _REAdjustmentTerm.InternalRealEstateNumber
                                                                                       and $projection.REAdjustmentNumber       = _REAdjustmentTerm.RETermNumber
  // Text

  association [0..*] to I_REConditionTypeText          as _REConditionTypeText           on $projection.REConditionType           = _REConditionTypeText.REConditionType
  association [0..*] to I_RECndnPurposeExtText         as _RECndnPurposeExtText          on $projection.REExtConditionPurpose     = _RECndnPurposeExtText.REExtConditionPurpose
  association [0..*] to I_RECndnCalculationRuleExtText as _RECndnCalculationRuleExtText  on $projection.RECalculationRule         = _RECndnCalculationRuleExtText.RECalculationRule
  association [0..*] to I_RECndnDistrRuleExtText       as _RECndnDistrRuleExtText        on $projection.REDistributionRule        = _RECndnDistrRuleExtText.REDistributionRule
  association [0..*] to I_RECndnChangeReasonText       as _RECndnChangeReasonText        on $projection.REReasonForChange         = _RECndnChangeReasonText.REReasonForChange
                                                                                         and $projection.REConditionType          = _RECndnChangeReasonText.REConditionType
  association [0..*] to I_CurrencyText                 as _CurrencyText                  on $projection.REConditionCurrency       = _CurrencyText.Currency
{
  key   condguid                                                       as REConditionUUID,
        intreno                                                        as InternalRealEstateNumber,
        @ObjectModel.foreignKey.association: '_REConditionType'
        condtype                                                       as REConditionType,
        cast(objnr as recdvdmobjnr)                                    as REStatusObjectCalculation,
        @Semantics.businessDate.from: true
        cast (condvalidfrom as rebdvdmvalidfrom )                      as ValidityStartDate,
        cast(objnrdist as recdvdmobjnrdist)                            as REStatusObjectDistribution,
        @ObjectModel.foreignKey.association: '_REObjectTypeDistribution'
        cast(objtypedistdist as recdvdmobjtypedist)                    as REObjectTypeDistribution,
        @ObjectModel.foreignKey.association: '_REObjectTypePosting'
        cast(objtypedistpost as recdvdmtermnopy)                       as REObjectTypePosting,

        @Semantics.businessDate.to: true
        cast ( condvalidto as rebdvdmvalidto )                         as ValidityEndDate,

        @Semantics.user.createdBy: true
        @ObjectModel.foreignKey.association: '_CreatedByUser'
        rerf                                                           as CreatedByUser,
        derf                                                           as CreationDate,
        terf                                                           as CreationTime,
        reher                                                          as RESourceOfCreation,
        @ObjectModel.foreignKey.association: '_ChangedByUser'
        rbear                                                          as LastChangedByUser,
        dbear                                                          as LastChangeDate,
        tbear                                                          as LastChangeTime,
        rbher                                                          as RESourceOfChange,

        uniquecond                                                     as REIsOneTimeCondition,
        cast(infocond as recdvdminfocond)                              as REConditionIsStatistical,

        termnopy                                                       as REPostingTerm,
        cast(termnorh as recdvdmtermnrhy)                              as RERhythmTerm,
        termnoaj                                                       as REAdjustmentNumber,
        cast(termnooa as recdvdmtermnooa)                              as REOrglAssignmentTerm,
        termnosr                                                       as RESalesTerm,
        termnomr                                                       as REPeakSalesTerm,
        termnopyscs                                                    as RESrvcChrgSettlementPostingTrm,
        termnowt                                                       as REWithholdingTaxTerm,

        @ObjectModel.foreignKey.association: '_RECndnCalculationRuleExt'
        calcrule                                                       as RECalculationRule,

        unitprice                                                      as REUnitPrice,
        @Semantics.currencyCode: true
        cast(condcurr as recdvdmcondcurr preserving type )             as REConditionCurrency,

        calcrulepara1                                                  as RECalculationRuleParam1,
        calcrulepara2                                                  as RECalculationRuleParam2,
        @ObjectModel.foreignKey.association: '_RECndnDistributionRuleExt'
        cast(distrule as recdvdmdistrule)                              as REDistributionRule,
        distrulepara1                                                  as REDistributionRuleParam1,
        distrulepara2                                                  as REDistributionRuleParam2,
        @ObjectModel.foreignKey.association: '_REConditionPurposeExt'
        cast(condpurposeext as recdvdmcondpurposeext)                  as REExtConditionPurpose,
        @ObjectModel.foreignKey.association: '_REConditionChangeReason'
        chgreason                                                      as REReasonForChange,
        cast( objnrcalcpara as  recdvdmobjnrparacalc preserving type ) as REStsObjectParamCalculation,
        cast( objnrdistpara as recdvdmobjnrparadist preserving type )  as REStsObjectParamDistribution,

        //      additional search/analytics fields right now not exposed to API

        duedatecorr                                                    as REDueDateTotNumberOfCrrtnDays,
        duedatecorrday                                                 as REDueDateNumberOfCrrtnDays,
        duedatecorrmonth                                               as REDueDateNumberOfCrrtnMonths,
        cfpostingfrom                                                  as RECashFlowPostingFromDate,
        exduedate                                                      as REConditionExceptionalDueDate,
        duedateup                                                      as REConditionFollowUpDueDate,
        invalidcalc                                                    as REConditionCalcIsInvalid,
        invaliddist                                                    as REDistributionIsInvalid,
        termnopyscsact                                                 as REServiceChrgSettlementIsActv,
        conddelete                                                     as REConditionIsToBeDeleted,

        cast( left(objnr,2) as rebdbusobjtypecn preserving type )      as REConditionObjTypeCalculation,
        cast( left(objnrdist,2) as rebdbusobjtypecn preserving type )  as REConditionObjTypeDistribution,

        _Currency,
        _CreatedByUser,
        _ChangedByUser,
        _REKeyAssgmt,

        _REConditionType,
        _RECndnCalculationRuleExt,
        _REObjectTypeDistribution,
        _REObjectTypePosting,
        _RECndnDistributionRuleExt,
        _REConditionPurposeExt,
        _REConditionChangeReason,

        _REConditionObjTypeCalculation,
        _REObjectGroupCalculation,
        _REContractSubjectCalculation,
        _REObjectCalculation,
        _CostCenterCalculation,
        _WBSElementCalculation,
        _InternalOrderCalculation,
        _TechnicalObjectCalculation,
        _REConditionCalculation,

        _REConditionObjTypeDistr,
        _REObjectGroupDistribution,
        _REContractSubjectDistribution,
        _REObjectDistribution,
        _CostCenterDistribution,
        _WBSElementDistribution,
        _InternalOrderDistribution,
        _REConditionDistribution,

        _REOrganizationalAssgmtTerm,
        _REPostingTerm,
        _RERhythmTerm,
        _REAdjustmentTerm,

        //Text

        _REConditionTypeText,
        _RECndnPurposeExtText,
        _RECndnCalculationRuleExtText,
        _RECndnDistrRuleExtText,
        _RECndnChangeReasonText,
        _CurrencyText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VICDCOND"
],
"ASSOCIATED":
[
"I_COSTCENTER",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_INTERNALORDER",
"I_READJUSTMENTTERM",
"I_RECNDNCALCULATIONRULEEXT",
"I_RECNDNCALCULATIONRULEEXTTEXT",
"I_RECNDNCHANGEREASONTEXT",
"I_RECNDNDISTRIBUTIONRULEEXT",
"I_RECNDNDISTRRULEEXTTEXT",
"I_RECNDNPURPOSEEXTTEXT",
"I_RECONDITIONCALCULATION",
"I_RECONDITIONCHANGEREASON",
"I_RECONDITIONDISTRIBUTION",
"I_RECONDITIONPURPOSEEXT",
"I_RECONDITIONTYPE",
"I_RECONDITIONTYPETEXT",
"I_RECONTRACTSUBJECT",
"I_REKEYASSGMT",
"I_REOBJECTGROUP",
"I_REOBJECTTYPE",
"I_REOBJECTTYPEDETAILS",
"I_REOBJECTTYPEDISTRIBUTION",
"I_REOBJECTTYPEPOSTING",
"I_REORGANIZATIONALASSGMTTERM",
"I_REPOSTINGTERM",
"I_RERHYTHMTERM",
"I_TECHNICALOBJECT",
"I_USER",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/