I_PAYMENTREQUEST

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #BASIC
@EndUserText.label: 'Payment Requests'
define view entity I_PaymentRequest
  as select from payrq

  // I_Bank deprecated - use I_Bank_2 instead

  association [0..1] to I_Bank                        as _PayeeBank                   on  $projection.PayeeBankCountry    = _PayeeBank.BankCountry
                                                                                      and $projection.PayeeBankInternalID = _PayeeBank.BankInternalID
  association [0..1] to I_Bank                        as _Bank                        on  $projection.BankCountry    = _Bank.BankCountry
                                                                                      and $projection.BankInternalID = _Bank.BankInternalID
  association [0..1] to I_Bank_2                      as _PayeeBank2                  on  $projection.PayeeBankCountry    = _PayeeBank2.BankCountry
                                                                                      and $projection.PayeeBankInternalID = _PayeeBank2.BankInternalID
  association [0..1] to I_Bank_2                      as _Bank2                       on  $projection.BankCountry    = _Bank2.BankCountry
                                                                                      and $projection.BankInternalID = _Bank2.BankInternalID
  association [0..1] to I_HouseBankAccount            as _HouseBankAccount            on  $projection.PayingCompanyCode = _HouseBankAccount.CompanyCode
                                                                                      and $projection.HouseBankAccount  = _HouseBankAccount.HouseBankAccount
                                                                                      and $projection.HouseBank         = _HouseBankAccount.HouseBank                                                                                      
  association [0..*] to I_BusinessAreaText            as _BusinessAreaText            on  $projection.BusinessArea   = _BusinessAreaText.BusinessArea
  association [1..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_CompanyCode                 as _PayingCompanyCode           on  $projection.PayingCompanyCode = _PayingCompanyCode.CompanyCode
  association [1..1] to I_Currency                    as _PaymentRequestCurrency      on  $projection.PaymentRequestCurrency = _PaymentRequestCurrency.Currency
  association [1..1] to I_Currency                    as _AdditionalCurrency1         on  $projection.AdditionalCurrency1    = _AdditionalCurrency1.Currency
  association [1..1] to I_Currency                    as _AdditionalCurrency2         on  $projection.AdditionalCurrency2    = _AdditionalCurrency2.Currency
  association [1..1] to I_Currency                    as _CompanyCodeCurrency         on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_DataExchangeInstructionKeys as _DataExchangeInstructionKeys on  $projection.BankCountry                = _DataExchangeInstructionKeys.BankCountryKey
                                                                                      and $projection.PaymentMethod              = _DataExchangeInstructionKeys.PaymentMethod
                                                                                      and $projection.DataExchangeInstructionKey = _DataExchangeInstructionKeys.DataExchangeInstructionKey
  association [0..1] to I_PaymentMethod               as _PaymentMethod               on  $projection.BankCountry   = _PaymentMethod.Country
                                                                                      and $projection.PaymentMethod = _PaymentMethod.PaymentMethod
  association [1..1] to I_PaytReqChgAndPostingData    as _PaytReqChangeAndPost        on  $projection.PaymentRequest = _PaytReqChangeAndPost.PaymentRequest
  association [1..1] to I_ReversalReason              as _ReversalReason              on  $projection.ReversalReason = _ReversalReason.ReversalReason //??TEXT

  association [1..*] to I_SystemStatusText            as _SystemStatusText            on  $projection.StatusCode = _SystemStatusText.SystemStatus
  association [1..1] to I_FiscalYearForCompanyCode    as _CalendarDateForCompanyCode  on  $projection.PayingCompanyCode =  _CalendarDateForCompanyCode.CompanyCode
                                                                                      and $projection.ClearingDate      >= _CalendarDateForCompanyCode.FiscalYearStartDate
                                                                                      and $projection.ClearingDate      <= _CalendarDateForCompanyCode.FiscalYearEndDate
  association [0..1] to I_PaymentReason               as _PaymentReason               on  $projection.PaymentReason = _PaymentReason.PaymentReason
  association [0..1] to I_PaymentSystem               as _PayeePaymentSystem          on  $projection.PayeePaymentSystem = _PayeePaymentSystem.PaymentSystem
  association [0..1] to I_AliasType                   as _PayeeAliasType              on  $projection.PayeeAliasType = _PayeeAliasType.AliasType
  
  association [1..1] to I_UserContactCard             as _CreatedBy                   on $projection.CreatedByUser = _CreatedBy.ContactCardID
  association [1..1] to I_UserContactCard             as _PostedBy                    on $projection.PostingCreatedByUser = _PostedBy.ContactCardID
  association [1..1] to I_UserContactCard             as _ReleasedBy                  on $projection.PaymentRequestReleasedByUser = _ReleasedBy.ContactCardID
  
  association [0..*] to I_CurrencyText                as _CurrencyText                on $projection.PaymentRequestCurrency = _CurrencyText.Currency  
        
  association [1..1] to E_PaymentRequest              as _Extension                   on  $projection.PaymentRequest = _Extension.PaymentRequest


{
  key cast(payrq.keyno as farp_prq_keyno preserving type) as PaymentRequest,

      @ObjectModel.foreignKey.association: '_PayingCompanyCode'
      @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element: 'CompanyCode' } }]
      cast(payrq.zbukr as farp_bnk_com_dzbukr)            as PayingCompanyCode,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element: 'CompanyCode' } }]
      cast(payrq.bukrs as fis_bukrs)                      as CompanyCode,

      cast(payrq.belnr as farp_belnr_d)                   as AccountingDocument,
      cast(payrq.gjahr as fis_gjahr)                      as FiscalYear,
      cast(payrq.buzei as fis_buzei)                      as AccountingDocumentItem,
      cast(payrq.znme1 as farp_payee_name)                as PayeeName,
      cast(payrq.zbnks as farp_dzbnks)                    as PayeeBankCountry,    //BNKA-BANKS!

      cast(payrq.zbnky as farp_bnk_com_dzbnky)            as PayeeBankInternalID, //BNKA-BANKL!

      cast(payrq.zbkon as farp_bnk_com_dzbkon)            as PayeeBankControlKey,
      cast(payrq.zbnkl as farp_bnk_com_dzbnkl)            as PayeeBank,           //BNKA-BNKLZ!

      cast(payrq.zbnkn as farp_bnk_com_dzbnkn)            as PayeeBankAccount,
      cast(payrq.bkref as farp_prq_bkref)                 as BankDetailReference,
      cast(payrq.crval as farp_prq_crval)                 as PayeeBankValueDate,
      cast(payrq.valut as farp_prq_valdt)                 as ValueDate,
      cast(payrq.koinh as bu_koinh)                       as BankAccountHolderName,
      payrq.gsber                                         as BusinessArea,
      cast(payrq.sgtxt as farp_reftxt)                    as ReferenceTypeText, //Reference Text

      cast(payrq.hbkid as farp_hbkid)                     as HouseBank,
      payrq.hktid                                         as HouseBankAccount,

      @ObjectModel.foreignKey.association: '_PaymentRequestCurrency'
      cast(payrq.pacur as farp_prq_pacur)                 as PaymentRequestCurrency,

      @Semantics.amount.currencyCode: 'PaymentRequestCurrency'
      @DefaultAggregation: #NONE
      cast(payrq.pamtf as farp_prq_amtfc)                 as PaymentRequestAmountInPaytCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      payrq.pamtl                                         as PaymentRequestAmountInCCCrcy,

      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      payrq.hwaer                                         as CompanyCodeCurrency,
      cast(payrq.uzawe as farp_uzawe)                     as PaymentMethodSupplement,
      payrq.zwels                                         as PaymentMethod,
      cast(payrq.xpore as farp_prq_xpore)                 as IsSinglePayment,
      payrq.kidno                                         as PaymentReference,
      cast(payrq.koart as farp_koart)                     as FinancialAccountType,
      payrq.hkont                                         as GLAccount,
      cast(payrq.usnam as vdm_createdbyuserid)            as CreatedByUser, //fclm_bam_created_by

      cast(payrq.xreld as farp_prq_xreld)                 as PaytReqIsReleasedForPosting,
      cast(payrq.xreli as farp_prq_xreli)                 as PaytReqIsCompleted,
      cast(payrq.xrelp as farp_prq_xrelp)                 as PaytReqIsReleasedForPayment,
      cast(payrq.xreve as farp_prq_xreve)                 as IsReversed,
      payrq.stgrd                                         as ReversalReason,
      cast(payrq.dtaws as farp_bnk_com_dtaws)             as DataExchangeInstructionKey,
      cast(payrq.dtws1 as farp_dtat16)                    as DataExchangeInstruction1,
      cast(payrq.dtws2 as farp_dtat17)                    as DataExchangeInstruction2,
      cast(payrq.dtws3 as farp_dtat18)                    as DataExchangeInstruction3,
      cast(payrq.dtws4 as farp_dtat19)                    as DataExchangeInstruction4,
      cast(payrq.post_date as farp_prq_postdate)          as PaymentRequestPostingDate,
      payrq.ubnks                                         as BankCountry,
      payrq.ubnky                                         as BankInternalID,
      payrq.land1                                         as SupplierCountry, //??

      payrq.landl                                         as SupplyingCountry,
      cast(payrq.origin as farp_fibl_origin)              as PaymentRequestOrigin,
      cast(payrq.lzbkz  as farp_prq_lzbkz)                as StateCentralBankPaymentReason,
      cast(payrq.cpudt  as farp_cpudt)                    as AccountingDocumentCreationDate,
      cast('000000'     as ttet_dt_cr_time)               as CreationTime,
      stcd1                                               as TaxID1,
      cast(payrq.augbl  as fis_augbl)                     as ClearingAccountingDocument,
      payrq.augdt                                         as ClearingDate,
      cast(payrq.bvtyp  as farp_bnk_com_bvtyp)            as BPBankAccountInternalID,

      cast(
      case
        when payrq.xreve = 'X' then 'I0559' //Reversed

        when payrq.augbl != '' and payrq.xreve = '' then 'IBC26' //Cleared

        when payrq.xrelp = 'X' then 'I0002'  //Released

        when payrq.xreld = 'X'  then 'ICL08 ' //Posted

        when payrq.xreld != 'X' then 'I0001' //Created

        else ''
      end as farp_payrq_status)                           as StatusCode,

      payrq.zanre                                         as PayeeTitle,
      payrq.zpstl                                         as PayeePostalCode,
      payrq.zpfac                                         as PayeePOBox,
      payrq.pstl2                                         as POBoxPostalCode,
      cast(payrq.znme2 as farp_dznme2)                    as PayeeAdditionalName2,
      cast(payrq.znme3 as farp_dznme3)                    as PayeeAdditionalName3,
      cast(payrq.znme4 as farp_dznme4)                    as PayeeAdditionalName4,
      cast(payrq.zort1 as farp_dzort1)                    as PayeeCityName,
      cast(payrq.zstra as farp_dzstra)                    as PayeeStreet,
      cast(payrq.zland as farp_dzland)                    as PayeeCountry,
      cast(payrq.zregi as farp_prq_dzregi)                as PayeeRegion,
      cast(payrq.zspra as farp_prq_dzspra)                as PayeeLanguage,
      cast(payrq.ztlfx as farp_telfx)                     as PayeeFaxNumber,
      cast(payrq.ztelf as farp_telf1)                     as PayeeTelephoneNumber,
      payrq.ziban                                         as PayeeIBAN,
      cast(payrq.rfttrn as farp_repetitive_code)          as PaymentRepetitiveCode,
      payrq.rel_date                                      as ReleaseDate,
      
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PaymentRequestReleasedByUser'
      payrq.rel_name                                      as ReleasedByUser,
      payrq.rel_name                                      as PaymentRequestReleasedByUser,
      payrq.post_name                                     as PostingCreatedByUser,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      payrq.dmbe2                                         as AmountInAdditionalCurrency1,
      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'      
      payrq.hwae2                                         as AdditionalCurrency1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      payrq.dmbe3                                         as AmountInAdditionalCurrency2,
      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      payrq.hwae3                                         as AdditionalCurrency2,
      @ObjectModel.foreignKey.association: '_PaymentReason'
      cast(payrq.payt_rsn as farp_payt_rsn preserving type ) as PaymentReason,
      
      payrq.zpayment_system                               as PayeePaymentSystem,
      payrq.zalias_type                                   as PayeeAliasType,
      payrq.zbank_alias                                   as PayeeAliasName,
            
      // I_Bank deprecated - use I_Bank_2 instead

      
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_PayeeBank2' 
      _PayeeBank,
      _PayeeBank2,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_Bank2' 
      _Bank,
      _Bank2,
      _HouseBankAccount,
      _BusinessAreaText,
      _CompanyCode,
      _PayingCompanyCode,
      _PaymentRequestCurrency,
      _CompanyCodeCurrency,
      _AdditionalCurrency1,
      _AdditionalCurrency2,
      _DataExchangeInstructionKeys,
      _PaymentMethod,
      _PaytReqChangeAndPost,
      _SystemStatusText,
      _ReversalReason,
      _CalendarDateForCompanyCode,
      _PaymentReason,
      _PayeePaymentSystem,
      _PayeeAliasType,
      _CreatedBy,
      _PostedBy,
      _ReleasedBy,
      _CurrencyText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PAYRQ"
],
"ASSOCIATED":
[
"I_ALIASTYPE",
"I_BANK",
"I_BANK_2",
"I_BUSINESSAREATEXT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_DATAEXCHANGEINSTRUCTIONKEYS",
"I_FISCALYEARFORCOMPANYCODE",
"I_HOUSEBANKACCOUNT",
"I_PAYMENTMETHOD",
"I_PAYMENTREASON",
"I_PAYMENTSYSTEM",
"I_PAYTREQCHGANDPOSTINGDATA",
"I_REVERSALREASON",
"I_SYSTEMSTATUSTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/