I_PPM_ISMYPROJECT

CDS View

All projects a user is respsonible for

I_PPM_ISMYPROJECT is a CDS View in S/4HANA. All projects a user is respsonible for. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_PPM_MostCriticalProject view left_outer COMPOSITE My Projects - Critical
I_PPM_Myplannedprojects view inner COMPOSITE My Projects – Planned
P_PPM_Project view left_outer COMPOSITE
P_PPM_ProjectList view left_outer COMPOSITE 
@EndUserText.label: 'All projects a user is respsonible for'

@VDM.viewType: #COMPOSITE

@AbapCatalog: { 
    sqlViewName: 'IPPMISMYPROJECT',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
   representativeKey: 'ProjectUUID',
   alternativeKey: [ { id : 'ProjectSummaryTaskUUID', uniqueness: #UNIQUE, element: 'ProjectSummaryTaskUUID' } ],
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #S
   }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
define view I_PPM_IsMyProject as select distinct from I_PPM_ProjectSummaryTask as PST
    inner join I_User as user
        on user.UserID = $session.user
    inner join dpr_entity_link as entity
        on PST.ProjectSummaryTaskUUID = entity.entity_guid
    left outer join cgpl_hierarchy  as cgplhier 
        on cgplhier.up = entity.participant_guid
    left outer join dpr_bupa_link   as concrete  
        on concrete.participant_guid = entity.participant_guid
    left outer join dpr_bupa_link   as abstract
        on abstract.participant_guid = cgplhier.guid   
{
    key PST.ProjectUUID,
    key PST.ProjectSummaryTaskUUID,
    entity.responsible as IsMyProject
    
} where concrete.bupa_guid = user.BusinessPartnerUUID or abstract.bupa_guid = user.BusinessPartnerUUID
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PPM_PROJECTSUMMARYTASK",
"I_USER",
"CGPL_HIERARCHY",
"DPR_BUPA_LINK",
"DPR_ENTITY_LINK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More