I_RAPERFORMANCEOBLIGATION
RA Performance Obligation
I_RAPERFORMANCEOBLIGATION is a CDS View in S/4HANA. RA Performance Obligation. It contains 103 fields. 65 CDS views read from this table.
CDS Views using this table (65)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_RAPerfOblgnManualSpreadingTP | view_entity | from | CONSUMPTION | RA Performance Obligation |
| C_RAPerfOblgnMnlFlfmtTP | view_entity | from | CONSUMPTION | RA Performance Obligation |
| C_RAPerfOblgnToDocumentFlow | view | from | CONSUMPTION | Performance Obligation To Document Flow |
| C_RAToBeMonitoredPerfOblgn | view | from | CONSUMPTION | Performance Obligation |
| C_RAToBeReassignedPerfOblgn | view_entity | from | CONSUMPTION | To Be Reassigned Performance Obligation |
| ESH_N_PEROBLIGN | view | from | ||
| I_RAContractWithPerfOblgnVH | view | from | COMPOSITE | RA Contract Value Help |
| I_RAPerfOblgnToRevnExplItem | view | from | COMPOSITE | RA Perf Oblgn To Revenue Expl Item |
| I_RAPerfOblgnWithToCurPerdAmt | view | from | COMPOSITE | Interface RA Perf Oblgn With Amt |
| I_RAPerfOblgnWthCndnTypeAmt | view | from | COMPOSITE | Interface RA Condition Type Amt |
| I_RAPerfOblgnWthToCurPerdAmtTP | view | from | TRANSACTIONAL | RA Perf Oblgn With Amt |
| I_RARevenueScheduleItem | view | inner | COMPOSITE | Revenue Schedule: Distinct and Compound POB |
| I_RevnAcctgScheduleItem | view | inner | COMPOSITE | Composite Revenue Acctg Schedule Item |
| P_CndnTypeAmtMngRevnContr | view_entity | from | CONSUMPTION | Conditions |
| P_EBRRRevContrWLITM | view_entity | from | CONSUMPTION | PECRun: Revenue Contract Worklist item |
| P_NmbrOfCompndPerfOblgnByContr | view | from | COMPOSITE | |
| P_RAAnlytsPerfOblgnTransPrice | view_entity | union | COMPOSITE | |
| P_RAAnlytsPerfOblgnTransPrice | view_entity | from | COMPOSITE | |
| P_RABOMHierarchyInfo | view_entity | from | COMPOSITE | BOM Hierarchy Information |
| P_RACompoundHierPerfOblgnCount | view_entity | from | COMPOSITE | Count of Performance Obligations of a Compound Hierarchy |
| P_RAContractRecognizedRevenue | view | inner | COMPOSITE | |
| P_RAContractTotalCost | view | inner | COMPOSITE | |
| P_RAContractualPriceByBP | view | from | COMPOSITE | |
| P_RAContractualPriceWithCust | view | from | COMPOSITE | |
| P_RAContractWithPerfOblgnStdVH | view | from | COMPOSITE | |
| P_RADefitemPerPerd | view | inner | COMPOSITE | |
| P_RAEffectiveQtyPerPeriod | view | inner | COMPOSITE | |
| P_RAFinCmplncMaximumChangeDate | view_entity | from | COMPOSITE | |
| P_RAFinCmplncPerfOblgnCrtnDate | view_entity | from | COMPOSITE | |
| P_RAFinCmplncPerfOblgnCrtnDate | view_entity | union_all | COMPOSITE | |
| P_RAFinCmplncPerfOblgnForAudit | view_entity | from | COMPOSITE | |
| P_RAFinCmplncPerfOblgnForAudit | view_entity | union_all | COMPOSITE | |
| P_RAFinCmplncPerfOblgnSeld | view_entity | from | COMPOSITE | |
| P_RAFinCmplncPerfOblgnTransPrc | view_entity | union | COMPOSITE | |
| P_RAFinCmplncPerfOblgnTransPrc | view_entity | from | COMPOSITE | |
| P_RAFinCmplncTransPriceForAud | view_entity | from | COMPOSITE | |
| P_RAFinCmplncTransPriceForAud | view_entity | union | COMPOSITE | |
| P_RAFulfilledQtyUpToCurPerd | view | union_all | COMPOSITE | |
| P_RAHighLvlPerfOblgnAmt | view | from | COMPOSITE | |
| P_RAIntegEBRRWBSElement | view | from | COMPOSITE | RAR Integration EBRR WBS |
| P_RAIntegObjEBRR | view | from | COMPOSITE | RAR integration Objects EBRR |
| P_RAIntegObjEBRR | view | union_all | COMPOSITE | RAR integration Objects EBRR |
| P_RAInvcAndFulfilledQtyPerKey | view | inner | COMPOSITE | |
| P_RAInvoicedQtyUpToCurPerd | view | inner | COMPOSITE | |
| P_RALinkedPerfOblgnCount | view_entity | from | COMPOSITE | Number of Linked POBs of a Leading POB |
| P_RANonDistinctMnllyAllcdPrc | view_entity | inner | COMPOSITE | |
| P_RAPerfOblgnByContract | view | from | COMPOSITE | |
| P_RAPerfOblgnMaxRecnclnKey | view | from | COMPOSITE | |
| P_RAPerfOblgnRevenueAmount | view | from | COMPOSITE | |
| P_RAPerfOblgnWthBalShtAccounts | view | from | COMPOSITE | |
| P_RAPerfOblignAllPeriods | view_entity | from | COMPOSITE | |
| P_RAPostingPerPerd | view | inner | COMPOSITE | |
| P_RAPriceByPerfOblgnName | view | from | COMPOSITE | |
| P_RASchedDistinctItem | view | inner | COMPOSITE | |
| P_RASchedNonDistinctPerdExtend | view | inner | COMPOSITE | |
| P_RASchedPerfOblgn | view | inner | COMPOSITE | |
| P_RATotalFulfilledQty | view | union_all | COMPOSITE | |
| P_RATOTALOPENCOST | view | from | COMPOSITE | |
| P_RATotalOpenRevenue | view | from | COMPOSITE | |
| P_RATotalOpenRevnEventBased | view | from | COMPOSITE | |
| P_RATotalOpenRevnTimeBased | view | from | COMPOSITE | |
| P_TotAllocatedEffctvAmtPerPerd | view | inner | COMPOSITE | |
| R_RAFinComplianceSuspension | view_entity | from | TRANSACTIONAL | Compliance of Suspension Date |
| R_RAPerfOblgnMngRevnContrTP | view_entity | from | TRANSACTIONAL | Performance Obligation |
| R_RAPerformanceObligationTP | view_entity | from | TRANSACTIONAL | RA Performance Obligation |
Fields (103)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AccountingPrinciple | AccountingPrinciple | 19 |
| KEY | CompanyCode | CompanyCode | 23 |
| KEY | PerformanceObligation | NPerformanceObligation,PerformanceObligation,RAHigherLevelPerfOblgn | 31 |
| KEY | PerformanceObligationClass | PerformanceObligationClass | 23 |
| KEY | RevenueAccountingContract | RevenueAccountingContract | 44 |
| _AccountingPrinciple | _AccountingPrinciple | 8 | |
| _BusinessArea | _BusinessArea | 6 | |
| _BusinessPartner | _BusinessPartner | 5 | |
| _ChangedByUser | _ChangedByUser | 2 | |
| _CompanyCode | _CompanyCode | 8 | |
| _ControllingArea | _ControllingArea | 4 | |
| _CostCenter | _CostCenter | 4 | |
| _CreatedByUser | _CreatedByUser | 2 | |
| _Currency | _Currency | 2 | |
| _CurrentCostCenter | _CurrentCostCenter | 1 | |
| _CurrentProfitCenter | _CurrentProfitCenter | 1 | |
| _Customer | _Customer | 7 | |
| _FulfillmentType | _FulfillmentType | 10 | |
| _FunctionalArea | _FunctionalArea | 6 | |
| _IndicatorManuallyChgd | _IndicatorManuallyChgd | 2 | |
| _Mapping | _Mapping | 2 | |
| _Order | _Order | 6 | |
| _PerfOblgnContractualQtyUnit | _PerfOblgnContractualQtyUnit | 4 | |
| _PerfOblgnDistinctType | _PerfOblgnDistinctType | 7 | |
| _PerfOblgnEffectiveQtyUnit | _PerfOblgnEffectiveQtyUnit | 6 | |
| _PerfOblgnStartDateType | _PerfOblgnStartDateType | 4 | |
| _PerfObligationEventType | _PerfObligationEventType | 10 | |
| _ProfitCenter | _ProfitCenter | 5 | |
| _RAPerfOblgnCategory | _RAPerfOblgnCategory | 3 | |
| _RAPerfOblgnStatus | _RAPerfOblgnStatus | 6 | |
| _RevenueAccountingContract | _RevenueAccountingContract | 6 | |
| _SalesOrder | _SalesOrder | 6 | |
| _SalesOrderItem | _SalesOrderItem | 2 | |
| _SalesOrganization | _SalesOrganization | 6 | |
| _Segment | _Segment | 6 | |
| _WBSElement | _WBSElement | 6 | |
| AllocatedPriceInSalesDocCrcy | AllocatedPriceInSalesDocCrcy | 4 | |
| BusinessArea | BusinessArea | 6 | |
| BusinessPartner | BusinessPartner | 9 | |
| ContractualPrcInSlsDocCrcy | ContractualPrcInSlsDocCrcy | 3 | |
| ControllingArea | ControllingArea | 5 | |
| CostCenter | CostCenter | 7 | |
| Customer | Customer | 13 | |
| FunctionalArea | FunctionalArea | 6 | |
| OrderID | OrderID | 7 | |
| PerfOblgnContractualQtyUnit | PerfOblgnContractualQtyUnit | 6 | |
| PerfOblgnContractualQuantity | PerfOblgnContractualQuantity | 5 | |
| PerfOblgnCreatedByUser | PerfOblgnCreatedByUser | 2 | |
| PerfOblgnCreationDate | PerfOblgnCreationDate,RAPerfOblgnInceptionDate | 6 | |
| PerfOblgnDeliveredQuantity | PerfOblgnDeliveredQuantity | 2 | |
| PerfOblgnEffectiveQuantity | PerfOblgnEffectiveQuantity | 4 | |
| PerfOblgnEffectiveQuantityUnit | FulfilledQuantityUnit,PerfOblgnEffectiveQuantityUnit | 10 | |
| PerfOblgnEventType | PerfOblgnEventType | 12 | |
| PerfOblgnFulfillmentType | PerfOblgnFulfillmentType | 16 | |
| PerfOblgnHasManualSpreading | PerfOblgnHasManualSpreading | 2 | |
| PerfOblgnHasSprdgConflict | PerfOblgnHasSprdgConflict | 2 | |
| PerfOblgnIsExclFromPriceAlloc | PerfOblgnIsExclFromPriceAlloc | 5 | |
| PerfOblgnIsFinallyInvoiced | PerfOblgnIsFinallyInvoiced | 5 | |
| PerfOblgnIsFullyFulfilled | PerfOblgnIsFullyFulfilled | 5 | |
| PerfOblgnIsSoftDeleted | PerfOblgnIsSoftDeleted | 7 | |
| PerfOblgnLastChangeDate | PerfOblgnLastChangeDate | 1 | |
| PerfOblgnLastChangedByUsr | PerfOblgnLastChangedByUsr | 2 | |
| PerfOblgnStartDateType | PerfOblgnStartDateType | 5 | |
| PerfObligationDeferralMethod | PerfObligationDeferralMethod | 6 | |
| PerformanceObligationEndDate | PerformanceObligationEndDate | 8 | |
| PerformanceObligationRole | PerformanceObligationRole | 1 | |
| PerformanceObligationStartDate | PerformanceObligationStartDate | 8 | |
| PerUnitSSPriceInSlsDocCrcy | PerUnitSSPriceInSlsDocCrcy | 5 | |
| ProfitabilitySegment_2 | ProfitabilitySegment_2 | 2 | |
| ProfitCenter | ProfitCenter | 8 | |
| RAAttributeHasConflict | RAAttributeHasConflict | 1 | |
| RAFulfillmentIsValueBased | RAFulfillmentIsValueBased | 1 | |
| RAHigherLevelPerfOblgn | RAHigherLevelPerfOblgn | 6 | |
| RAInitialEffectiveDate | RAInitialEffectiveDate | 7 | |
| RAItemDifferenceToDeliveredQty | RAItemDifferenceToDeliveredQty | 2 | |
| RAPerfOblgnCategory | RAPerfOblgnCategory | 6 | |
| RAPerfOblgnCompletionDate | RAPerfOblgnCompletionDate | 2 | |
| RAPerfOblgnDistinctType | RAPerfOblgnDistinctType | 10 | |
| RAPerfOblgnFinalizationDate | RAPerfOblgnFinalizationDate | 2 | |
| RAPerfOblgnInceptionDate | RAPerfOblgnInceptionDate | 3 | |
| RAPerfOblgnInvoiceEffectType | RAPerfOblgnInvoiceEffectType | 2 | |
| RAPerfOblgnIsCostRecognizable | RAPerfOblgnIsCostRecognizable | 1 | |
| RAPerfOblgnIsManuallyChanged | RAPerfOblgnIsManuallyChanged | 2 | |
| RAPerfOblgnIsManuallyCreated | RAPerfOblgnIsManuallyCreated | 2 | |
| RAPerfOblgnIsManuallyDeleted | RAPerfOblgnIsManuallyDeleted | 2 | |
| RAPerfOblgnIsResidual | RAPerfOblgnIsResidual | 4 | |
| RAPerformanceObligationType | RAPerformanceObligationType | 8 | |
| RAUnivRevnRecgnIntegType | RAUnivRevnRecgnIntegType | 7 | |
| RevnAcctgPerfOblgnStatus | RevnAcctgPerfOblgnStatus | 8 | |
| RevnAcctgReceivablesAccount | RevnAcctgReceivablesAccount | 1 | |
| RevnAcctgSalesOrganization | RevnAcctgSalesOrganization | 6 | |
| RevnAcctgSuspensionDate | RevnAcctgSuspensionDate | 5 | |
| RevnAcctgSuspensionReason | RevnAcctgSuspensionReason | 4 | |
| RootPerformanceObligationInBOM | RootPerformanceObligationInBOM | 4 | |
| SalesDocumentCurrency | SalesDocumentCurrency | 17 | |
| SalesOrder | SalesOrder | 6 | |
| SalesOrderItem | SalesOrderItem | 2 | |
| Segment | Segment | 7 | |
| SSPriceInSalesDocCrcy | SSPriceInSalesDocCrcy | 7 | |
| SSPriceToleranceAmount | SSPriceToleranceAmount | 3 | |
| SSPriceTolerancePercent | SSPriceTolerancePercent | 2 | |
| WBSElementExternalID | WBSElementExternalID | 7 | |
| WBSElementInternalID | WBSElementInternalID | 1 |
@AbapCatalog.sqlViewName: 'IRAPERFOBLGN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'RA Performance Obligation'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser' ]
@Analytics.dataCategory: #DIMENSION
@Metadata.ignorePropagatedAnnotations: true //C1 release shall be annotated with this
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.semanticKey: ['PerformanceObligation']
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XXL, dataClass: #TRANSACTIONAL}
@Metadata.allowExtensions:true
@ObjectModel.representativeKey: 'PerformanceObligation'
@VDM.viewType: #BASIC
define view I_RAPerformanceObligation
as select from farr_d_pob
association [1..1] to I_RevenueAccountingContract as _RevenueAccountingContract on $projection.RevenueAccountingContract = _RevenueAccountingContract.RevenueAccountingContract
association [1..*] to I_RevenueAccountingMapping as _Mapping on $projection.PerformanceObligation = _Mapping.PerformanceObligation
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_AccountingPrinciple as _AccountingPrinciple on $projection.AccountingPrinciple = _AccountingPrinciple.AccountingPrinciple
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_Segment as _Segment on $projection.Segment = _Segment.Segment
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..*] to I_ProfitCenter as _ProfitCenter on $projection.ControllingArea = _ProfitCenter.ControllingArea
and $projection.ProfitCenter = _ProfitCenter.ProfitCenter
association [0..1] to I_ProfitCenter as _CurrentProfitCenter on $projection.ControllingArea = _CurrentProfitCenter.ControllingArea
and $projection.ProfitCenter = _CurrentProfitCenter.ProfitCenter
and _CurrentProfitCenter.ValidityStartDate <= $session.system_date
and _CurrentProfitCenter.ValidityEndDate >= $session.system_date
association [0..*] to I_CostCenter as _CostCenter on $projection.ControllingArea = _CostCenter.ControllingArea
and $projection.CostCenter = _CostCenter.CostCenter
association [0..1] to I_CostCenter as _CurrentCostCenter on $projection.ControllingArea = _CurrentCostCenter.ControllingArea
and $projection.CostCenter = _CurrentCostCenter.CostCenter
and _CurrentCostCenter.ValidityStartDate <= $session.system_date
and _CurrentCostCenter.ValidityEndDate >= $session.system_date
association [0..1] to I_WBSElementByExternalID as _WBSElement on $projection.WBSElementExternalID = _WBSElement.WBSElementExternalID
// update association to internal wbs element
association [0..1] to I_WBSElementBasicData as _InternalWBSElement on $projection.WBSElementInternalID = _InternalWBSElement.WBSElementInternalID
association [0..1] to I_Currency as _Currency on $projection.SalesDocumentCurrency = _Currency.Currency
association [0..1] to I_Currency as _CostCurrency on $projection.CostCurrency = _CostCurrency.Currency
association [0..1] to I_UnitOfMeasure as _PerfOblgnEffectiveQtyUnit on $projection.PerfOblgnEffectiveQuantityUnit = _PerfOblgnEffectiveQtyUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _PerfOblgnContractualQtyUnit on $projection.PerfOblgnContractualQtyUnit = _PerfOblgnContractualQtyUnit.UnitOfMeasure
association [1..1] to I_RAPerfOblgnFlfmtType as _FulfillmentType on $projection.PerfOblgnFulfillmentType = _FulfillmentType.PerfOblgnFulfillmentType
association [0..1] to I_RAPerfObligationEventType as _PerfObligationEventType on $projection.PerfOblgnEventType = _PerfObligationEventType.PerfOblgnEventType
association [0..1] to I_RAPerfOblgnStartDateType as _PerfOblgnStartDateType on $projection.PerfOblgnStartDateType = _PerfOblgnStartDateType.PerfOblgnStartDateType
association [1..1] to I_RAPerfOblgnStatus as _RAPerfOblgnStatus on $projection.RevnAcctgPerfOblgnStatus = _RAPerfOblgnStatus.RevnAcctgPerfOblgnStatus
association [1..1] to I_User as _CreatedByUser on $projection.PerfOblgnCreatedByUser = _CreatedByUser.UserID
association [1..1] to I_User as _ChangedByUser on $projection.PerfOblgnLastChangedByUsr = _ChangedByUser.UserID
association [0..1] to I_Customer as _Customer on $projection.Customer = _Customer.Customer
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_Order as _Order on $projection.OrderID = _Order.OrderID
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrder = _SalesOrderItem.SalesOrder
and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
association [1..1] to I_Indicator as _IndicatorManuallyChgd on $projection.RAPerfOblgnIsManuallyChanged = _IndicatorManuallyChgd.IndicatorValue
association [1..1] to I_RAPerfOblgnDistinctType as _PerfOblgnDistinctType on $projection.RAPerfOblgnDistinctType = _PerfOblgnDistinctType.RAPerfOblgnDistinctType
association [0..1] to I_PerformanceObligationRole as _PerformanceObligationRole on $projection.PerformanceObligationRole = _PerformanceObligationRole.PerformanceObligationRole
association [1..1] to I_RAPerfOblgnCategory as _RAPerfOblgnCategory on $projection.RAPerfOblgnCategory = _RAPerfOblgnCategory.RAPerfOblgnCategory
association [0..1] to I_SalesOrganization as _SalesOrganization on $projection.RevnAcctgSalesOrganization = _SalesOrganization.SalesOrganization
association [1..1] to I_RAUnivRevnRecgnIntegType as _RAUnivRevnRecgnIntegType on $projection.RAUnivRevnRecgnIntegType = _RAUnivRevnRecgnIntegType.RAUnivRevnRecgnIntegType
//association [0..1] to I_RAPerfOblgnDeferralMethod as _PerfOblgnDeferralMethod on $projection.PerfObligationDeferralMethod = _PerfOblgnDeferralMethod.PerfObligationDeferralMethod
//association [0..1] to I_RAPerfOblgnInvcEffctType as _PerfOblgnInvcEffctType on $projection.RAPerfOblgnInvoiceEffectType = _PerfOblgnInvcEffctType.RAPerfOblgnInvoiceEffectType
{
@ObjectModel.text.element: ['PerformanceObligationClass']
key cast(pob_id as farr_cds_pob_id preserving type) as PerformanceObligation,
@Semantics.text: true
cast( pob_name as farr_cds_pob_name preserving type ) as PerformanceObligationClass,
@ObjectModel.foreignKey.association: '_RevenueAccountingContract'
cast( contract_id as farr_cds_contract_id preserving type ) as RevenueAccountingContract,
@ObjectModel.foreignKey.association: '_Segment'
segment as Segment,
@ObjectModel.foreignKey.association: '_ControllingArea'
_CompanyCode.ControllingArea as ControllingArea,
@ObjectModel.foreignKey.association: '_ProfitCenter'
prctr as ProfitCenter,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
alloc_amt as AllocatedPriceInSalesDocCrcy,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
cast(trx_price as farr_cds_contractual_price preserving type ) as ContractualPrcInSlsDocCrcy,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
cast( unit_ssp as farr_cds_unit_ssp preserving type ) as PerUnitSSPriceInSlsDocCrcy,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
cast( ssp as farr_cds_standalone_price preserving type ) as SSPriceInSalesDocCrcy,
cast( ssp_range_perc as farr_cds_ssp_range_percentage ) as SSPriceTolerancePercent,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
ssp_range_amount as SSPriceToleranceAmount,
@ObjectModel.foreignKey.association: '_Currency'
@Semantics.currencyCode: true
alloc_amt_curk as SalesDocumentCurrency,
@Semantics.quantity.unitOfMeasure: 'PerfOblgnContractualQtyUnit'
cast( quantity as farr_cds_contractual_quantity) as PerfOblgnContractualQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_PerfOblgnContractualQtyUnit'
quantity_unit as PerfOblgnContractualQtyUnit,
@Semantics.quantity.unitOfMeasure: 'PerfOblgnEffectiveQuantityUnit'
//cast( effective_qty as abap.dec(18, 2) ) as PerfOblgnEffectiveQuantity,
cast( effective_qty as farr_cds_effective_quantity) as PerfOblgnEffectiveQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_PerfOblgnEffectiveQtyUnit'
effective_qty_unit as PerfOblgnEffectiveQuantityUnit,
@ObjectModel.foreignKey.association: '_FulfillmentType'
cast( fulfill_type as farr_fulfill_type) as PerfOblgnFulfillmentType,
cast( residual_pob as farr_cds_residual_pob preserving type ) as RAPerfOblgnIsResidual,
@ObjectModel.foreignKey.association: '_PerfObligationEventType'
event_type as PerfOblgnEventType,
@Semantics.businessDate.from: true
start_date as PerformanceObligationStartDate,
@Semantics.businessDate.to: true
end_date as PerformanceObligationEndDate,
final_date as RAPerfOblgnFinalizationDate,
// @ObjectModel.foreignKey.association: '_PerfOblgnDeferralMethod'
deferral_method as PerfObligationDeferralMethod,
@ObjectModel.foreignKey.association: '_PerfOblgnStartDateType'
start_date_type as PerfOblgnStartDateType,
duration as PerfObligationDuration,
duration_unit as PerfObligationDurationUnit,
cast ( fully_fulfilled as farr_cds_fully_fulfilled preserving type ) as PerfOblgnIsFullyFulfilled,
final_invoice as PerfOblgnIsFinallyInvoiced,
@ObjectModel.foreignKey.association: '_BusinessPartner'
partner as BusinessPartner,
@ObjectModel.foreignKey.association: '_CostCenter'
kostl as CostCenter,
@ObjectModel.foreignKey.association:'_WBSElement'
_InternalWBSElement.WBSElementExternalID as WBSElementExternalID,
@ObjectModel.foreignKey.association: '_InternalWBSElement'
cast( ps_psp_pnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
//No dimension view can be used as sales organization of Revenue accounting is compatible for different component
// @ObjectModel.foreignKey.association:'_SalesOrganization'
sales_org as RevnAcctgSalesOrganization,
@ObjectModel.foreignKey.association: '_CompanyCode'
company_code as CompanyCode,
@ObjectModel.foreignKey.association: '_AccountingPrinciple'
acct_principle as AccountingPrinciple,
@Semantics.user.createdBy: true
// @ObjectModel.foreignKey.association: '_CreatedByUser' //C1 released view cannot use ForeignKey Association of View without Representative key
cast( created_by as fis_cc_erfnm preserving type ) as PerfOblgnCreatedByUser,
@Semantics.systemDate.createdAt: true
cast( created_on as fis_cc_erfdt preserving type ) as PerfOblgnCreationDate,
@Semantics.systemDate.lastChangedAt: true
last_changed_on as PerfOblgnLastChangeDate,
@Semantics.user.lastChangedBy: true
// @ObjectModel.foreignKey.association: '_ChangedByUser'
cast( last_changed_by as fis_aufaenam preserving type ) as PerfOblgnLastChangedByUsr,
cast( prevent_alloc as farr_cds_exclude_allocation preserving type ) as PerfOblgnIsExclFromPriceAlloc,
rev_rec_block as PerfOblgnPostingIsSusp,
@Semantics.amount.currencyCode: 'SalesDocumentCurrency'
distributed_org_price as OplContractualPrcInSlsDocCrcy,
cast( has_pro_change as farr_cds_has_pro_change preserving type) as PerfOblgnHasContrModification,
hi_level_pob_id as RAHigherLevelPerfOblgn,
soft_deleted as PerfOblgnIsSoftDeleted,
/// @ObjectModel.foreignKey.association:'_PerfOblgnInvcEffctType'
invoice_effect_type as RAPerfOblgnInvoiceEffectType,
cast( value_based_fulfillments as farr_cds_ful_based_on_value preserving type ) as RAFulfillmentIsValueBased,
@ObjectModel.foreignKey.association: '_RAPerfOblgnStatus'
cast( status as farr_cds_pob_status preserving type ) as RevnAcctgPerfOblgnStatus,
cast( completion_date as farr_cds_pob_completion_date preserving type ) as RAPerfOblgnCompletionDate,
@ObjectModel.foreignKey.association: '_Customer'
customer_id as Customer,
cast(pob_type as farr_cds_pob_type preserving type) as RAPerformanceObligationType,
@ObjectModel.foreignKey.association: '_RAPerfOblgnCategory'
cast(pob_category as farr_cds_pob_category preserving type ) as RAPerfOblgnCategory,
@ObjectModel.foreignKey.association: '_FunctionalArea'
fkber as FunctionalArea,
@ObjectModel.foreignKey.association: '_BusinessArea'
gsber as BusinessArea,
@API.element.releaseState: #DECOMMISSIONED
@API.element.successor: 'ProfitabilitySegment_2'
cast( case when paobjnr > '9999999999' then '9999999999' else lpad( paobjnr, 10, '0' ) end as rkeobjnr_numc ) as ProfitabilitySegment,
cast(paobjnr as rkeobjnr_char) as ProfitabilitySegment_2,
@ObjectModel.foreignKey.association: '_Order'
aufnr as OrderID,
@ObjectModel.foreignKey.association: '_SalesOrder'
kdauf as SalesOrder,
@ObjectModel.foreignKey.association: '_SalesOrderItem'
kdpos as SalesOrderItem,
accrued_cost_account as RAPerfOblgnAccruedCostAccount,
deferred_cost_account as RAPerfOblgnDeferredCostAccount,
asset_account as RAContractAssetAccount,
liability_account as RAContractLiabilityAccount,
manual_changed as RAPerfOblgnIsManuallyChanged,
manual_created as RAPerfOblgnIsManuallyCreated,
manual_deleted as RAPerfOblgnIsManuallyDeleted,
@Semantics.amount.currencyCode: 'CostCurrency'
cost as RAPerfOblgnCostAmtInSlsDocCrcy,
@ObjectModel.foreignKey.association: '_CostCurrency'
@Semantics.currencyCode: true
cost_curk as CostCurrency,
@ObjectModel.foreignKey.association: '_PerfOblgnDistinctType'
distinct_type as RAPerfOblgnDistinctType,
cast(cost_recognition as farr_cds_cost_recognition ) as RAPerfOblgnIsCostRecognizable,
initial_effective_date as RAInitialEffectiveDate,
bom_pob_id as RootPerformanceObligationInBOM,
@Semantics.quantity.unitOfMeasure: 'PerfOblgnContractualQtyUnit'
cast( delivered_quantity as farr_cds_delivered_quantity) as PerfOblgnDeliveredQuantity,
@Semantics.quantity.unitOfMeasure: 'PerfOblgnContractualQtyUnit'
cast( delivered_qty_diff as farr_cds_diff_to_delivered_qty) as RAItemDifferenceToDeliveredQty,
cast(pob_role as farr_cds_pob_role) as PerformanceObligationRole,
cast(leading_pob_id as farr_cds_leading_pob_id) as LeadingPerformanceObligation,
inception_date as RAPerfOblgnInceptionDate,
suspension_date as RevnAcctgSuspensionDate,
suspension_reason as RevnAcctgSuspensionReason,
manual_spreading as PerfOblgnHasManualSpreading,
spread_conflict as PerfOblgnHasSprdgConflict,
attr_conflict as RAAttributeHasConflict,
urr_integration_type as RAUnivRevnRecgnIntegType,
receivable_account as RevnAcctgReceivablesAccount,
/* association */
_RevenueAccountingContract,
_Mapping,
_CompanyCode,
_AccountingPrinciple,
_BusinessPartner,
_Segment,
_WBSElement,
_ControllingArea,
_CurrentProfitCenter,
_ProfitCenter,
_CurrentCostCenter,
_CostCenter,
_Currency,
_CostCurrency,
_PerfOblgnContractualQtyUnit,
_PerfOblgnEffectiveQtyUnit,
_FulfillmentType,
_PerfObligationEventType,
_PerfOblgnStartDateType,
_RAPerfOblgnStatus,
_CreatedByUser,
_ChangedByUser,
_Customer,
_FunctionalArea,
_BusinessArea,
_Order,
_SalesOrder,
_SalesOrderItem,
_IndicatorManuallyChgd,
_PerfOblgnDistinctType,
_PerformanceObligationRole,
_RAPerfOblgnCategory,
_RAUnivRevnRecgnIntegType,
_SalesOrganization,
_InternalWBSElement
// _PerfOblgnDeferralMethod,
// _PerfOblgnInvcEffctType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_WBSELEMENTBASICDATA",
"FARR_D_POB"
],
"ASSOCIATED":
[
"I_ACCOUNTINGPRINCIPLE",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_CUSTOMER",
"I_FUNCTIONALAREA",
"I_INDICATOR",
"I_ORDER",
"I_PERFORMANCEOBLIGATIONROLE",
"I_PROFITCENTER",
"I_RAPERFOBLGNCATEGORY",
"I_RAPERFOBLGNDISTINCTTYPE",
"I_RAPERFOBLGNFLFMTTYPE",
"I_RAPERFOBLGNSTARTDATETYPE",
"I_RAPERFOBLGNSTATUS",
"I_RAPERFOBLIGATIONEVENTTYPE",
"I_RAUNIVREVNRECGNINTEGTYPE",
"I_REVENUEACCOUNTINGCONTRACT",
"I_REVENUEACCOUNTINGMAPPING",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SALESORGANIZATION",
"I_SEGMENT",
"I_UNITOFMEASURE",
"I_USER",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYEXTERNALID"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/