I_BOOMATERIALASSIGNMENT

CDS View

Material assgmt. to Bill of Operations

I_BOOMATERIALASSIGNMENT is a CDS View in S/4HANA. Material assgmt. to Bill of Operations. It contains 5 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 5 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_ProductsByWorkCenter view left_outer CONSUMPTION Products by work center
I_BOOMaterialAssignmentStdVH view_entity from COMPOSITE Material assgmt. to Bill of Operations
I_BOOMaterialAssignmentVH view_entity from COMPOSITE Material Assignment to Bill of Operations
I_ChgRecdMstrRcpMatlAssgmt view from COMPOSITE Change Record Master Recipe Material
I_ChgRecdRefMstrRcpMatl view from COMPOSITE Change Record Master Rcp Mat assignment
I_MfgBOOMaterialAssignment view from BASIC Material Assignment to Manufacturing Bill of Operations
P_ProductsByWorkCenter view inner COMPOSITE

Fields (5)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup BillOfOperationsGroup 3
KEY BillOfOperationsType BillOfOperationsType 3
KEY BillOfOperationsVariant BillOfOperationsVariant 3
KEY Material Material,Product 3
KEY Plant Plant 1 
@AbapCatalog.sqlViewName: 'IBOOMATASSIGN'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOToMaterialInternalID'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Material assgmt. to Bill of Operations'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Search.searchable: true
@Metadata.allowExtensions:true
@AbapCatalog.preserveKey:true 

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view I_BOOMaterialAssignment
  as select distinct from mapl

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_BillOfOperations      as _BillOfOperations      on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                          and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_Plant                 as _Plant                 on  $projection.Plant = _Plant.Plant
  association [1..1] to I_Material              as _Material              on  $projection.Material = _Material.Material

{
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @ObjectModel.foreignKey.association: '_Material'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.matnr                    as   Material,
      @ObjectModel.foreignKey.association: '_Plant'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.werks                    as   Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key mapl.plnty                    as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.plnnr                    as   BillOfOperationsGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key mapl.plnal                    as   BillOfOperationsVariant,
  key mapl.zkriz                    as   BOOToMaterialInternalID,

      _Material,
      _Plant,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      // !! DO NOT USE @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]

      _BillOfOperations
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MAPL"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_MATERIAL",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More