I_PPM_Myplannedprojects

@EndUserText.label: 'My Projects – Planned'
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPPMMYPLANNED'
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory:  #L
@ObjectModel.usageType.dataClass:  #MIXED

@ClientHandling.algorithm: #SESSION_VARIABLE

// auth check via MyLogic

@AccessControl.authorizationCheck: #NOT_ALLOWED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.semanticKey:  [ 'Project' ] 
@ObjectModel.representativeKey: 'ProjectUUID'
@ObjectModel.alternativeKey: [{
    id: 'ProjectSummaryTaskUUID',  element: ['ProjectSummaryTaskUUID'],    uniqueness: #UNIQUE
}]

@Metadata.allowExtensions: true
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_Myplannedprojects as select from I_PPM_ProjectSummaryTask as Project
    inner join I_PPM_IsMyProject       as IsMyProject     on Project.ProjectUUID = IsMyProject.ProjectUUID 

    // essential milestone

    association [0..1] to I_PPM_ProjectMilestEssent as _MilestEssent     
                    on $projection.ProjectUUID      = _MilestEssent.ProjectUUID  

    association [0..1] to I_PPM_SingleResponsibleForObj as _ProjectResponsible
                    on $projection.ProjectSummaryTaskUUID =  _ProjectResponsible.ReferencedObjectUUID                                 
    
    // retrieve portfolio info

    association [0..1] to I_PPM_ItemInfo    as _Item 
                    on ( $projection.ProjectUUID = _Item.ProjectUUID ) 
                
    association [0..*] to I_PPM_Text as _ProjectNameUserLanguage
                 on $projection.ProjectSummaryTaskUUID = _ProjectNameUserLanguage.ReferencedObjectUUID                              

{
    @Consumption.semanticObject: 'EnterpriseProject'
    key Project.ProjectUUID, 

    Project.ProjectSummaryTaskUUID,
    
    Project.ProjectName                     as ProjectName,
//    Project.ProjectName                     as ProjectNameUseranguage,



    Project.Project,   
    

    @Semantics.businessDate.at: true 
    tstmp_to_dats( Project.CreationDateTime, abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as ProjectCreationDate,

    @Semantics.businessDate.at: true 
    Project.LatestStartDate   as ProjectStartDate,
      
//    text: _PriorityText[ 1: LanguageCode = $session.system_language  ].PriorityCodeName    

//    PriorityText.PriorityCodeName,

    
    Project.PriorityCode,
//    Project._PriorityText.PriorityCodeName,

    
    _MilestEssent,
    _ProjectResponsible,
    _Item,
    _ProjectNameUserLanguage,
    Project._PriorityText,
    
    Project._AuthUser,
    Project._AuthSubst,
    Project._AuthRole,
    Project._AuthGroup   
     
}
 where Project.ProjectProcessingStatus = '00'  // Created

 and Project.ProjectVersionNumber = '' // active projects do not have a version!   

 and IsMyProject.IsMyProject = 'X'                                                                                                                                         
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PPM_ISMYPROJECT",
"I_PPM_PROJECTSUMMARYTASK"
],
"ASSOCIATED":
[
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH",
"I_PPM_ITEMINFO",
"I_PPM_PRIORITYTEXT",
"I_PPM_PROJECTMILESTESSENT",
"I_PPM_SINGLERESPONSIBLEFOROBJ",
"I_PPM_TEXT"
],
"BASE":
[
"I_PPM_PROJECTSUMMARYTASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/