I_PROFITCENTERTOWBSELEMENT

CDS View

Assgmt of PrftCtr to WBS Element

I_PROFITCENTERTOWBSELEMENT is a CDS View in S/4HANA. Assgmt of PrftCtr to WBS Element. It contains 6 fields. 9 CDS views read from this table.

Used by 9 CDS view(s) 6 fields

CDS Views using this table (9)

ViewTypeJoinVDMDescription
C_ProfitCenterToWBSElement view_entity from CONSUMPTION Assgmt of PrftCtr to WBS Element
FINOC_RT_FA_FILL view union_all Orgl Change: Fill Runtime for Fixed Asset
FINOC_RT_POI_FILL view from Orgl Change: Fill Runtime for Purg Doc
FINOC_RT_SOI_FILL view from Orgl Change: Fill Runtime for Sales Doc
FINOC_RT_WBS_FILL view left_outer Orgl Change: Fill Runtime for WBS Elmnt
P_NmbrOfOrglChgObjectsByType view_entity from CONSUMPTION Orgl Change Master Data Report List
P_OrglChangeReportRootWBS view from CONSUMPTION Orgl Change Report Root WBSElement
P_OrglChangeReportWBStoPROJ view from CONSUMPTION Dependent WBS Element to Root Project
P_OrglChangeReportWBStoWBS view from CONSUMPTION Dependent WBSElement to Root WBSElement

Fields (6)

KeyField CDS FieldsUsed in Views
KEY OrganizationalChange OrganizationalChange 3
CompanyCode CompanyCode 2
ControllingArea ControllingArea 2
ProfitCenter ProfitCenterByOrglChange 3
ProfitCenterBeforeOrglChange ProfitCenterBeforeOrglChange 3
SourceProjectInternalID SourceProjectInternalID 1 
@AbapCatalog.sqlViewName: 'IFINOCRTWBS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Assgmt of PrftCtr to WBS Element'
@VDM.viewType: #BASIC
@Analytics: {
  dataCategory: #DIMENSION
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'WBSElementInternalID'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #L
}
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true

@ObjectModel:{
  supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern:  #ANALYTICAL_DIMENSION 
}

define view I_ProfitCenterToWBSElement
  as select from finoc_rt_wbs
  association [1]    to I_OrglChangeReassignmentStatus as _OrglChgReassignmentStatus    on  $projection.OrglChangeReassignmentStatus = _OrglChgReassignmentStatus.OrglChangeReassignmentStatus
  association [0..1] to I_ProfitCtrDerivationSrceType  as _ProfitCtrDerivationSrceType  on  $projection.ProfitCenterDerivationSrceType = _ProfitCtrDerivationSrceType.ProfitCenterDerivationSrceType
  association [1]    to I_WBSElementBasicData          as _WBSElement                   on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_OrganizationalChange         as _OrglChange                   on  $projection.OrganizationalChange = _OrglChange.OrganizationalChange
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1]    to I_ControllingArea              as _ControllingArea              on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ProfitCenter                 as _ProfitCtr                    on  $projection.ControllingArea   =  _ProfitCtr.ControllingArea
                                                                                        and $projection.ProfitCenter      =  _ProfitCtr.ProfitCenter
                                                                                        and $projection.ValidityStartDate >= _ProfitCtr.ValidityStartDate
                                                                                        and $projection.ValidityStartDate <= _ProfitCtr.ValidityEndDate
  association [0..1] to I_ProfitCenter                 as _ProfitCenterBeforeOrglChange on  $projection.ControllingArea              =  _ProfitCenterBeforeOrglChange.ControllingArea
                                                                                        and $projection.ProfitCenterBeforeOrglChange =  _ProfitCenterBeforeOrglChange.ProfitCenter
                                                                                        and $projection.ValidityStartDate            >= _ProfitCenterBeforeOrglChange.ValidityStartDate
                                                                                        and $projection.ValidityStartDate            <= _ProfitCenterBeforeOrglChange.ValidityEndDate
  association [0..1]    to I_WBSElementBasicData          as _SourceWBSElement          on  $projection.SourceWBSElementInternalID = _SourceWBSElement.WBSElementInternalID
 
{
  key cast (ps_psp_pnr as fis_wbsint_no_conv preserving type) as WBSElementInternalID,
      @Semantics.businessDate.from:true
  key valid_from                                              as ValidityStartDate,
      @Semantics.businessDate.to:true
      valid_to                                                as ValidityEndDate,
      kokrs                                                   as ControllingArea,
      bukrs                                                   as CompanyCode,
      prctr_old                                               as ProfitCenterBeforeOrglChange,
      prctr                                                   as ProfitCenter,
      orgl_change                                             as OrganizationalChange,
      reassgmt_status                                         as OrglChangeReassignmentStatus,
      prctr_drvtn_source_type                                 as ProfitCenterDerivationSrceType,
      srce_ps_psp_pnr                                         as SourceWBSElementInternalID,
      cast (srce_ps_prj_pnr as ps_s4_proj_pspnr preserving type)   as SourceProjectInternalID,
      _SourceWBSElement.WBSElementExternalID                  as SourceWBSElementExternalID,
      _OrglChgReassignmentStatus,
      _ProfitCtrDerivationSrceType,
      _WBSElement,
      _OrglChange,
      _CompanyCode,
      _ControllingArea,
      _ProfitCtr,
      _ProfitCenterBeforeOrglChange
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WBSELEMENTBASICDATA",
"FINOC_RT_WBS"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_ORGANIZATIONALCHANGE",
"I_ORGLCHANGEREASSIGNMENTSTATUS",
"I_PROFITCENTER",
"I_PROFITCTRDERIVATIONSRCETYPE",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More