R_PaymentRequestTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.semanticKey: ['PaymentRequest']
@ObjectModel.sapObjectNodeType.name: 'PaymentRequest'

@AbapCatalog.extensibility.extensible: true
@AbapCatalog.extensibility.dataSources: ['_Extension']
@AbapCatalog.extensibility.elementSuffix: 'PRQ'
@AbapCatalog.extensibility.quota: {
  maximumFields: 408,  //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

  maximumBytes: 4080 } //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>


@EndUserText.label: 'Payment Request'
define root view entity R_PaymentRequestTP
  as select from           I_PaymentRequest          as PaymentRequest

    left outer to one join I_OperationalAcctgDocItem as _AccountingDocItem002 on  _AccountingDocItem002.CompanyCode            = PaymentRequest.CompanyCode
                                                                              and _AccountingDocItem002.AccountingDocument     = PaymentRequest.AccountingDocument
                                                                              and _AccountingDocItem002.FiscalYear             = PaymentRequest.FiscalYear
                                                                              and _AccountingDocItem002.AccountingDocumentItem = '002'

  association [1..1] to I_Customer                     as _Customer                on  $projection.Customer = _Customer.Customer
  association [1..1] to I_Supplier                     as _Supplier                on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_UserContactCard              as _ChangedBy               on  $projection.lastchangedbyuser = _ChangedBy.ContactCardID

  association [1..1] to P_PFFPCustomerSupplierBankType as _BankType                on  $projection.PaymentRequest = _BankType.PaymentRequest

  association [0..1] to I_PaymentBatchPaymentDocument  as _BatchDocument           on  $projection.ClearingAccountingDocument = _BatchDocument.PaymentDocument
                                                                                   and $projection.PayingCompanyCode          = _BatchDocument.PayingCompanyCode
                                                                                   and $projection.ClearingFiscalYear         = _BatchDocument.FiscalYear
  association [1..*] to I_PaymentRequestStatusText     as _PaymentRequestStatusText on  $projection.PaymentRequestStatus = _PaymentRequestStatusText.PaymentRequestStatus

  association [1..1] to E_PaymentRequest               as _Extension               on  $projection.PaymentRequest = _Extension.PaymentRequest

{
  key PaymentRequest.PaymentRequest,
      PaymentRequest.StatusCode                               as PaymentRequestStatus,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      PaymentRequest.CompanyCode,
      PaymentRequest.BusinessArea,
      PaymentRequest.AccountingDocumentCreationDate,
      PaymentRequest.AccountingDocument,
      PaymentRequest.FiscalYear,
      PaymentRequest.ClearingAccountingDocument,
      PaymentRequest.ClearingDate,
      PaymentRequest._CalendarDateForCompanyCode.FiscalYear   as ClearingFiscalYear,

      cast(
        case
          when (    _AccountingDocItem002.FinancialAccountType is null
                and PaymentRequest._PaytReqChangeAndPost.FinancialAccountType = 'D' )
            then PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount

          when _AccountingDocItem002.FinancialAccountType = 'D'
            then _AccountingDocItem002.Customer

          else ''
      end as farp_customer_id)                                as Customer,

      cast(
        case
          when (    _AccountingDocItem002.FinancialAccountType is null
                and PaymentRequest._PaytReqChangeAndPost.FinancialAccountType = 'K' )
            then PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount

          when _AccountingDocItem002.FinancialAccountType = 'K'
            then _AccountingDocItem002.Supplier

          else ''
      end as farp_supplier_id)                                as Supplier,

      cast( _BankType.PaymentRequestType as farp_payrq_type ) as PaymentRequestType,
      _BankType.CustomerBankType,
      _BankType.SupplierBankType,
      PaymentRequest.PayingCompanyCode,
      PaymentRequest.HouseBank,
      PaymentRequest.BankInternalID,
      PaymentRequest.HouseBankAccount,

      @Semantics.amount.currencyCode: 'PaymentRequestCurrency'
      PaymentRequest.PaymentRequestAmountInPaytCrcy,
      PaymentRequest.PaymentRequestCurrency,
      PaymentRequest.PaymentRequestPostingDate,
      PaymentRequest.PaymentMethod                            as ConsideredPaymentMethods,
      PaymentRequest.PaymentMethodSupplement,
      PaymentRequest.PaymentReason,
      PaymentRequest.PaymentRepetitiveCode,
      PaymentRequest.PayeeAliasType,
      PaymentRequest.PayeeAliasName,
      PaymentRequest.PayeePaymentSystem,
      PaymentRequest.PaymentRequestOrigin,

      cast(
        case
          when _AccountingDocItem002.FinancialAccountType is null
              then PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount
          when _AccountingDocItem002.FinancialAccountType = 'D'
              then _AccountingDocItem002.Customer
          when _AccountingDocItem002.FinancialAccountType = 'K'
              then _AccountingDocItem002.Supplier
          when _AccountingDocItem002.FinancialAccountType = 'S'
              then _AccountingDocItem002.GLAccount
          else ''
      end as farp_account_apar)                               as CustomerSupplierAccount,

      case
        when _AccountingDocItem002.DocumentItemText is null
          then PaymentRequest._PaytReqChangeAndPost.DocumentItemText
        else _AccountingDocItem002.DocumentItemText
      end                                                     as DocumentItemText,

      cast(
        case
          when _AccountingDocItem002.FinancialAccountType is null
            then PaymentRequest._PaytReqChangeAndPost.FinancialAccountType
          else _AccountingDocItem002.FinancialAccountType
      end as financialaccounttype)                            as FinancialAccountType,

      cast(
        case
          when _AccountingDocItem002.FinancialAccountType is null
            then PaymentRequest._PaytReqChangeAndPost._FinancialAccountType._Text[1:Language = $session.system_language].FinancialAccountTypeName
          else _AccountingDocItem002._FinancialAccountType._Text[1:Language = $session.system_language].FinancialAccountTypeName
      end as farp_fin_acc_type_name)                          as FinancialAccountTypeName,

      PaymentRequest.GLAccount,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PaymentRequest.PaymentRequestAmountInCCCrcy,
      PaymentRequest.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      PaymentRequest.AmountInAdditionalCurrency1,
      PaymentRequest.AdditionalCurrency1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      PaymentRequest.AmountInAdditionalCurrency2,
      PaymentRequest.AdditionalCurrency2,

      //      PaymentRequest.BankChain,

      PaymentRequest.BankCountry,
      PaymentRequest.DataExchangeInstructionKey,
      PaymentRequest.DataExchangeInstruction1,
      PaymentRequest.DataExchangeInstruction2,
      PaymentRequest.DataExchangeInstruction3,
      PaymentRequest.DataExchangeInstruction4,
      PaymentRequest.StateCentralBankPaymentReason,
      PaymentRequest.PayeeName,
      PaymentRequest.PayeeBank,
      PaymentRequest.PayeeBankCountry,
      PaymentRequest.PayeeBankInternalID,
      PaymentRequest.PayeeBankAccount,
      PaymentRequest.PayeeBankControlKey,
      PaymentRequest._PaytReqChangeAndPost.BankChain,
      PaymentRequest.BankAccountHolderName,
      PaymentRequest.BankDetailReference,
      PaymentRequest.ReferenceTypeText,
      PaymentRequest.IsSinglePayment,
      PaymentRequest.PayeeTitle,
      PaymentRequest.PayeePostalCode,
      PaymentRequest.PayeePOBox,
      PaymentRequest.POBoxPostalCode,
      PaymentRequest.PayeeAdditionalName2,
      PaymentRequest.PayeeAdditionalName3,
      PaymentRequest.PayeeAdditionalName4,
      PaymentRequest.PayeeCityName,
      PaymentRequest.PayeeStreet,
      PaymentRequest.PayeeCountry,
      PaymentRequest.PayeeRegion,
      PaymentRequest.PayeeLanguage,
      PaymentRequest.PayeeFaxNumber,
      PaymentRequest.PayeeTelephoneNumber,
      PaymentRequest.PayeeIBAN,
      PaymentRequest.PaymentReference,
      PaymentRequest.PaytReqIsReleasedForPosting,
      PaymentRequest.PaytReqIsCompleted,
      PaymentRequest.PaytReqIsReleasedForPayment,
      PaymentRequest.IsReversed,
      PaymentRequest.ReversalReason,
      PaymentRequest.CreatedByUser,
      PaymentRequest.PaymentRequestReleasedByUser,
      PaymentRequest.ReleaseDate,
      PaymentRequest.PostingCreatedByUser,
      PaymentRequest._PaytReqChangeAndPost.LastChangedByUser,
      PaymentRequest.SupplyingCountry,
      PaymentRequest.TaxID1,
      PaymentRequest.ValueDate,

      @Semantics.booleanIndicator: true
      cast ('' as abap_boolean)                               as BankAliasEntryIsSelected,
      cast ('' as fibl_opvar)                                 as PaymentRequestVariant,

      cast (
        case tims_is_valid(PaymentRequest._PaytReqChangeAndPost.CreationTime)
          when 1 then dats_tims_to_tstmp( PaymentRequest.AccountingDocumentCreationDate, PaymentRequest._PaytReqChangeAndPost.CreationTime,
                                     abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
          else dats_tims_to_tstmp( PaymentRequest.AccountingDocumentCreationDate, PaymentRequest.CreationTime,
                                     abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
       end as farp_prq_cr_date )                              as CreationDateTime,

      @Semantics.systemDateTime.lastChangedAt: true
      cast( dats_tims_to_tstmp( PaymentRequest._PaytReqChangeAndPost.LastChangeDate,
                         PaymentRequest._PaytReqChangeAndPost.LastChangeTime,
                         abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
                                 as farp_prq_chg_date )       as LastChangeDateTime,

      _Customer,
      _Supplier,
      _ChangedBy,
      _BatchDocument,
      _PaymentRequestStatusText,
      PaymentRequest._CreatedBy,
      PaymentRequest._PostedBy,
      PaymentRequest._ReleasedBy,
      PaymentRequest._CurrencyText,
      PaymentRequest._PaytReqChangeAndPost,
      PaymentRequest._BusinessAreaText,
      PaymentRequest._CompanyCode,
      PaymentRequest._PayingCompanyCode,
      PaymentRequest._Bank2,
      PaymentRequest._PaymentReason,
      PaymentRequest._DataExchangeInstructionKeys,
      PaymentRequest._SystemStatusText,
      PaymentRequest._HouseBankAccount,
      PaymentRequest._PayeeBank2,
      PaymentRequest._PayeePaymentSystem,
      PaymentRequest._PaymentMethod,
      PaymentRequest._PayeeAliasType
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALACCOUNTTYPETEXT",
"I_FISCALYEARFORCOMPANYCODE",
"I_OPERATIONALACCTGDOCITEM",
"I_PAYMENTREQUEST",
"I_PAYTREQCHGANDPOSTINGDATA",
"P_PFFPCUSTOMERSUPPLIERBANKTYPE"
],
"ASSOCIATED":
[
"I_ALIASTYPE",
"I_BANK_2",
"I_BUSINESSAREATEXT",
"I_COMPANYCODE",
"I_CURRENCYTEXT",
"I_CUSTOMER",
"I_DATAEXCHANGEINSTRUCTIONKEYS",
"I_HOUSEBANKACCOUNT",
"I_PAYMENTBATCHPAYMENTDOCUMENT",
"I_PAYMENTMETHOD",
"I_PAYMENTREASON",
"I_PAYMENTREQUESTSTATUSTEXT",
"I_PAYMENTSYSTEM",
"I_PAYTREQCHGANDPOSTINGDATA",
"I_SUPPLIER",
"I_SYSTEMSTATUSTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_PAYMENTREQUEST"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/