I_CABILLGDOCHEADER
Abrechnungsbelegkopf
I_CABILLGDOCHEADER is a CDS View in S/4HANA. Abrechnungsbelegkopf. It contains 53 fields. 7 CDS views read from this table.
CDS Views using this table (7)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_BSQPMContrAcctgBillgDocument | view_entity | from | CONSUMPTION | CA Billing Document Attribute |
| C_CABillgDocHeader | view | from | CONSUMPTION | Abrechnungsbelegkopf anzeigen |
| C_CABillgDocVH | view | from | CONSUMPTION | Wertehilfe Abrechnungsbeleg |
| C_CAInvcgOvwBillgDocHeader | view | from | CONSUMPTION | Abrechnungsbelegkopf anzeigen |
| CRMS4_IU_I_CBH | view_entity | from | Convergent Invoice Billing Doc. Header | |
| I_CABillPrntBillgDocHeader | view | from | COMPOSITE | Abrechnungsbelegkopf anzeigen |
| R_CABillgDocumentTP | view_entity | from | TRANSACTIONAL | Billing Document - TP |
Fields (53)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CABillgDocument | CABillgDocument | 3 |
| BusinessPartner | BusinessPartner | 4 | |
| CAAltvMDOriginalIsIncluded | CAAltvMDOriginalIsIncluded | 3 | |
| CAApplicationArea | CAApplicationArea | 3 | |
| CABillgAdjustedDocument | CABillgAdjustedDocument | 3 | |
| CABillgAdjustmentDocument | CABillgAdjustmentDocument | 3 | |
| CABillgBaseDate | CABillgBaseDate | 3 | |
| CABillgCurrency | CABillgCurrency | 3 | |
| CABillgDocCreationDate | BillingDate,CABillgDocCreationDate | 4 | |
| CABillgDocCreationTime | CABillgDocCreationTime | 3 | |
| CABillgDocHasPrepaidItems | CABillgDocHasPrepaidItems | 3 | |
| CABillgDocHasRefillItems | CABillgDocHasRefillItems | 3 | |
| CABillgDocHasRefObjects | CABillgDocHasRefObjects | 3 | |
| CABillgDocHasRevnRecgnItems | CABillgDocHasRevnRecgnItems | 3 | |
| CABillgDocInternalNumber | CABillgDocInternalNumber | 3 | |
| CABillgDocOriginProcess | CABillgDocOriginProcess | 3 | |
| CABillgDocPeriodEndDate | CABillgDocPeriodEndDate | 3 | |
| CABillgDocPeriodStartDate | CABillgDocPeriodStartDate | 3 | |
| CABillgDocumentExternal | CABillgDocumentExternal | 3 | |
| CABillgDocumentInvcgStatus | CABillgDocumentInvcgStatus | 3 | |
| CABillgDocumentNumberOfItems | CABillgDocumentNumberOfItems | 3 | |
| CABillgDocumentReversalReason | CABillgDocumentReversalReason | 3 | |
| CABillgGrpgOfAdditionalItems | CABillgGrpgOfAdditionalItems | 3 | |
| CABillgHasAdditionalInvoice | CABillgHasAdditionalInvoice | 3 | |
| CABillgIsDocumentSimulated | CABillgIsDocumentSimulated | 3 | |
| CABillgLockedForInvoicing | CABillgLockedForInvoicing | 3 | |
| CABillgProcess | CABillgProcess | 3 | |
| CABillgReversalDocument | CABillgReversalDocument | 3 | |
| CABillgReversedDocument | CABillgReversedDocument | 3 | |
| CABillgType | CABillgType | 3 | |
| CAInvcgAltvBusinessPartner | CAInvcgAltvBusinessPartner | 3 | |
| CAInvcgAltvContractAccount | CAInvcgAltvContractAccount | 3 | |
| CAInvcgCategory | CAInvcgCategory | 3 | |
| CAInvcgControlOfInvoicingUnit | CAInvcgControlOfInvoicingUnit | 3 | |
| CAInvcgCorrectionCategory | CAInvcgCorrectionCategory | 3 | |
| CAInvcgCreationDate | CAInvcgCreationDate | 3 | |
| CAInvcgCurrency | CAInvcgCurrency | 3 | |
| CAInvcgDocumentType | CAInvcgDocumentType | 3 | |
| CAInvcgFirstDate | CAInvcgFirstDate | 3 | |
| CAInvcgIsAccrualPostingRlvt | CAInvcgIsAccrualPostingRlvt | 2 | |
| CaInvcgIsOrderDeleted | CaInvcgIsOrderDeleted | 3 | |
| CAInvcgMasterDataType | CAInvcgMasterDataType | 3 | |
| CAInvcgSourceDocumentType | CAInvcgSourceDocumentType | 3 | |
| CAInvcgTargetProcess | CAInvcgTargetProcess | 3 | |
| CAInvcgTechnicalDocumentType | CAInvcgTechnicalDocumentType | 3 | |
| CAInvoicingDocument | CAInvoicingDocument | 2 | |
| CAPartnerSettlementRule | CAPartnerSettlementRule | 3 | |
| CASubAreaForParallelization | CASubAreaForParallelization | 3 | |
| CATaxDateType | CATaxDateType | 3 | |
| CATaxDetnType | CATaxDetnType | 3 | |
| ContractAccount | ContractAccount | 3 | |
| CreatedByUser | CreatedByUser | 3 | |
| LogicalSystem | LogicalSystem | 3 |
@AbapCatalog.sqlViewName: 'ICAINVBILL_H'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
usageType: {
serviceQuality: #B,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
},
representativeKey: 'CABillgDocument',
supportedCapabilities: [
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET
]
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Abrechnungsbelegkopf'
define view I_CABillgDocHeader
as select from dfkkinvbill_h as invbill_h
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_ContractAccountHeader as _ContractAccountHeader on $projection.ContractAccount = _ContractAccountHeader.ContractAccount
association [0..1] to I_BusinessPartner as _CAInvcgAltvBusinessPartner on $projection.CAInvcgAltvBusinessPartner = _CAInvcgAltvBusinessPartner.BusinessPartner
association [0..1] to I_ContractAccountHeader as _CAInvcgAltvContractAccount on $projection.CAInvcgAltvContractAccount = _CAInvcgAltvContractAccount.ContractAccount
association [0..1] to I_ContractAccountPartner as _ContractAccountPartner on $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
and $projection.ContractAccount = _ContractAccountPartner.ContractAccount
association [0..1] to I_Currency as _CABillgCurrency on $projection.CABillgCurrency = _CABillgCurrency.Currency
association [0..1] to I_Currency as _CAInvcgCurrency on $projection.CAInvcgCurrency = _CAInvcgCurrency.Currency
association [0..1] to I_CABillgDocHeader as _CABillgReversalDocument on $projection.CABillgReversalDocument = _CABillgReversalDocument.CABillgDocument
association [0..1] to I_CABillgDocHeader as _CABillgReversedDocument on $projection.CABillgReversedDocument = _CABillgReversedDocument.CABillgDocument
association [0..1] to I_CABillgDocHeader as _CABillgAdjustmentDocument on $projection.CABillgAdjustmentDocument = _CABillgAdjustmentDocument.CABillgDocument
association [0..1] to I_CABillgDocHeader as _CABillgAdjustedDocument on $projection.CABillgAdjustedDocument = _CABillgAdjustedDocument.CABillgDocument
association [0..1] to I_CABillgDocOriginProcess as _CABillgDocOriginProcess on $projection.CABillgDocOriginProcess = _CABillgDocOriginProcess.CABillgDocOriginProcess
association [0..1] to I_CAInvcgTargetProc as _CAInvcgTargetProc on $projection.CAInvcgTargetProcess = _CAInvcgTargetProc.CAInvcgTargetProcess
association [0..1] to I_CAInvcgCategory as _CAInvcgCategory on $projection.CAInvcgCategory = _CAInvcgCategory.CAInvcgCategory
association [0..1] to I_CABillgProcess as _CABillgProcess on $projection.CABillgProcess = _CABillgProcess.CABillgProcess
association [0..1] to I_CABillgType as _CABillgType on $projection.CABillgType = _CABillgType.CABillgType
association [0..1] to I_CAApplicationArea as _CAApplicationArea on $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
association [0..1] to I_CAInvcgSourceDocType as _CAInvcgSourceDocType on _CAInvcgSourceDocType.CAInvcgSourceDocumentCat = 'INVBI'
and $projection.CAInvcgSourceDocumentType = _CAInvcgSourceDocType.CAInvcgSourceDocumentType
association [0..1] to I_CAInvcgDocumentType as _CAInvcgDocumentType on $projection.CAInvcgDocumentType = _CAInvcgDocumentType.CAInvcgDocumentType
and $projection.CAApplicationArea = _CAInvcgDocumentType.CAApplicationArea
and _CAInvcgDocumentType.NameNumberRangeObject = 'FKKINVBILL'
association [0..1] to I_CAInvcgDocTechDocType as _CAInvcgDocTechDocType on $projection.CAInvcgTechnicalDocumentType = _CAInvcgDocTechDocType.CAInvcgTechnicalDocumentType
association [0..1] to I_CABillgDocReversalReason as _CABillgDocReversalReason on $projection.CABillgDocumentReversalReason = _CABillgDocReversalReason.CABillgDocumentReversalReason
association [0..1] to I_CAInvcgMasterDataType as _CAInvcgMasterDataType on $projection.CAInvcgMasterDataType = _CAInvcgMasterDataType.CAInvcgMasterDataType
association [0..1] to I_CATaxDetnType as _CATaxDetnType on $projection.CATaxDetnType = _CATaxDetnType.CATaxDetnType
association [0..1] to I_CATaxDateType as _CATaxDateType on $projection.CATaxDateType = _CATaxDateType.CATaxDateType
association [0..1] to I_CAInvcgControlOfInvcgUnit as _CAInvcgControlOfInvcgUnit on $projection.CAInvcgControlOfInvoicingUnit = _CAInvcgControlOfInvcgUnit.CAInvcgControlOfInvoicingUnit
association [0..1] to I_CAInvcgCorrectionCat as _CAInvcgCorrectionCat on $projection.CAInvcgCorrectionCategory = _CAInvcgCorrectionCat.CAInvcgCorrectionCategory
association [0..1] to I_CABillgExistsAddInvcg as _CABillgExistsAddInvcg on $projection.CABillgHasAdditionalInvoice = _CABillgExistsAddInvcg.CABillgHasAdditionalInvoice
association [0..1] to I_CABillgLockedForInvcg as _CABillgLockedForInvcg on $projection.CABillgLockedForInvoicing = _CABillgLockedForInvcg.CABillgLockedForInvoicing
association [0..1] to I_CABillgDocInvcgStatus as _CABillgDocInvcgStatus on $projection.CABillgDocumentInvcgStatus = _CABillgDocInvcgStatus.CABillgDocumentInvcgStatus
association [0..1] to I_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
// extension
//association [0..1] to E_CABillgDocHeader as _Extension on $projection.CABillgDocument = _Extension.CABillgDocument
{
@EndUserText.label: 'Abrechnungsbeleg'
key billdocno as CABillgDocument,
@ObjectModel.foreignKey.association: '_BusinessPartner'
gpart as BusinessPartner,
@ObjectModel.foreignKey.association: '_ContractAccountHeader'
vkont as ContractAccount,
@ObjectModel.foreignKey.association: '_CABillgType'
bill_type as CABillgType,
cast(date_from as bill_period_from_gfn_kk preserving type ) as CABillgDocPeriodStartDate,
cast(date_to as bill_period_to_gfn_kk preserving type ) as CABillgDocPeriodEndDate,
@ObjectModel.foreignKey.association: '_CABillgDocReversalReason'
revreason as CABillgDocumentReversalReason,
simulated as CABillgIsDocumentSimulated,
cast(refdocno as refdocno_gfn_kk preserving type ) as CABillgDocumentExternal,
log_system as LogicalSystem,
@ObjectModel.foreignKey.association: '_CAApplicationArea'
applk as CAApplicationArea,
@ObjectModel.foreignKey.association: '_CABillgDocOriginProcess'
srcprocess as CABillgDocOriginProcess,
@ObjectModel.foreignKey.association: '_CAInvcgSourceDocType'
srcdoctype as CAInvcgSourceDocumentType,
@ObjectModel.foreignKey.association: '_CAInvcgDocTechDocType'
cast(techdoctype as techdoctype_gfn_kk preserving type ) as CAInvcgTechnicalDocumentType,
@ObjectModel.foreignKey.association: '_CAInvcgDocumentType'
doctype as CAInvcgDocumentType,
@ObjectModel.foreignKey.association: '_CAInvcgTargetProc'
targprocess as CAInvcgTargetProcess,
@ObjectModel.foreignKey.association: '_CAInvcgMasterDataType'
mdcat as CAInvcgMasterDataType,
@ObjectModel.foreignKey.association: '_CAInvcgAltvBusinessPartner'
cast(gpart_inv as gpart_inv_gfn_kk preserving type ) as CAInvcgAltvBusinessPartner,
@ObjectModel.foreignKey.association: '_CAInvcgAltvContractAccount'
cast(vkont_inv as vkont_inv_gfn_kk preserving type ) as CAInvcgAltvContractAccount,
bill_basedate as CABillgBaseDate,
@ObjectModel.foreignKey.association: '_CABillgCurrency'
bill_curr as CABillgCurrency,
@ObjectModel.foreignKey.association: '_CAInvcgCurrency'
cast(inv_curr as inv_curr_gfn_kk preserving type ) as CAInvcgCurrency,
@ObjectModel.foreignKey.association: '_CATaxDetnType'
tax_det_type as CATaxDetnType,
@ObjectModel.foreignKey.association: '_CATaxDateType'
tax_date_type as CATaxDateType,
@ObjectModel.foreignKey.association: '_CAInvcgCategory'
inv_category as CAInvcgCategory,
cast(separate_inv as separate_inv_bitpack_gfn_kk preserving type ) as CAInvcgControlOfInvoicingUnit,
invoice_first as CAInvcgFirstDate,
@ObjectModel.foreignKey.association: '_CABillgReversalDocument'
cast(reversaldoc as reversalbilldoc_gfn_kk preserving type ) as CABillgReversalDocument,
@ObjectModel.foreignKey.association: '_CABillgReversedDocument'
cast(reverseddoc as reversedbilldoc_gfn_kk preserving type ) as CABillgReversedDocument,
@ObjectModel.foreignKey.association: '_CABillgAdjustmentDocument'
cast(adjustmentdoc as adjustmentbilldoc_gfn_kk preserving type ) as CABillgAdjustmentDocument,
@ObjectModel.foreignKey.association: '_CABillgAdjustedDocument'
adjusteddoc as CABillgAdjustedDocument,
@ObjectModel.foreignKey.association: '_CAInvcgCorrectionCat'
cast(corrcat as corrcat_gfn_kk preserving type ) as CAInvcgCorrectionCategory,
cast(trigdeleted as trigdeleted_gfn_kk preserving type ) as CaInvcgIsOrderDeleted,
xinfbill as CABillgHasAdditionalInvoice,
cast(xbillac as xbillac_gfn_kk preserving type ) as CAInvcgIsAccrualPostingRlvt,
@ObjectModel.foreignKey.association: '_CABillgLockedForInvcg'
invlock as CABillgLockedForInvoicing,
cast(add_group as add_group_gfn_kk preserving type ) as CABillgGrpgOfAdditionalItems,
cast(xinvbill_x as xinvbill_x_gfn_kk preserving type ) as CABillgDocHasRefObjects,
recnum as CABillgDocumentNumberOfItems,
@Semantics.user.createdBy: true
crname as CreatedByUser,
@Semantics.systemDate.createdAt: true
crdate as CABillgDocCreationDate,
@Semantics.systemTime.createdAt: true
crtime as CABillgDocCreationTime,
cast(billrunno as billrunno_gfn_kk preserving type ) as CABillgDocInternalNumber,
@ObjectModel.foreignKey.association: '_CABillgProcess'
bill_process as CABillgProcess,
prepaid_incl as CABillgDocHasPrepaidItems,
pprefill_incl as CABillgDocHasRefillItems,
revrec_incl as CABillgDocHasRevnRecgnItems,
ptsrl as CAPartnerSettlementRule,
@ObjectModel.foreignKey.association: '_CABillgDocInvcgStatus'
invstatus as CABillgDocumentInvcgStatus,
@ObjectModel.foreignKey.association: '_CAInvcgDocHeader'
invdocno as CAInvoicingDocument,
invcrdate as CAInvcgCreationDate,
keypp as CASubAreaForParallelization,
altmd_orig_incl as CAAltvMDOriginalIsIncluded,
// Make association public
_ContractAccountPartner,
_BusinessPartner,
_ContractAccountHeader,
_CAInvcgAltvBusinessPartner,
_CAInvcgAltvContractAccount,
_CABillgReversalDocument,
_CABillgReversedDocument,
_CABillgAdjustedDocument,
_CABillgAdjustmentDocument,
_CAApplicationArea,
_CABillgCurrency,
_CAInvcgCurrency,
_CABillgDocOriginProcess,
_CAInvcgSourceDocType,
_CAInvcgTargetProc,
_CAInvcgCategory,
_CABillgProcess,
_CABillgType,
_CAInvcgDocTechDocType,
_CAInvcgMasterDataType,
_CATaxDetnType,
_CATaxDateType,
_CAInvcgDocumentType,
_CAInvcgControlOfInvcgUnit,
_CAInvcgCorrectionCat,
_CABillgExistsAddInvcg,
_CABillgLockedForInvcg,
_CABillgDocInvcgStatus,
_CABillgDocReversalReason,
_CAInvcgDocHeader
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKKINVBILL_H"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CABILLGDOCINVCGSTATUS",
"I_CABILLGDOCORIGINPROCESS",
"I_CABILLGDOCREVERSALREASON",
"I_CABILLGEXISTSADDINVCG",
"I_CABILLGLOCKEDFORINVCG",
"I_CABILLGPROCESS",
"I_CABILLGTYPE",
"I_CAINVCGCATEGORY",
"I_CAINVCGCONTROLOFINVCGUNIT",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGDOCHEADER",
"I_CAINVCGDOCTECHDOCTYPE",
"I_CAINVCGDOCUMENTTYPE",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGSOURCEDOCTYPE",
"I_CAINVCGTARGETPROC",
"I_CATAXDATETYPE",
"I_CATAXDETNTYPE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/