P_RATotalOpenRevnEventBased

@AbapCatalog.sqlViewName: 'PRATTOPNRVNEVT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_RATotalOpenRevnEventBased
  with parameters
    P_FiscalYear   : fis_gjahr,
    P_FiscalPeriod : fins_fiscalperiod

  as select from           I_RAPerformanceObligation as PerformObligation

    left outer to one join P_RATotalSumRevenue(
                           P_FiscalYear          : :P_FiscalYear,
                           P_FiscalPeriod        : :P_FiscalPeriod
                           )                         as _SumRevenue on  PerformObligation.PerformanceObligation = _SumRevenue.PerformanceObligation
                                                                    and PerformObligation.CompanyCode           = _SumRevenue.CompanyCode
                                                                    and PerformObligation.AccountingPrinciple   = _SumRevenue.AccountingPrinciple
{
  key PerformObligation.PerformanceObligation,

  key PerformObligation.CompanyCode,
  key PerformObligation.AccountingPrinciple,

      PerformObligation.RevenueAccountingContract,
      PerformObligation.SalesDocumentCurrency,

      cast(0 as farr_open_revenue)                                                                                                                           as TimeBasedTotalOpenRevenue,

      cast(( PerformObligation.AllocatedPriceInSalesDocCrcy - coalesce( TotalRecognizedAmount, 0) - coalesce( TotalCatchupAmount, 0)) as farr_open_revenue)  as EventBasedTotalOpenRevenue,

      //cast(( PerformObligation.AllocatedPriceInSalesDocCrcy - coalesce( TotalRecognizedAmount, 0) - coalesce( TotalCatchupAmount, 0)) as farr_open_revenue)  as TotalOpenRevenue,


      PerformObligation.RAPerformanceObligationType,
      PerformObligation.BusinessPartner,
      PerformObligation.Customer,
      PerformObligation.PerfOblgnFulfillmentType,
      PerformObligation.PerfOblgnEventType,
      PerformObligation.RevnAcctgSalesOrganization,
      PerformObligation.FunctionalArea,
      PerformObligation.BusinessArea,
      PerformObligation.Segment,
      PerformObligation.ProfitCenter,
      PerformObligation.CostCenter,
      PerformObligation.OrderID,
      PerformObligation.SalesOrder,
      PerformObligation.WBSElementExternalID,
      PerformObligation.RevnAcctgPerfOblgnStatus,
      PerformObligation.ControllingArea,
      PerformObligation.PerformanceObligationClass,
      PerformObligation.RAInitialEffectiveDate,


      /**** Others ****/
      PerformObligation._AccountingPrinciple,
      PerformObligation._BusinessArea,
      PerformObligation._BusinessPartner,
      PerformObligation._CompanyCode,
      PerformObligation._Customer,
      PerformObligation._FulfillmentType,
      PerformObligation._FunctionalArea,
      PerformObligation._Order,
      PerformObligation._PerfObligationEventType,
      PerformObligation._RAPerfOblgnStatus,
      PerformObligation._SalesOrder,
      PerformObligation._Segment,
      PerformObligation._WBSElement,
      PerformObligation._CostCenter,
      PerformObligation._ProfitCenter,
      PerformObligation._ControllingArea,
      PerformObligation._SalesOrganization,
      PerformObligation._RevenueAccountingContract
}
where
       PerformObligation.PerfOblgnIsSoftDeleted   =  ''
  and(
       PerformObligation.RAPerfOblgnDistinctType  =  'D'
    or PerformObligation.RAPerfOblgnDistinctType  =  'N'
  )
  and  PerformObligation.RAPerfOblgnCategory      =  ''
  and  PerformObligation.PerfOblgnFulfillmentType <> 'T'
  and(
       PerformObligation.RevnAcctgPerfOblgnStatus =  'I'
    or PerformObligation.RevnAcctgPerfOblgnStatus =  'R'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RAPERFORMANCEOBLIGATION",
"P_RATOTALSUMREVENUE"
],
"ASSOCIATED":
[
"I_ACCOUNTINGPRINCIPLE",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CUSTOMER",
"I_FUNCTIONALAREA",
"I_ORDER",
"I_PROFITCENTER",
"I_RAPERFOBLGNFLFMTTYPE",
"I_RAPERFOBLGNSTATUS",
"I_RAPERFOBLIGATIONEVENTTYPE",
"I_REVENUEACCOUNTINGCONTRACT",
"I_SALESORDER",
"I_SALESORGANIZATION",
"I_SEGMENT",
"I_WBSELEMENTBYEXTERNALID"
],
"BASE":
[
"I_RAPERFORMANCEOBLIGATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/