I_BUSINESSPARTNERBANK
Business Partner Bank
I_BUSINESSPARTNERBANK is a CDS View in S/4HANA. Business Partner Bank. It contains 21 fields. 8 CDS views read from this table.
CDS Views using this table (8)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| /PF1/I_BP_ACCOUNT | view_entity | from | BP Account ID | |
| A_BusinessPartnerBank | view | from | BASIC | Bank |
| C_InsurClmPaytBankVH | view_entity | from | CONSUMPTION | Value Help for Claim Payment Bank ID |
| C_NL_SAFTBusPartnerBankAcct | view | inner | CONSUMPTION | SAFT NL Business Partner Bank Accounts |
| I_BankChainBankDetail | view_entity | from | BASIC | Supplier and Customer Bank Detail |
| I_BusinessPartnerBankTP | view | from | TRANSACTIONAL | Association View for bank details |
| I_WorkForcePersonPayt | view | left_outer | COMPOSITE | Workforce Person Payment Details for Object Page |
| P_BusinessPartnerBank | view | from | COMPOSITE |
Fields (21)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BankIdentification | BankIdentification,BankIdentificationForEdit | 4 |
| KEY | BusinessPartner | BusinessPartner,BusinessPartnerForEdit | 3 |
| _BusinessPartner | _BusinessPartner | 1 | |
| BankAccount | BankAccount | 3 | |
| BankAccountHolderName | BankAccountHolderName | 3 | |
| BankAccountName | BankAccountName | 3 | |
| BankAccountReferenceText | BankAccountReferenceText,BankReference | 3 | |
| BankControlKey | BankControlKey | 3 | |
| BankCountryKey | BankCountryKey | 3 | |
| BankName | BankName | 2 | |
| BankNumber | Bank,BankNumber | 3 | |
| BPBankDetailsChangeDate | BPBankDetailsChangeDate | 1 | |
| BPBankDetailsChangeTargetID | BPBankDetailsChangeTargetID | 1 | |
| BPBankIsProtected | BPBankIsProtected | 3 | |
| BusinessPartnerExternalBankID | BusinessPartnerExternalBankID | 1 | |
| CollectionAuthInd | CollectionAuthInd | 2 | |
| IBAN | IBAN | 3 | |
| IBANValidityStartDate | IBANValidityStartDate | 1 | |
| SWIFTCode | SWIFTCode | 2 | |
| ValidityEndDate | ValidityEndDate | 2 | |
| ValidityStartDate | ValidityStartDate | 2 |
@AbapCatalog.sqlViewName: 'IBUPABANK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: '_BusinessPartner.IsBusinessPurposeCompleted'
//@Analytics: {
// dataCategory: #DIMENSION,
// dataExtraction: {
// enabled: true,
// delta.changeDataCapture: {
// automatic: true
// }
// }
//}
@Analytics: {
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
mapping:[
{
table: 'BUT0BK', role: #MAIN,
viewElement: ['BusinessPartner','BankIdentification'],
tableElement: ['partner','bkvid']
},
{
table: 'BUT000', role: #LEFT_OUTER_TO_ONE_JOIN,
viewElement: ['BusinessPartner'],
tableElement: ['partner']
},
{
table: 'BNKA', role: #LEFT_OUTER_TO_ONE_JOIN,
viewElement: ['BankCountryKey','BankNumber'],
tableElement: ['banks', 'bankl']
},
{
table: 'TIBAN', role: #LEFT_OUTER_TO_ONE_JOIN,
viewElement: ['BankCountryKey','BankNumber','BankAccount','BankControlKey'],
tableElement: ['banks', 'bankl','bankn', 'bkont']
}
]
}
}
}
@ObjectModel.representativeKey:'BankIdentification'
@VDM.viewType: #BASIC
@EndUserText.label: 'Business Partner Bank'// data'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET,
#EXTRACTION_DATA_SOURCE]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
define view I_BusinessPartnerBank
as select from but0bk as BusinessPartnerBank
association [1..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_Bank as _Bank on $projection.BankNumber = _Bank.BankInternalID
and $projection.BankCountryKey = _Bank.BankCountry
// association [1..1] to tiban as _IBAN on $projection.BankAccount = _IBAN.bankn
// and $projection.BankNumber = _IBAN.bankl
// and $projection.BankCountryKey = _IBAN.banks
// and $projection.BankControlKey = _IBAN.bkont
association [1..1] to I_Iban as _IBAN on $projection.BankAccount = _IBAN.BankAccount
and $projection.BankNumber = _IBAN.Bank
and $projection.BankCountryKey = _IBAN.BankCountry
and $projection.BankControlKey = _IBAN.BankControlKey
association [1..1] to I_BusinessPartnerBankAlias as _BusinessPartnerBankAlias on $projection.BPBankUUID = _BusinessPartnerBankAlias.BPBankUUID
{
@Search.defaultSearchElement: true
@ObjectModel.foreignKey.association: '_BusinessPartner'
key BusinessPartnerBank.partner as BusinessPartner,
@Search.defaultSearchElement: true
key BusinessPartnerBank.bkvid as BankIdentification,
BusinessPartnerBank.banks as BankCountryKey,
_Bank.BankName as BankName,
BusinessPartnerBank.bankl as BankNumber,
_Bank.SWIFTCode as SWIFTCode,
BusinessPartnerBank.bkont as BankControlKey,
BusinessPartnerBank.koinh as BankAccountHolderName,
BusinessPartnerBank.accname as BankAccountName,
BusinessPartnerBank.bk_valid_from as ValidityStartDate,
BusinessPartnerBank.bk_valid_to as ValidityEndDate,
//_IBAN.IBAN as IBAN,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'BPIsActualDate'
case
when BusinessPartnerBank.bk_valid_from <= tstmp_current_utctimestamp()
and BusinessPartnerBank.bk_valid_to >= tstmp_current_utctimestamp()
then cast('X' as boole_d)
else cast(' ' as boole_d)
end as IsActualDate,
case
when BusinessPartnerBank.bk_valid_from <= tstmp_current_utctimestamp()
and BusinessPartnerBank.bk_valid_to >= tstmp_current_utctimestamp()
then cast('X' as boole_d)
else cast(' ' as boole_d)
end as BPIsActualDate,
case
when BusinessPartnerBank.bankn <> ''
then _IBAN.IBAN
else
BusinessPartnerBank.iban
end as IBAN,
_IBAN.IBANValidityStartDate as IBANValidityStartDate,
BusinessPartnerBank.bankn as BankAccount,
BusinessPartnerBank.bkref as BankAccountReferenceText,
BusinessPartnerBank.xezer as CollectionAuthInd,
BusinessPartnerBank.bkext as BusinessPartnerExternalBankID,
BusinessPartnerBank.bk_move_date as BPBankDetailsChangeDate,
BusinessPartnerBank.move_bkvid as BPBankDetailsChangeTargetID,
BusinessPartnerBank.protect as BPBankIsProtected,
BusinessPartnerBank.bp_bank_guid as BPBankUUID,
_Bank.CityName as CityName,
_Bank,
_IBAN,
_BusinessPartner,
_BusinessPartnerBankAlias,
_BusinessPartner.AuthorizationGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK",
"I_BUSINESSPARTNER",
"I_IBAN",
"BUT0BK"
],
"ASSOCIATED":
[
"I_BANK",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERBANKALIAS",
"I_IBAN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/