I_ALLOCATIONCYCLE

@AbapCatalog.sqlViewName: 'ALLOCCYCLE'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Allocation Cycle'

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #BASIC
define view I_AllocationCycle
  as select from    t811c

    left outer join P_AllocationCycleChange as _Change on  t811c.tab   = _Change.AllocationType
                                                       and t811c.cycle = _Change.AllocationCycle
                                                       and t811c.sdate = _Change.AllocationCycleStartDate

  association [0..*] to I_AllocActualPlanVariantText as _ActualPlanText on  $projection.AllocationActualPlanVariant = _ActualPlanText.AllocationActualPlanVariant

  //  association [0..*] to I_DomainFixedValue as _AllocationPostingTypeText on _AllocationPostingTypeText.SAPDataDictionaryDomain   = 'FCO_ALLOCATION_ALART'

  //                                                                        and _AllocationPostingTypeText.DomainValue               = $projection.AllocationPostingType


  association [0..1] to I_AllocationContextType      as _Context        on  $projection.AllocationType = _Context.AllocationType
  association [0..1] to I_AllocAssmtDistrLongText    as _Text           on  $projection.AllocationType           = _Text.AllocationType
                                                                        and $projection.AllocationCycle          = _Text.AllocationCycle
                                                                        and $projection.AllocationCycleStartDate = _Text.AllocationCycleStartDate
                                                                        and _Text.LanguageCode                   = $session.system_language
                                                                        and _Text.AllocationCycleSegment         = '0000'

{
  key cast(tab as fco_allocation_context)             as AllocationType,
  key cycle                                           as AllocationCycle,
  key cast(sdate      as fco_alloc_valid_from)        as AllocationCycleStartDate,
      cast(edate      as fco_alloc_valid_to )         as AllocationCycleEndDate,
      rstatus                                         as AllocationStatus, //status new ? any other?

      freq                                            as AllocationFrequency,
      crdate                                          as AllocationCreateDate,
      cast(puser      as fco_tag_created_user)        as CreatedByUser,
      moddate                                         as LastChangeDate,
      cast(moduser    as fco_tag_changed_user)        as LastChangedByUser,
      cast(lastexec as fco_alloc_last_execute_data)   as AllocationLastExecutedDate,
      lexecby                                         as AllocationLastExecutedByUser,
      timeexec                                        as AllocationLastExecutionTime,
      iterflag                                        as AllocationIsProcessed,
      //astatus, //not used

      cycleset                                        as AllocationCycleSet,
      negtest                                         as ScaleNegativeTracingFactor,
      //cast(alart as fco_allocation_posting_type) as AllocationPostingType,

      cast(alart as fco_alloc_posting_type)           as AllocationPostingType,
      cast(ipknz as fco_alloc_ipknz )                 as AllocationActualPlanVariant,
      job                                             as AllocationJob, //job???

      kumuflag                                        as AllocationIsCumulative,
      xxkumuflag                                      as AllocIsCumulativeOptimized,
      rckumuflag                                      as AllocHasAggregatedProcess,
      proc_group                                      as AllocationCycleRunGroup,
      substid                                         as AllocationSubstitutionName,
      //      rke_split       as AllocationSplitCost, //just for PA CO Alloc dont need now, sender selection type

      fm_derive                                       as AllocFundMgmtIsActive,
      gl_xbilk                                        as AllocationIsBalanceSheetActive,
      fm_derive_fonds                                 as AllocHasDerivdFundFrmRcpnt,
      fm_derive_fkber                                 as AllocIsDerivdFuncAreaFrmRcpnt,
      fm_derive_grant                                 as AllocIsDerivdGrantFrmRcpnt,
      fm_derive_budpd                                 as AllocIsDerivdBudgedPerdRcpnt,
      gl_ldgrp                                        as AllocationLedgerGroup,
      period_lag                                      as AllocationIsPeriodShiftActive,
      period_delta                                    as AllocationPeriodDeltaSize,
      kalc_prodper                                    as AllocIsProdnMnthDerivd,
      variabel                                        as AllocationIsVariableQuantity,
      valutyp_alloc                                   as AllocationValuationType,
      cast(substring(cycle, 3, 8) as fco_alloc_cycle) as AllocationCycleName,
      cast(substring(cycle, 1, 3) as fis_rldnr)       as Ledger,

      cast(enable_delta_process as fco_alloc_delta_process_enable) 
                                                      as CycleIsDeltaProcessEnabled,

      cast(case when iterflag = 'I' then 'X' else ''
        end as fco_alloc_iterative)                   as AllocationCycleIsIterative,

      cast(can_exec_for_other_ledger as
        fco_alloc_parallel_ledger)                    as CycleIsParallelLedgerEnabled,
      
      cast(enable_attributed_line_items as
        fco_alloc_enbl_attr_line_items)               as  CycleIsAttributedLineItmEnbld,                    

      _Change.LastChangeTime,

      _Context,
      _ActualPlanText,
      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_ALLOCATIONCYCLECHANGE",
"T811C"
],
"ASSOCIATED":
[
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCASSMTDISTRLONGTEXT",
"I_ALLOCATIONCONTEXTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/